net-misc/youtube-dl: Version 2019.08.13

Package-Manager: Portage-2.3.71, Repoman-2.3.17
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

2 files changed, 70 insertions, 0 deletions

diff --git a/net-misc/youtube-dl/Manifest b/net-misc/youtube-dl/Manifest
index 0d68537f2e74..e49238c4c8ea 100644
--- a/net-misc/youtube-dl/Manifest
+++ b/net-misc/youtube-dl/Manifest
@@ -1 +1,2 @@
 DIST youtube-dl-2019.08.02.tar.gz 3174224 BLAKE2B c5f3d0d210cc2dcc8e4d1170cfc44ade5095808fc1189b7e6dc5ce068ef421a70514d4e5af631d0d25e7ec68959d24ed988195b0f860c67f25898c177a9f8132 SHA512 9740fd8cb16ce73695ecc40017b8807d8a40d2df6bb7c1f89db00d0c490bd5a67718dffdf39b2b7d65071f01738c684a1deb520eef5efcf87f1e39ac8f3e103f
+DIST youtube-dl-2019.08.13.tar.gz 3177273 BLAKE2B 927b7bfe128738efbb5023817ccbcf635b6f7f3741f3f794bd8af377cd7c203ae4466818d03ee717f5196124c3a46c5bf9c1e1a92438a295a453786bd8ec3ee5 SHA512 0b5066f3ce93bc0ffa3f9c3aefe4154daae38e78449a8b5825ecf032252f8fafde893f1325809b3d9fecf28ca1c2539d941b90acf204c5bf68783e79fcd28c61
diff --git a/net-misc/youtube-dl/youtube-dl-2019.08.13.ebuild b/net-misc/youtube-dl/youtube-dl-2019.08.13.ebuild
new file mode 100644
index 000000000000..89ac8f636eea
--- /dev/null
+++ b/net-misc/youtube-dl/youtube-dl-2019.08.13.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+PYTHON_COMPAT=(python{2_7,3_5,3_6,3_7})
+inherit bash-completion-r1 distutils-r1 readme.gentoo-r1
+
+DESCRIPTION="Download videos from YouTube.com (and more sites...)"
+HOMEPAGE="https://github.com/ytdl-org/youtube-dl/"
+SRC_URI="https://youtube-dl.org/downloads/${PV}/${P}.tar.gz"
+LICENSE="public-domain"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x86-solaris"
+RESTRICT="test"
+SLOT="0"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	${DEPEND}
+	|| (
+		dev-python/pycryptodome[${PYTHON_USEDEP}]
+		dev-python/pycrypto[${PYTHON_USEDEP}]
+	)
+"
+S="${WORKDIR}/${PN}"
+
+src_compile() {
+	distutils-r1_src_compile
+}
+
+python_install_all() {
+	dodoc README.txt
+	doman ${PN}.1
+
+	newbashcomp ${PN}.bash-completion ${PN}
+
+	insinto /usr/share/zsh/site-functions
+	newins ${PN}.zsh _${PN}
+
+	insinto /usr/share/fish/vendor_completions.d
+	doins ${PN}.fish
+
+	distutils-r1_python_install_all
+
+	rm -r "${ED}"/usr/etc || die
+	rm -r "${ED}"/usr/share/doc/youtube_dl || die
+}
+
+pkg_postinst() {
+	elog "${PN}(1) / https://bugs.gentoo.org/355661 /"
+	elog "https://github.com/rg3/${PN}/blob/master/README.md#faq :"
+	elog
+	elog "${PN} works fine on its own on most sites. However, if you want"
+	elog "to convert video/audio, you'll need avconf (media-video/libav) or"
+	elog "ffmpeg (media-video/ffmpeg). On some sites - most notably YouTube -"
+	elog "videos can be retrieved in a higher quality format without sound."
+	elog "${PN} will detect whether avconv/ffmpeg is present and"
+	elog "automatically pick the best option."
+	elog
+	elog "Videos or video formats streamed via RTMP protocol can only be"
+	elog "downloaded when rtmpdump (media-video/rtmpdump) is installed."
+	elog
+	elog "Downloading MMS and RTSP videos requires either mplayer"
+	elog "(media-video/mplayer) or mpv (media-video/mpv) to be installed."
+	elog
+	elog "If you want ${PN} to embed thumbnails from the metadata into the"
+	elog "resulting MP4 files, consider installing media-video/atomicparsley"
+}