kde-apps: Add KDE Applications 19.08.3

Package-Manager: Portage-2.3.79, Repoman-2.3.18
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 88 insertions, 0 deletions

diff --git a/kde-apps/kwave/Manifest b/kde-apps/kwave/Manifest
index 5b68158a709b..e2bfb356e7cc 100644
--- a/kde-apps/kwave/Manifest
+++ b/kde-apps/kwave/Manifest
@@ -1,2 +1,3 @@
 DIST kwave-19.04.3.tar.xz 6209860 BLAKE2B 67d25636f857b81bf4586ac7a77cca1837a0267b16c3ee4b239058f26e4b2319e37c873eb42f239d20a0b545178a464bcb996fa1020e9c86905bd2b11395ee55 SHA512 9f3c6a058c652164d610f53ec36f1dd4d1c255b99c71684d8c19357ddf3c74dbc66288d47292866f88ed81ef72aa440f07534f55c7b2d34093f6c2c58a9a86a7
 DIST kwave-19.08.2.tar.xz 6194828 BLAKE2B 54a17ce6ac105a0963ffdb943b6571925a88adfd474557e0adaa0789d1bf9ddbcc63eecc833bb4fe0a2c44bf93ac4b325c27bddd14abf9c91c0819d0c6226062 SHA512 f282730973c6568997b732b1dce82c4e0426f460b3f14627a21045bc65a76b190f6da83828280d89f8f727a887dcbd7b3c0f005c77956f32b901724e0de888d0
+DIST kwave-19.08.3.tar.xz 6196324 BLAKE2B 33cbc85f3afb4c050f536819c799a7393d5883a7929b73cdbf782f43166990c1adad288e786755f5e9b35cbc7e72b0620d64f731fc6cd481da57aaf692d5084d SHA512 ad332004dbd9ab4b0a0c047a6012c071d44dbe1fe81dface3f68fbd556b52ac7ece5c5da66e704d87dab3db69cfb45a92f5fdecbb638decef7265db9c1945554
diff --git a/kde-apps/kwave/kwave-19.08.3.ebuild b/kde-apps/kwave/kwave-19.08.3.ebuild
new file mode 100644
index 000000000000..e1302c6a1b5a
--- /dev/null
+++ b/kde-apps/kwave/kwave-19.08.3.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.60.0
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="Sound editor built on KDE Frameworks 5 that can edit many types of audio files"
+HOMEPAGE="http://kwave.sourceforge.net/ https://kde.org/applications/multimedia/kwave/"
+LICENSE="CC-BY-SA-3.0 CC0-1.0 GPL-2+ LGPL-2+
+	handbook? ( FDL-1.2 )
+	opus? ( BSD-2 )
+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="alsa flac mp3 opus oss pulseaudio +qtmedia vorbis"
+
+BDEPEND="
+	sys-devel/gettext
+	handbook? ( || (
+		gnome-base/librsvg
+		virtual/imagemagick-tools[png,svg]
+	) )
+"
+RDEPEND="
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	media-libs/audiofile:=
+	>=sci-libs/fftw-3
+	media-libs/libsamplerate
+	alsa? ( media-libs/alsa-lib )
+	flac? ( media-libs/flac )
+	mp3? (
+		media-libs/id3lib
+		media-libs/libmad
+		|| ( media-sound/lame media-sound/toolame media-sound/twolame )
+	)
+	qtmedia? ( >=dev-qt/qtmultimedia-${QTMIN}:5 )
+	opus? (
+		media-libs/libogg
+		media-libs/opus
+	)
+	pulseaudio? ( media-sound/pulseaudio )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+"
+DEPEND="${RDEPEND}
+	>=kde-apps/poxml-${PVCUT}:5
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+"
+
+DOCS=( AUTHORS CHANGES LICENSES README TODO )
+
+src_configure() {
+	local mycmakeargs=(
+		-DDEBUG=$(usex debug)
+		-DWITH_ALSA=$(usex alsa)
+		-DWITH_DOC=$(usex handbook)
+		-DWITH_FLAC=$(usex flac)
+		-DWITH_MP3=$(usex mp3)
+		-DWITH_OGG_VORBIS=$(usex vorbis)
+		-DWITH_OGG_OPUS=$(usex opus)
+		-DWITH_OSS=$(usex oss)
+		-DWITH_PULSEAUDIO=$(usex pulseaudio)
+		-DWITH_QT_AUDIO=$(usex qtmedia)
+	)
+
+	ecm_src_configure
+}