net-misc/streamlink: add 6.3.1

Signed-off-by: Sam James <sam@gentoo.org>

3 files changed, 83 insertions, 7 deletions

diff --git a/net-misc/streamlink/Manifest b/net-misc/streamlink/Manifest
index 941d1a4fca78..30d4bb556928 100644
--- a/net-misc/streamlink/Manifest
+++ b/net-misc/streamlink/Manifest
@@ -3,3 +3,4 @@ DIST streamlink-6.0.1.tar.gz 682425 BLAKE2B a84c6c1594b78b62c1c20c021c3dde2eae06
 DIST streamlink-6.1.0.tar.gz 686463 BLAKE2B cc2890db0181e47bcae9da38eddeaadfd34b29a3d4b8bc2bb4d296289cdb356f9614d4e1edd8b11e23d226115f645399296d5589e42832ad473d9cb96ebfde0f SHA512 24fb549be6088eb913348ae892f694b91a6d6c929a06b9ed0db050e203a020ea9780b217f96d7890b7309d304e9a547c47673b8b3f2588dfedbaa44bb5808e29
 DIST streamlink-6.2.0.tar.gz 690986 BLAKE2B 5f7cab73ea366580aeb837b8f8a27fa7cd5ca687afa53908900dc9f290a0da916778fda8351acda00f795688b156ca0f37302e67128ce30e9838a45111b88ecd SHA512 2747ebc584caa8ebb2fde5d4f309c911a52fd1a8d2d0e832487e589873c270534e0d0b18120a2db7a68e150e301e57db1e8d63f1d5bb6244f364e9cbd6606213
 DIST streamlink-6.2.1.tar.gz 692446 BLAKE2B c1b98ffca37051675a92afc86d12635b538c1b12c023b652a05516faffb289f50b479b38ae48813a4f83d6c881dc7f211e66c6d7f7dd08adcf1a354c9bd15427 SHA512 852610d97138cf0a8066f760f747cb32f1d51c8c55b84df5b6a798556343010c2e68ca5d9a8473e8d32f72bc2a5d89f9d90ee70ccced84b6c9408930ed49585a
