net-libs/libtorrent-rasterbar: Version bump (v1.2.7)

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Mikle Kolyada <zlogene@gentoo.org>

2 files changed, 110 insertions, 0 deletions

diff --git a/net-libs/libtorrent-rasterbar/Manifest b/net-libs/libtorrent-rasterbar/Manifest
index 5b72f9279d26..e2cdd9dce239 100644
--- a/net-libs/libtorrent-rasterbar/Manifest
+++ b/net-libs/libtorrent-rasterbar/Manifest
@@ -1,2 +1,3 @@
 DIST libtorrent-rasterbar-1.1.14.tar.gz 4040571 BLAKE2B 38ea1a71e46bf18c9beeb869280e4949b199ab58c32f41e63f1c15c7c32db0d256b741ea707350e9e153695b9cc28e0a95385944bf76dbd5eb2055e66bb0f919 SHA512 b640ada016f8e68a3fb0e033dd33ab79b345b0f691aa722c4256b8cd8524c6e55067ccd1f11584984bbb82c0f64151f0b5223bd2b8431b899ffca46d2d31fff5
 DIST libtorrent-rasterbar-1.2.6.tar.gz 3611015 BLAKE2B 39323c223927272a4eb9bb93ad70acd62165b9b3eb3f4f45cb76f99a23b1e131b526c8d8370fbd7cc30c7e776a5f9b7990c989ceaa3566272adc25df639fc5ba SHA512 9f03e28449b08e18a98a1f1bf0571f470c56fabd2becde5bde56ad566611c8519b0b387939f285a552d1f0382446633b67d00b6b5ff7083e4d1420a3ce9232fc
+DIST libtorrent-rasterbar-1.2.7.tar.gz 4105179 BLAKE2B 126bb0b287c0573f755e918b3cf32a0a98c14b3b41f676d7842ea58deecc141b046b4bc18579cb9c20b324fb1361794ee6afedeff64d0b76f1bb6a95b82e10f7 SHA512 60dfb31b1300b3aa2219227b3a263ba73aedb54a90aa940c117027651779cb972d6e1badf9519f6ad7947233b54df608b829bab34493ceda9e4cb8913041a752
diff --git a/net-libs/libtorrent-rasterbar/libtorrent-rasterbar-1.2.7.ebuild b/net-libs/libtorrent-rasterbar/libtorrent-rasterbar-1.2.7.ebuild
new file mode 100644
index 000000000000..c123d741392f
--- /dev/null
+++ b/net-libs/libtorrent-rasterbar/libtorrent-rasterbar-1.2.7.ebuild
@@ -0,0 +1,109 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8} )
+PYTHON_REQ_USE="threads(+)"
+DISTUTILS_OPTIONAL=true
+DISTUTILS_IN_SOURCE_BUILD=true
+
+inherit autotools distutils-r1
+
+MY_PV=$(ver_rs 1-2 '_')
+
+DESCRIPTION="C++ BitTorrent implementation focusing on efficiency and scalability"
+HOMEPAGE="https://libtorrent.org https://github.com/arvidn/libtorrent"
+SRC_URI="https://github.com/arvidn/libtorrent/releases/download/libtorrent_${MY_PV}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/10"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86"
+IUSE="debug +dht doc examples libressl python +ssl static-libs test"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/boost:=[threads]
+	virtual/libiconv
+	examples? ( !net-p2p/mldonkey )
+	python? (
+		${PYTHON_DEPS}
+		dev-libs/boost:=[python,${PYTHON_USEDEP}]
+	)
+	ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:= )
+	)
+"
+DEPEND="${RDEPEND}
+	sys-devel/libtool
+"
+
+src_prepare() {
+	touch "${S}"/build-aux/config.rpath || die
+	eautoreconf
+
+	default
+
+	# bug 578026
+	# prepend -L${S}/... to ensure bindings link against the lib we just built
+	sed -i -e "s|^|-L${S}/src/.libs |" bindings/python/link_flags.in || die
+
+	# prepend -I${S}/... to ensure bindings use the right headers
+	sed -i -e "s|^|-I${S}/src/include |" bindings/python/compile_flags.in || die
+
+	use python && distutils-r1_src_prepare
+}
+
+src_configure() {
+
+	local myeconfargs=(
+		$(use_enable debug)
+		$(use_enable debug export-all)
+		$(use_enable debug logging)
+		$(use_enable dht)
+		$(use_enable examples)
+		$(use_enable ssl encryption)
+		$(use_enable static-libs static)
+		$(use_enable test tests)
+		--with-boost="${EPREFIX}/usr"
+		--with-libiconv
+	)
+	econf "${myeconfargs[@]}"
+
+	if use python; then
+		python_configure() {
+			econf "${myeconfargs[@]}" \
+				--enable-python-binding \
+				--with-boost-python="boost_${EPYTHON/./}"
+		}
+		distutils-r1_src_configure
+	fi
+}
+
+src_compile() {
+	default
+
+	python_compile() {
+		cd "${BUILD_DIR}/../bindings/python" || die
+		distutils-r1_python_compile
+	}
+	use python && distutils-r1_src_compile
+}
+
+src_install() {
+	use doc && HTML_DOCS+=( "${S}"/docs )
+
+	default
+
+	python_install() {
+		cd "${BUILD_DIR}/../bindings/python" || die
+		distutils-r1_python_install
+	}
+	use python && distutils-r1_src_install
+
+	find "${D}" -name '*.la' -delete || die
+}