media-sound/sndio: Add a live ebuild

Signed-off-by: Haelwenn (lanodan) Monnier <contact@hacktivis.me>
Closes: https://github.com/gentoo/gentoo/pull/20283
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

2 files changed, 61 insertions, 2 deletions

diff --git a/media-sound/sndio/sndio-1.7.0-r1.ebuild b/media-sound/sndio/sndio-1.7.0-r1.ebuild
index e0b1447d8708..f7fa4e0c4498 100644
--- a/media-sound/sndio/sndio-1.7.0-r1.ebuild
+++ b/media-sound/sndio/sndio-1.7.0-r1.ebuild
@@ -7,11 +7,17 @@ inherit multilib-minimal toolchain-funcs
 
 DESCRIPTION="small audio and MIDI framework part of the OpenBSD project"
 HOMEPAGE="http://www.sndio.org/"
-SRC_URI="http://www.sndio.org/${P}.tar.gz"
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://caoua.org/git/sndio"
+	EGIT_MIN_CLONE_TYPE="single+tags"
+else
+	SRC_URI="http://www.sndio.org/${P}.tar.gz"
+	KEYWORDS="amd64 arm arm64 ~hppa ~ia64 ppc ppc64 sparc x86"
+fi
 
 LICENSE="ISC"
 SLOT="0/7.0"
-KEYWORDS="amd64 arm arm64 ~hppa ~ia64 ppc ppc64 sparc x86"
 IUSE="alsa"
 
 DEPEND="
diff --git a/media-sound/sndio/sndio-9999.ebuild b/media-sound/sndio/sndio-9999.ebuild
new file mode 100644
index 000000000000..16b9e5b69d36
--- /dev/null
+++ b/media-sound/sndio/sndio-9999.ebuild
@@ -0,0 +1,53 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit multilib-minimal toolchain-funcs
+
+DESCRIPTION="small audio and MIDI framework part of the OpenBSD project"
+HOMEPAGE="http://www.sndio.org/"
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://caoua.org/git/sndio"
+	EGIT_MIN_CLONE_TYPE="single+tags"
+else
+	SRC_URI="http://www.sndio.org/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+fi
+
+LICENSE="ISC"
+SLOT="0/7.1"
+IUSE="alsa"
+
+DEPEND="
+	dev-libs/libbsd[${MULTILIB_USEDEP}]
+	alsa? ( media-libs/alsa-lib[${MULTILIB_USEDEP}] )
+"
+RDEPEND="
+	${DEPEND}
+	acct-user/sndiod
+"
+
+src_prepare() {
+	default
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	tc-export CC
+
+	./configure \
+		--prefix="${EPREFIX}"/usr \
+		--libdir="${EPREFIX}"/usr/$(get_libdir) \
+		--privsep-user=sndiod \
+		--with-libbsd \
+		$(use_enable alsa) \
+	|| die "Configure failed"
+}
+
+src_install() {
+	multilib-minimal_src_install
+
+	doinitd "${FILESDIR}/sndiod"
+}