+DIST streamlink-6.3.1.tar.gz 699073 BLAKE2B 9d1fc58bd0cf4539369fc9d49230c18ef3b9a783783a517c831089571424412841f9e8925202d32bc4218d7a08e4e53c823fc503199131edb59e8fd69e8d49fa SHA512 a1e50688acd3b99efd20c1ff1d3bda03cb6e6b5566484d29372bc6d08ee4115f8ad2edea2f0a90f5de105edb52689781892f413f4af3d836cdd9e9a364006610
diff --git a/net-misc/streamlink/streamlink-6.3.1.ebuild b/net-misc/streamlink/streamlink-6.3.1.ebuild
new file mode 100644
index 000000000000..05ac7784a3e8
--- /dev/null
+++ b/net-misc/streamlink/streamlink-6.3.1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+if [[ ${PV} = 9999* ]]; then
+	EGIT_REPO_URI="https://github.com/streamlink/${PN}.git"
+	inherit git-r3
+fi
+
+DISTUTILS_SINGLE_IMPL=1
+# >= 6.2.1 uses a bunch of setuptools hooks instead of vanilla setuptools
+# https://github.com/streamlink/streamlink/commit/194d9bc193f5285bc1ba33af5fd89209a96ad3a7
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{10..12} )
+PYTHON_REQ_USE='xml(+),threads(+)'
+inherit distutils-r1
+
+DESCRIPTION="CLI for extracting streams from websites to a video player of your choice"
+HOMEPAGE="https://streamlink.github.io/"
+
+if [[ ${PV} != 9999* ]]; then
+	SRC_URI="https://github.com/streamlink/${PN}/releases/download/${PV}/${P}.tar.gz"
+fi
+
+LICENSE="BSD-2 Apache-2.0"
+SLOT="0"
+if [[ ${PV} != 9999* ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+RDEPEND="
+	media-video/ffmpeg
+	$(python_gen_cond_dep '
+		dev-python/certifi[${PYTHON_USEDEP}]
+		>=dev-python/requests-2.26.0[${PYTHON_USEDEP}]
+		dev-python/isodate[${PYTHON_USEDEP}]
+		>=dev-python/lxml-4.6.4[${PYTHON_USEDEP}]
+		>=dev-python/websocket-client-1.2.1[${PYTHON_USEDEP}]
+		dev-python/pycountry[${PYTHON_USEDEP}]
+		>=dev-python/pycryptodome-3.4.3[${PYTHON_USEDEP}]
+		>dev-python/PySocks-1.5.7[${PYTHON_USEDEP}]
+		>=dev-python/trio-0.22.0[${PYTHON_USEDEP}]
+		>=dev-python/trio-websocket-0.9.0[${PYTHON_USEDEP}]
+		>=dev-python/urllib3-1.26.0[${PYTHON_USEDEP}]
+	')
+"
+BDEPEND="
+	$(python_gen_cond_dep '
+		>=dev-python/setuptools-64[${PYTHON_USEDEP}]
+		>=dev-python/versioningit-2.0.0[${PYTHON_USEDEP}]
+		test? (
+			>=dev-python/freezegun-1.0.0[${PYTHON_USEDEP}]
+			dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+			dev-python/pytest-trio[${PYTHON_USEDEP}]
+			dev-python/requests-mock[${PYTHON_USEDEP}]
+		)
+	')
+"
+
+if [[ ${PV} == 9999* ]]; then
+	RDEPEND+="
+		$(python_gen_cond_dep '
+			>=dev-python/versioningit-2.0.0[${PYTHON_USEDEP}]
+		')
+	"
+fi
+
+distutils_enable_tests pytest
diff --git a/net-misc/streamlink/streamlink-9999.ebuild b/net-misc/streamlink/streamlink-9999.ebuild
index 5f7264547893..05ac7784a3e8 100644
--- a/net-misc/streamlink/streamlink-9999.ebuild
+++ b/net-misc/streamlink/streamlink-9999.ebuild
@@ -21,13 +21,16 @@ HOMEPAGE="https://streamlink.github.io/"
 
 if [[ ${PV} != 9999* ]]; then
 	SRC_URI="https://github.com/streamlink/${PN}/releases/download/${PV}/${P}.tar.gz"
-	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
 fi
 
 LICENSE="BSD-2 Apache-2.0"
 SLOT="0"
+if [[ ${PV} != 9999* ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
 
-DEPEND="
+RDEPEND="
+	media-video/ffmpeg
 	$(python_gen_cond_dep '
 		dev-python/certifi[${PYTHON_USEDEP}]
 		>=dev-python/requests-2.26.0[${PYTHON_USEDEP}]
@@ -40,13 +43,8 @@ DEPEND="
 		>=dev-python/trio-0.22.0[${PYTHON_USEDEP}]
 		>=dev-python/trio-websocket-0.9.0[${PYTHON_USEDEP}]
 		>=dev-python/urllib3-1.26.0[${PYTHON_USEDEP}]
-		>=dev-python/versioningit-2.0.0[${PYTHON_USEDEP}]
 	')
 "
-RDEPEND="
-	${DEPEND}
-	media-video/ffmpeg
-"
 BDEPEND="
 	$(python_gen_cond_dep '
 		>=dev-python/setuptools-64[${PYTHON_USEDEP}]
@@ -60,4 +58,12 @@ BDEPEND="
 	')
 "
 
+if [[ ${PV} == 9999* ]]; then
+	RDEPEND+="
+		$(python_gen_cond_dep '
+			>=dev-python/versioningit-2.0.0[${PYTHON_USEDEP}]
+		')
+	"
+fi
+
 distutils_enable_tests pytest