gui-wm/wayfire: add 0.9.0

Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>

2 files changed, 99 insertions, 0 deletions

diff --git a/gui-wm/wayfire/Manifest b/gui-wm/wayfire/Manifest
index d2482b440895..74a3981aec2f 100644
--- a/gui-wm/wayfire/Manifest
+++ b/gui-wm/wayfire/Manifest
@@ -1 +1,2 @@
 DIST wayfire-0.8.1.tar.xz 856364 BLAKE2B 1b596b28878789ca26eeb57c6c24e0b69508731de2144e1477f8071b41f17757b2125f2f4f99670ca8b7f85172a9f641b9be1f9190eeff5b261bcc2df1bec4ab SHA512 7bce5656b6a7a7fe53b37492465dee3e591eb386666fdd3d6876f4a589f059510fb2d0c0a326df260ca6a293edf4ba43bb55f813e85d4d2d38d6ef1319280254
+DIST wayfire-0.9.0.tar.xz 875584 BLAKE2B d7f07d7ff8a54437dc5b69e27dcfadecbd3426993e88f68f4af376bbbde08c8ea76646a361d4228ae8ee21e03c3ebe5562b80ec9d3aecde03fb653135fec8645 SHA512 572bfbe1821490842eae33285a0a5607f70b96b0d5b994246ffe6f0bd74ef03d8d699f3f429bff4d376a0a9390312aa67332e8f614fefa2400e0b844b2d74ab9
diff --git a/gui-wm/wayfire/wayfire-0.9.0.ebuild b/gui-wm/wayfire/wayfire-0.9.0.ebuild
new file mode 100644
index 000000000000..4d9595e505b1
--- /dev/null
+++ b/gui-wm/wayfire/wayfire-0.9.0.ebuild
@@ -0,0 +1,98 @@
+# Copyright 2019-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+DESCRIPTION="compiz like 3D wayland compositor"
+HOMEPAGE="https://github.com/WayfireWM/wayfire"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/WayfireWM/${PN}.git"
+	SLOT="0/0.10"
+else
+	SRC_URI="https://github.com/WayfireWM/${PN}/releases/download/v${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm64 ~riscv"
+	SLOT="0/$(ver_cut 1-2)"
+fi
+
+LICENSE="MIT"
+IUSE="+dbus +gles3 test X"
+RESTRICT="!test? ( test )"
+
+# bundled wlroots has the following dependency string according to included headers.
+# wlroots[drm,gles2-renderer,libinput,x11-backend?,X?]
+# enable x11-backend with X and vice versa
+CDEPEND="
+	dev-cpp/nlohmann_json
+	dev-libs/glib:2
+	dev-libs/libevdev
+	dev-libs/libinput:=
+	dev-libs/wayland
+	>=dev-libs/wayland-protocols-1.12
+	gui-libs/wf-config:${SLOT}
+	gui-libs/wlroots:0/17[drm(+),libinput(+),x11-backend,X?]
+	media-libs/glm
+	media-libs/libglvnd
+	media-libs/libjpeg-turbo:=
+	media-libs/libpng:=
+	x11-libs/cairo
+	x11-libs/libxkbcommon
+	x11-libs/pango
+	x11-libs/pixman
+	dbus? ( sys-apps/dbus )
+	X? ( x11-libs/libxcb:= )
+"
+
+RDEPEND="
+	${CDEPEND}
+	x11-misc/xkeyboard-config
+"
+DEPEND="
+	${CDEPEND}
+	test? ( dev-cpp/doctest )
+"
+BDEPEND="
+	dev-util/wayland-scanner
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+
+	local dbusrunsession=$(usev dbus dbus-run-session)
+	sed -e "s:@EPREFIX@:${EPREFIX}:g" -e "s:@DBUS_RUN_SESSION@:${dbusrunsession}:" \
+		"${FILESDIR}"/wayfire-session-2 > "${T}"/wayfire-session || die
+	sed -e "s:@EPREFIX@:${EPREFIX}:" \
+		"${FILESDIR}"/wayfire-session.desktop > "${T}"/wayfire-session.desktop || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature test tests)
+		$(meson_feature X xwayland)
+		$(meson_use gles3 enable_gles32)
+		-Duse_system_wfconfig=enabled
+		-Duse_system_wlroots=enabled
+	)
+
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	dobin "${T}"/wayfire-session
+
+	insinto "/usr/share/wayland-sessions/"
+	insopts -m644
+	doins wayfire.desktop
+	doins "${T}"/wayfire-session.desktop
+
+	insinto "/usr/share/wayfire/"
+	doins wayfire.ini
+
+	insinto "/etc"
+	doins "${FILESDIR}"/wayfire.env
+}