net-im/spectrum2: force irc for tests, block dev-libs/libpqxx-7

In order to run all tests, irc must be enabled for those tests. It's not
required for normal usage.

Also restricted on <=dev-libs/libpqxx-7, since it does not compile with
newest version.

Closes: https://bugs.gentoo.org/731166
Closes: https://bugs.gentoo.org/735100
Package-Manager: Portage-3.0.1, Repoman-2.3.23
Signed-off-by: Conrad Kostecki <conikost@gentoo.org>

2 files changed, 215 insertions, 0 deletions

diff --git a/net-im/spectrum2/spectrum2-2.0.12-r4.ebuild b/net-im/spectrum2/spectrum2-2.0.12-r4.ebuild
new file mode 100644
index 000000000000..334f15bf5380
--- /dev/null
+++ b/net-im/spectrum2/spectrum2-2.0.12-r4.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake systemd
+
+DESCRIPTION="An open source instant messaging transport"
+HOMEPAGE="https://www.spectrum.im"
+SRC_URI="https://github.com/SpectrumIM/spectrum2/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="amd64"
+IUSE="doc frotz irc mysql postgres purple sms +sqlite test twitter whatsapp xmpp"
+REQUIRED_USE="
+	|| ( mysql postgres sqlite )
+	test? ( irc )
+"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	acct-group/spectrum
+	acct-user/spectrum
+	dev-libs/boost:=[nls]
+	dev-libs/expat
+	dev-libs/libev:=
+	dev-libs/log4cxx
+	dev-libs/jsoncpp:=
+	dev-libs/openssl:0=
+	dev-libs/popt
+	dev-libs/protobuf:=
+	net-dns/libidn:0=
+	>=net-im/swift-4.0.2-r2:=
+	net-misc/curl
+	sys-libs/zlib:=
+	frotz? ( !games-engines/frotz )
+	irc? ( net-im/libcommuni )
+	mysql? (
+		|| (
+			dev-db/mariadb-connector-c
+			dev-db/mysql-connector-c
+		)
+	)
+	postgres? ( <=dev-libs/libpqxx-7.0.0:= )
+	purple? (
+		dev-libs/glib
+		net-im/pidgin:=
+	)
+	sms? ( app-mobilephone/smstools )
+	sqlite? ( dev-db/sqlite:3 )
+	twitter? ( net-misc/curl )
+	whatsapp? ( net-im/transwhat )"
+
+DEPEND="
+	${RDEPEND}
+	doc? ( app-doc/doxygen )
+	test? (	dev-util/cppunit )
+"
+
+PATCHES="
+	"${FILESDIR}/${P}-boost-173-compatibility.patch"
+	"${FILESDIR}/${P}-gcc-10-compatibility.patch"
+"
+
+src_prepare() {
+	# Respect users LDFLAGS
+	sed -i -e "s/-Wl,-export-dynamic/& ${LDFLAGS}/" spectrum/src/CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_DOCS="$(usex doc)"
+		-DENABLE_FROTZ="$(usex frotz)"
+		-DENABLE_IRC="$(usex irc)"
+		-DENABLE_MYSQL="$(usex mysql)"
+		-DENABLE_PQXX="$(usex postgres)"
+		-DENABLE_PURPLE="$(usex purple)"
+		$(usex irc '-DENABLE_QT4=OFF' '')
+		-DENABLE_SMSTOOLS3="$(usex sms)"
+		-DENABLE_SQLITE3="$(usex sqlite)"
+		-DENABLE_TESTS="$(usex test)"
+		-DENABLE_TWITTER="$(usex twitter)"
+		-DENABLE_XMPP="$(usex xmpp)"
+		-DLIB_INSTALL_DIR="$(get_libdir)"
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	cd "${BUILD_DIR}/tests/libtransport" || die
+	./libtransport_test || die
+}
+
+src_install() {
+	cmake_src_install
+
+	diropts -o spectrum -g spectrum
+	keepdir /var/log/spectrum2 /var/lib/spectrum2
+	diropts
+
+	newinitd "${FILESDIR}"/spectrum2.initd spectrum2
+	systemd_newunit "${FILESDIR}"/spectrum2.service spectrum2.service
+	systemd_newtmpfilesd "${FILESDIR}"/spectrum2.tmpfiles-r1 spectrum2.conf
+
+	einstalldocs
+}
diff --git a/net-im/spectrum2/spectrum2-2.0.13-r2.ebuild b/net-im/spectrum2/spectrum2-2.0.13-r2.ebuild
new file mode 100644
index 000000000000..edbad4cad3eb
--- /dev/null
+++ b/net-im/spectrum2/spectrum2-2.0.13-r2.ebuild
@@ -0,0 +1,105 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake systemd
+
+DESCRIPTION="An open source instant messaging transport"
+HOMEPAGE="https://www.spectrum.im"
+SRC_URI="https://github.com/SpectrumIM/spectrum2/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="doc frotz irc mysql postgres purple sms +sqlite test twitter whatsapp xmpp"
+REQUIRED_USE="
+	|| ( mysql postgres sqlite )
+	test? ( irc )
+"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	acct-group/spectrum
+	acct-user/spectrum
+	dev-libs/boost:=[nls]
+	dev-libs/expat
+	dev-libs/libev:=
+	dev-libs/log4cxx
+	dev-libs/jsoncpp:=
+	dev-libs/openssl:0=
+	dev-libs/popt
+	dev-libs/protobuf:=
+	net-dns/libidn:0=
+	>=net-im/swift-4.0.2-r2:=
+	net-misc/curl
+	sys-libs/zlib:=
+	frotz? ( !games-engines/frotz )
+	irc? ( net-im/libcommuni )
+	mysql? (
+		|| (
+			dev-db/mariadb-connector-c
+			dev-db/mysql-connector-c
+		)
+	)
+	postgres? ( <=dev-libs/libpqxx-7.0.0:= )
+	purple? (
+		dev-libs/glib
+		net-im/pidgin:=
+	)
+	sms? ( app-mobilephone/smstools )
+	sqlite? ( dev-db/sqlite:3 )
+	twitter? ( net-misc/curl )
+	whatsapp? ( net-im/transwhat )"
+
+DEPEND="
+	${RDEPEND}
+	doc? ( app-doc/doxygen )
+	test? ( dev-util/cppunit )
+"
+
+src_prepare() {
+	# Respect users LDFLAGS
+	sed -i -e "s/-Wl,-export-dynamic/& ${LDFLAGS}/" spectrum/src/CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_DOCS="$(usex doc)"
+		-DENABLE_FROTZ="$(usex frotz)"
+		-DENABLE_IRC="$(usex irc)"
+		-DENABLE_MYSQL="$(usex mysql)"
+		-DENABLE_PQXX="$(usex postgres)"
+		-DENABLE_PURPLE="$(usex purple)"
+		$(usex irc '-DENABLE_QT4=OFF' '')
+		-DENABLE_SMSTOOLS3="$(usex sms)"
+		-DENABLE_SQLITE3="$(usex sqlite)"
+		-DENABLE_TESTS="$(usex test)"
+		-DENABLE_TWITTER="$(usex twitter)"
+		-DENABLE_XMPP="$(usex xmpp)"
+		-DLIB_INSTALL_DIR="$(get_libdir)"
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	cd "${BUILD_DIR}/tests/libtransport" || die
+	./libtransport_test || die
+}
+
+src_install() {
+	cmake_src_install
+
+	diropts -o spectrum -g spectrum
+	keepdir /var/log/spectrum2 /var/lib/spectrum2
+	diropts
+
+	newinitd "${FILESDIR}"/spectrum2.initd spectrum2
+	systemd_newunit "${FILESDIR}"/spectrum2.service spectrum2.service
+	systemd_newtmpfilesd "${FILESDIR}"/spectrum2.tmpfiles-r1 spectrum2.conf
+
+	einstalldocs
+}