media-sound/sox: Switch to media-libs/libpulse, add security patches

Source:
https://salsa.debian.org/multimedia-team/sox/-/tree/master/debian/patches

Patchset content:
0019-fix-resource-leak-comments.patch
0020-fix-resource-leak-hcom.patch
0022-CVE-2021-3643.patch
0023-CVE-2021-23159.patch
0025-CVE-2021-40426.patch
0026-CVE-2022-31650.patch
0027-CVE-2022-31651.patch
0028-CVE-2023-32627-Filter-null-sampling-rate-in-VOC-code.patch
0030-vorbis-fix-memory-leaks.patch

Bug: https://bugs.gentoo.org/838382
Closes: https://bugs.gentoo.org/939108
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 119 insertions, 0 deletions

diff --git a/media-sound/sox/Manifest b/media-sound/sox/Manifest
index af44637e105c..e188c594038a 100644
--- a/media-sound/sox/Manifest
+++ b/media-sound/sox/Manifest
@@ -1 +1,2 @@
+DIST sox-14.4.2_p20210509-patchset.tar.xz 3560 BLAKE2B 8f575dbff121d749c83c6074dadeb92475472f36ad5b9c389e1591b60cff853167c22f7c059731fa5b78c497817bcae6be93ace21bfe605faf2445301a0fe2af SHA512 4b57689bc85ac7664693c6344fd17c7fc7991e04d5e6628c2455c8e541ecfec073690d4dc23a909474ba93fd24cd877aa77f1e7fcc5b52773daa794689212bb8
 DIST sox-14.4.2_p20210509.zip 942551 BLAKE2B 2ddd229faacb9190fe18052b1c02da40d4c3f24fc73dd08b28ac99bef267cb05f8bcbf64e0c397c391b3be2467667783ed94f6c60798af069567e1c237ec9ccd SHA512 4868f9b77141b7e2caf2571ceb68a48bd744732e72f63ed787f8e0b9fe39b77de4e998b32d99c2500e10b017a1fd1a3379f4f9f8b67db6093b85d02cb3447934
diff --git a/media-sound/sox/sox-14.4.2_p20210509-r3.ebuild b/media-sound/sox/sox-14.4.2_p20210509-r3.ebuild
new file mode 100644
index 000000000000..a61bd7961895
--- /dev/null
+++ b/media-sound/sox/sox-14.4.2_p20210509-r3.ebuild
@@ -0,0 +1,118 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+# We take a snapshot because of the huge number of security
+# and other fixes since the release of 14.4.2.
+# Recommend mirroring the snapshot; unclear if they are stable URIs.
+COMMIT="42b3557e13e0fe01a83465b672d89faddbe65f49"
+MY_P="sox-code-${COMMIT}"
+
+PATCHSET="${P}-patchset"
+
+DESCRIPTION="The swiss army knife of sound processing programs"
+HOMEPAGE="https://sox.sourceforge.net"
+# Source: https://sourceforge.net/code-snapshots/git/s/so/sox/code.git/${MY_P}.zip
+SRC_URI="https://dev.gentoo.org/~fordfrog/distfiles/${MY_P}.zip -> ${P}.zip
+	https://dev.gentoo.org/~asturm/distfiles/${PATCHSET}.tar.xz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="alsa amr ao encode flac id3tag ladspa mad magic ogg openmp oss opus png pulseaudio sndfile sndio static-libs twolame wavpack"
+
+RDEPEND="
+	dev-libs/libltdl:0=
+	>=media-sound/gsm-1.0.12-r1
+	sys-apps/file
+	alsa? ( media-libs/alsa-lib )
+	amr? ( media-libs/opencore-amr )
+	ao? ( media-libs/libao:= )
+	encode? ( >=media-sound/lame-3.98.4 )
+	flac? ( >=media-libs/flac-1.1.3:= )
+	id3tag? ( media-libs/libid3tag:= )
+	ladspa? ( media-libs/ladspa-sdk )
+	mad? ( media-libs/libmad )
+	magic? ( sys-apps/file )
+	ogg? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+	opus? (
+		media-libs/opus
+		media-libs/opusfile
+	)
+	png? (
+		media-libs/libpng:0=
+		sys-libs/zlib
+	)
+	pulseaudio? ( media-libs/libpulse )
+	sndfile? ( >=media-libs/libsndfile-1.0.11 )
+	sndio? ( media-sound/sndio:= )
+	twolame? ( media-sound/twolame )
+	wavpack? ( media-sound/wavpack )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	app-arch/unzip
+	dev-build/autoconf-archive
+	virtual/pkgconfig
+"
+
+DOCS=( AUTHORS ChangeLog NEWS )
+
+PATCHES=( "${WORKDIR}/${PATCHSET}" ) # bug 838382
+
+src_prepare() {
+	default
+
+	# bug #386027
+	sed -i -e 's|CFLAGS="-g"|CFLAGS="$CFLAGS -g"|' configure.ac || die
+
+	# bug #712630
+	if use elibc_musl ; then
+		ewarn "Applying musl workaround for bug #712630."
+		ewarn "File-type detection with pipes may be missing."
+		sed -i '/error FIX NEEDED HERE/d' src/formats.c || die
+	fi
+
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable alsa)
+		$(use_enable amr amrnb)
+		$(use_enable amr amrwb)
+		$(use_enable ao)
+		$(use_with encode lame)
+		$(use_enable flac)
+		$(use_with id3tag)
+		$(use_with ladspa ladspa dyn)
+		$(use_with mad)
+		$(use_with magic)
+		$(use_enable openmp)
+		$(use_enable ogg oggvorbis)
+		$(use_enable oss)
+		$(use_enable opus)
+		$(use_with png)
+		$(use_enable pulseaudio)
+		$(use_enable sndfile)
+		$(use_enable sndio)
+		$(use_enable static-libs static)
+		$(use_with twolame)
+		$(use_enable wavpack)
+		--enable-formats=dyn
+		--with-distro="Gentoo"
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${ED}" -type f -name '*.la' -delete || die
+}