kde-apps/kleopatra: 22.12.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 68 insertions, 0 deletions

diff --git a/kde-apps/kleopatra/Manifest b/kde-apps/kleopatra/Manifest
index 4af07b22d200..05829049fada 100644
--- a/kde-apps/kleopatra/Manifest
+++ b/kde-apps/kleopatra/Manifest
@@ -1,2 +1,3 @@
 DIST kleopatra-22.08.3.tar.xz 2378124 BLAKE2B e4eca866dbe9db52beb228119e530505b4929fec3b91a60a731c75a3eea8e041aa98bd19c4fceffce498d5b78bf422e7f8f8b376494bffbabdd94a699041d6f6 SHA512 42eb43ec94a611d7380866023eafc5b5a566ccf0f04d2ef04065c38b9f6a65d0b6dc92d06b9cca852d0c3a09a0fd91f76272b8e970f8f02d368298d8cda9ed7c
 DIST kleopatra-22.12.2.tar.xz 2576540 BLAKE2B 60475c4616c12f0b2aeca482977dc38e18e6d7eed072f2fe3db1d497d86cc34b84fd30b95eaa9564d95f845294d514ab2a7168d2d9b38aaa1b5bea104c7f1b6c SHA512 72f14429172422228eb2dd96eab31a6b0bfa382989669236be5f3cb81751d96e958b47b7a3b4a83bb56819bcbfb80397172407e7a84e7370d4f68eb4e74ad9f0
+DIST kleopatra-22.12.3.tar.xz 2579704 BLAKE2B e82bd88040185d87a418175f3446b8d6327c3d42fa37f055d735a2769458b120a04e0e3137bd246c62496138f8201ed68a64aa8185e14854dd4c7d01bd2a121b SHA512 da674a693111279f3b54ab05301562306472d4d834fc665924c315a92bb88101865e50aef9b1b7003015d75cc4e48fe35a29761ca4c14168e848d14b341e90c2
diff --git a/kde-apps/kleopatra/kleopatra-22.12.3.ebuild b/kde-apps/kleopatra/kleopatra-22.12.3.ebuild
new file mode 100644
index 000000000000..0fde36e08bae
--- /dev/null
+++ b/kde-apps/kleopatra/kleopatra-22.12.3.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+ECM_TEST="forceoptional"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.101.0
+QTMIN=5.15.5
+VIRTUALX_REQUIRED="test"
+inherit ecm gear.kde.org
+
+DESCRIPTION="Certificate manager and GUI for OpenPGP and CMS cryptography"
+HOMEPAGE="https://apps.kde.org/kleopatra/"
+
+LICENSE="GPL-2+ handbook? ( FDL-1.2+ )"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="pim"
+
+# tests completely broken, bug #641720
+RESTRICT="test"
+
+DEPEND="
+	>=app-crypt/gpgme-1.16.0:=[cxx,qt5]
+	dev-libs/libassuan
+	dev-libs/libgpg-error
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/kmime-${PVCUT}:5
+	>=kde-apps/libkleo-${PVCUT}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	pim? (
+		>=kde-apps/kidentitymanagement-${PVCUT}:5
+		>=kde-apps/kmailtransport-${PVCUT}:5
+	)
+"
+RDEPEND="${DEPEND}
+	>=app-crypt/gnupg-2.1
+	app-crypt/paperkey
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package pim KF5IdentityManagement)
+		$(cmake_use_find_package pim KF5MailTransport)
+		$(cmake_use_find_package pim KF5MailTransportAkonadi)
+	)
+	ecm_src_configure
+}