media-sound/ncmpcpp: Version bump.

Package-Manager: portage-2.2.28

1 files changed, 70 insertions, 0 deletions

diff --git a/media-sound/ncmpcpp/ncmpcpp-0.7.4.ebuild b/media-sound/ncmpcpp/ncmpcpp-0.7.4.ebuild
new file mode 100644
index 000000000000..114ea3cb847c
--- /dev/null
+++ b/media-sound/ncmpcpp/ncmpcpp-0.7.4.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils
+
+DESCRIPTION="featureful ncurses based MPD client inspired by ncmpc"
+HOMEPAGE="http://ncmpcpp.rybczak.net/"
+SRC_URI="http://ncmpcpp.rybczak.net/stable/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86"
+IUSE="clock curl outputs taglib unicode visualizer"
+
+RDEPEND="
+	!dev-libs/boost:0/1.57.0
+	>=media-libs/libmpdclient-2.1
+	dev-libs/boost:=[nls,threads]
+	sys-libs/ncurses:=[unicode?]
+	sys-libs/readline:*
+	curl? ( net-misc/curl )
+	taglib? ( media-libs/taglib )
+	unicode? (
+		dev-libs/boost:=[icu]
+		dev-libs/icu:=
+	)
+	visualizer? ( sci-libs/fftw:3.0= )
+"
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	sed -i -e '/^docdir/d' {,doc/}Makefile{.am,.in} || die
+	sed -i -e 's|COPYING||g' Makefile{.am,.in} || die
+}
+
+src_configure() {
+	econf \
+		$(use_enable clock) \
+		$(use_enable outputs) \
+		$(use_enable unicode) \
+		$(use_enable visualizer) \
+		$(use_with curl) \
+		$(use_with taglib) \
+		$(use_with visualizer fftw) \
+		--docdir=/usr/share/doc/${PF}
+}
+
+src_install() {
+	default
+
+	dodoc doc/{bindings,config}
+}
+
+pkg_postinst() {
+	echo
+	elog "Example configuration files have been installed at"
+	elog "${ROOT}usr/share/doc/${PF}"
+	elog "${P} uses ~/.ncmpcpp/config and ~/.ncmpcpp/bindings"
+	elog "as user configuration files."
+	echo
+	if use visualizer; then
+	elog "If you want to use the visualizer, you need mpd with fifo enabled."
+	echo
+	fi
+}