kde-apps/umbrello: 21.08.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 76 insertions, 0 deletions

diff --git a/kde-apps/umbrello/Manifest b/kde-apps/umbrello/Manifest
index c407d2226dec..b972ecbe4a85 100644
--- a/kde-apps/umbrello/Manifest
+++ b/kde-apps/umbrello/Manifest
@@ -1 +1,2 @@
 DIST umbrello-21.04.3.tar.xz 5650032 BLAKE2B b306695798eb2791968b9b4ad98b34825c8712800fbf2a87a2f6398768cf9bcee1e94dd1efa8d513f2cb8f07f683ee880c8e655236d88b96c3c1bcc98929af6d SHA512 f4f632bf37f4170ebf6c1d776b70b058ded1c8a1a9626adea1c9b63e7d7cf45c0afaf77c4c9bf778c601265b9d819f5a898813ac32b58bcf29d7ab94c753d73d
+DIST umbrello-21.08.0.tar.xz 5650084 BLAKE2B 57ba3029349ff0c84b8a9c0bd142c2af32051323ac616b2de3ce4b5a2a013acf1d17fe3f691b08ff928e767d0fbdea9d358b6f84d2af1b6c66ccc0662b134b98 SHA512 aa6c3172e2a5510f9acf7991b800a2a13ac004abf98047f0fd240b529194357c41a15343df819e8c5d3c7d47c0b3899bdc0821d8eba602fb646ab3c2f39c2e5c
diff --git a/kde-apps/umbrello/umbrello-21.08.0.ebuild b/kde-apps/umbrello/umbrello-21.08.0.ebuild
new file mode 100644
index 000000000000..272d49fa4cd2
--- /dev/null
+++ b/kde-apps/umbrello/umbrello-21.08.0.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+ECM_QTHELP="false" # TODO: figure out install error
+ECM_TEST="forceoptional"
+KFMIN=5.84.0
+QTMIN=5.15.2
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="KDE UML Modeller"
+HOMEPAGE="https://apps.kde.org/umbrello/ https://umbrello.kde.org"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="php"
+
+RDEPEND="
+	dev-libs/libxml2
+	dev-libs/libxslt
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdelibs4support-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/ktexteditor-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	php? (
+		dev-util/kdevelop:5=
+		dev-util/kdevelop-pg-qt:5
+		dev-util/kdevelop-php:5
+	)
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-20.08.3-no-qtwebkit.patch
+	"${FILESDIR}"/${PN}-20.08.3-gentoo-docbundledir.patch # fix hardcoded path
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_Doxygen=ON # broken, re-enable w/ ECM_QTHELP
+		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5WebKitWidgets=ON
+		-DBUILD_APIDOC=OFF
+		-DBUILD_KF5=ON
+		-DBUILD_PHP_IMPORT=$(usex php)
+		-DBUILD_unittests=$(usex test)
+	)
+	use test && mycmakeargs+=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_LLVM=ON
+		-DCMAKE_DISABLE_FIND_PACKAGE_Clang=ON
+		-DCMAKE_DISABLE_FIND_PACKAGE_CLANG=ON
+	)
+
+	ecm_src_configure
+}