media-gfx/openvdb: add missing dependencies

Add in missing dependencies:
* media-libs/glu (subject of the bug)
* media-libs/ilmbase (though it is a transient dep via OpenEXR)

We also include dev-cpp/tbb in ${RDEPEND} rather than only
${DEPEND}, given we link against it.

Closes: https://bugs.gentoo.org/673798
Package-Manager: Portage-3.0.4, Repoman-3.0.1
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 105 insertions, 0 deletions

diff --git a/media-gfx/openvdb/openvdb-5.2.0-r2.ebuild b/media-gfx/openvdb/openvdb-5.2.0-r2.ebuild
new file mode 100644
index 000000000000..e7e00d1db240
--- /dev/null
+++ b/media-gfx/openvdb/openvdb-5.2.0-r2.ebuild
@@ -0,0 +1,105 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+
+inherit cmake flag-o-matic python-single-r1
+
+DESCRIPTION="Library for the efficient manipulation of volumetric data"
+HOMEPAGE="https://www.openvdb.org"
+SRC_URI="https://github.com/AcademySoftwareFoundation/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="abi3-compat abi4-compat +abi5-compat doc python test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="
+	python? ( ${PYTHON_REQUIRED_USE} )
+	^^ ( abi3-compat abi4-compat abi5-compat )
+"
+
+RDEPEND="
+	dev-cpp/tbb
+	dev-libs/boost:=
+	dev-libs/c-blosc:=
+	dev-libs/jemalloc:=
+	dev-libs/log4cplus:=
+	media-libs/glfw
+	media-libs/glu
+	media-libs/ilmbase:=
+	media-libs/openexr:=
+	sys-libs/zlib:=
+	x11-libs/libXcursor
+	x11-libs/libXi
+	x11-libs/libXinerama
+	x11-libs/libXrandr
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			dev-libs/boost:=[python?,${PYTHON_USEDEP}]
+			dev-python/numpy[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+DEPEND="${RDEPEND}"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? (
+		app-doc/doxygen
+		dev-texlive/texlive-bibtexextra
+		dev-texlive/texlive-fontsextra
+		dev-texlive/texlive-fontutils
+		dev-texlive/texlive-latex
+		dev-texlive/texlive-latexextra
+	)
+	test? ( dev-util/cppunit )
+"
+
+PATCHES=(
+	"${FILESDIR}/${P}-use-gnuinstalldirs.patch"
+	"${FILESDIR}/${P}-use-pkgconfig-for-ilmbase-and-openexr.patch"
+	"${FILESDIR}/${PN}-4.0.2-fix-const-correctness-for-unittest.patch"
+	"${FILESDIR}/${PN}-4.0.2-fix-build-docs.patch"
+)
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local myprefix="${EPREFIX}/usr/"
+
+	local version
+	if use abi3-compat; then
+		version=3
+	elif use abi4-compat; then
+		version=4
+	elif use abi5-compat; then
+		version=5
+	else
+		die "Openvdb ABI version not specified"
+	fi
+
+	local mycmakeargs=(
+		-DBLOSC_LOCATION="${myprefix}"
+		-DCMAKE_INSTALL_DOCDIR="share/doc/${PF}"
+		-DGLFW3_LOCATION="${myprefix}"
+		-DOPENVDB_ABI_VERSION_NUMBER="${version}"
+		-DOPENVDB_BUILD_DOCS=$(usex doc)
+		-DOPENVDB_BUILD_PYTHON_MODULE=$(usex python)
+		-DOPENVDB_BUILD_UNITTESTS=$(usex test)
+		-DOPENVDB_ENABLE_RPATH=OFF
+		-DTBB_LOCATION="${myprefix}"
+		-DUSE_GLFW3=ON
+	)
+
+	use python && mycmakeargs+=( -DPYOPENVDB_INSTALL_DIRECTORY="$(python_get_sitedir)" )
+	use test && mycmakeargs+=( -DCPPUNIT_LOCATION="${myprefix}" )
+
+	cmake_src_configure
+}