media-radio/tucnak: add 4.49

Signed-off-by: Thomas Beierlein <tomjbe@gentoo.org>

2 files changed, 69 insertions, 0 deletions

diff --git a/media-radio/tucnak/Manifest b/media-radio/tucnak/Manifest
index c572c9c39018..569b05a5a819 100644
--- a/media-radio/tucnak/Manifest
+++ b/media-radio/tucnak/Manifest
@@ -1 +1,2 @@
 DIST tucnak-4.46.tar.gz 3617927 BLAKE2B 090a962c686e0de83d41c4fb017caaf9482d2058909164a97db4eb7e4bfd4d8fe19e21cc750f31493e4bf64454fa8d03f65b55da58749257601dba64b1476c8e SHA512 9c33c9dd7061d0ab2cb696ccf121145ebc60e0f8b2a29152ec6e59155af186c20d101cce698d48b8d669f64c8ee4b88d57d1896b574e9e250853a2bc45029d06
+DIST tucnak-4.49.tar.gz 3619211 BLAKE2B 549399c2123ebd17f1164d431707b49a01159566be97b05b5f656a40c555d6c96b04a7d765db4ad94231f01b8d3af600a060104e42a87c60b6905eeba6cf8c8e SHA512 9c55b9a9048c95692d6cce7586c1b78a6237b02a43ad82ec771491f8463518f1e09e9f0be4db02b061b5aff518507a11bd6b0b7a038b90ff18ea1286accc3be4
diff --git a/media-radio/tucnak/tucnak-4.49.ebuild b/media-radio/tucnak/tucnak-4.49.ebuild
new file mode 100644
index 000000000000..1f2cfa26c1bf
--- /dev/null
+++ b/media-radio/tucnak/tucnak-4.49.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit autotools flag-o-matic
+
+DESCRIPTION="Amateur Radio VHF Contest Logbook"
+HOMEPAGE="http://tucnak.nagano.cz"
+SRC_URI="http://tucnak.nagano.cz/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa fftw gpm hamlib suid"
+
+RDEPEND="dev-libs/glib:2
+	~dev-libs/libzia-4.49
+	media-libs/libsndfile
+	media-libs/libsdl2
+	alsa? ( media-libs/alsa-lib )
+	fftw? ( sci-libs/fftw:3.0 )
+	gpm? ( sys-libs/gpm )
+	hamlib? ( media-libs/hamlib:= )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_prepare() {
+	eapply_user
+	# fix destop file
+	sed -i -e "s/HamRadio/HamRadio;/" share/applications/tucnak.desktop || die
+	# fix doc install path
+	sed -i -e "s/docsdir/# docsdir/" \
+		-e "s/docs_DATA =/# docs_DATA/" \
+		-e "s/EXTRA_DIST =/# EXTRA_DIST =/" Makefile.am doc/Makefile.am || die
+	eautoreconf
+}
+
+src_configure() {
+	append-ldflags -L/usr/$(get_libdir)/hamlib
+	econf $(use_with alsa) \
+		$(use_with gpm) $(use_with hamlib) \
+		$(use_with fftw fftw3)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc AUTHORS ChangeLog doc/NAVOD.pdf
+	if use suid ; then
+		fperms 4711 /usr/bin/soundwrapper
+	fi
+}
+
+pkg_postinst() {
+	elog "In order to use sound with tucnak add yourself to the 'audio' group"
+	elog "and to key your rig via the parport add yourself to the 'lp' group"
+	elog ""
+	elog "tucnak can be used with the following additional packages:"
+	elog "	   media-radio/cwdaemon  : Morse output via code cwdaemon"
+	elog "                             (No need to recompile)"
+	if use suid ; then
+		ewarn "You have choosen to install the little helper program 'soundwrapper'"
+		ewarn "setuid by setting USE=suid. That helper is only needed if you"
+		ewarn "want to use morse sidetone output via the PC speaker."
+		ewarn ""
+		ewarn "While the helper should be safe by design be aware that setting"
+		ewarn "any program setuid is a security risk."
+	fi
+}