kde-plasma/breeze: Fix logic error leading to kstyle crash

Upstream commit 2aa08ed366917b7b207842844b78e5dadd5a06ed
See also: https://invent.kde.org/plasma/breeze/-/merge_requests/163

Package-Manager: Portage-3.0.29, Repoman-3.0.3
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 88 insertions, 0 deletions

diff --git a/kde-plasma/breeze/breeze-5.23.4-r1.ebuild b/kde-plasma/breeze/breeze-5.23.4-r1.ebuild
new file mode 100644
index 000000000000..25e2284b20ba
--- /dev/null
+++ b/kde-plasma/breeze/breeze-5.23.4-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KFMIN=5.86.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="Breeze visual style for the Plasma desktop"
+HOMEPAGE="https://invent.kde.org/plasma/breeze"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="X"
+
+RDEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=kde-frameworks/frameworkintegration-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-plasma/kdecoration-${PVCUT}:5
+	X? ( x11-libs/libxcb )
+"
+DEPEND="${RDEPEND}
+	>=kde-frameworks/kpackage-${KFMIN}:5
+"
+PDEPEND="
+	>=kde-frameworks/breeze-icons-${KFMIN}:5
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+"
+
+PATCHES=( "${FILESDIR}"/${P}-fix-kstyle-crash.patch )
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package X XCB)
+	)
+	ecm_src_configure
+}
diff --git a/kde-plasma/breeze/files/breeze-5.23.4-fix-kstyle-crash.patch b/kde-plasma/breeze/files/breeze-5.23.4-fix-kstyle-crash.patch
new file mode 100644
index 000000000000..1d714c7aa6df
--- /dev/null
+++ b/kde-plasma/breeze/files/breeze-5.23.4-fix-kstyle-crash.patch
@@ -0,0 +1,35 @@
+From 2aa08ed366917b7b207842844b78e5dadd5a06ed Mon Sep 17 00:00:00 2001
+From: David Edmundson <kde@davidedmundson.co.uk>
+Date: Sun, 5 Dec 2021 16:50:10 +0000
+Subject: [PATCH] [kstyle] Fix logic error in
+ drawIndicatorButtonDropDownPrimitive
+
+The current code checks for !complexOption, but then continues to
+de-reference it in the second clause of the statement leading to an
+inveitable crash.
+
+I assume it's meant to be an `or` for the latter part of the statement
+to make sense.
+
+
+(cherry picked from commit b09dbd9282f848e779e74840a5a3ef13c71fa82e)
+---
+ kstyle/breezestyle.cpp | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/kstyle/breezestyle.cpp b/kstyle/breezestyle.cpp
+index ee06f41c..1337d26e 100644
+--- a/kstyle/breezestyle.cpp
++++ b/kstyle/breezestyle.cpp
+@@ -4024,7 +4024,7 @@ namespace Breeze
+ 
+         // cast option and check
+         const auto complexOption( qstyleoption_cast<const QStyleOptionComplex*>( option ) );
+-        if( !complexOption && !(complexOption->subControls & SC_ToolButtonMenu) ) return true;
++        if( !complexOption || !(complexOption->subControls & SC_ToolButtonMenu) ) return true;
+ 
+         // button state
+         bool enabled = option->state & QStyle::State_Enabled;
+-- 
+GitLab
+