gnome-base/gnome-control-center: bump to 3.24.4, adapt patchset

Also remove QA_CONFIGURE_OPTIONS=".*", as I can't see any nested configure
in current versions.

Upstream fixed udev without gtk-wayland differently, by not building the
sources at all without wayland, as it's only used for wayland specific code.
As such, instead of needing a patch to the udev source file that adds
GDK_WINDOWING_WAYLAND, we instead simply need to adapt the wayland
optionality patch to set the added HAVE_WAYLAND AM_CONDITIONAL as
appropriate.

Package-Manager: Portage-2.3.28, Repoman-2.3.9

2 files changed, 159 insertions, 0 deletions

diff --git a/gnome-base/gnome-control-center/Manifest b/gnome-base/gnome-control-center/Manifest
index d48c3d2524fd..83532ec5cec0 100644
--- a/gnome-base/gnome-control-center/Manifest
+++ b/gnome-base/gnome-control-center/Manifest
@@ -1,2 +1,4 @@
 DIST gnome-control-center-3.24.2-patchset.tar.xz 8496 BLAKE2B 8bdbfcef3917ec12e82e7a5ea163f14954f9793b806c4a827620d1f693220527540f1b8a8ac0f121dae0bc8fc687f1974544b35cccd0b9e50474386c28d9ddbf SHA512 967258cf003c013881a2555be7624bad227d898cff72fe2899243692f7a06730e5dc79a849728cce6f9a7234a74b2b8433d1689c2846e8389eb9813fe5df1da1
 DIST gnome-control-center-3.24.3.tar.xz 7302120 BLAKE2B 026ad3bb34c2bfc2f7a6d398a3c47bc3f620a3f947a0cb43336b437b4926e7a360e287d6020dc0e82eda43955cfb38ffcd7ed94593adac119d7413f63bc437c8 SHA512 70b827f70fb95e8db0ee01e3ba80242dfdb0f90e31c391ca470c372cb6c8626f054e1e5b79e954935e9b567564129b80957091039e16e921e1c93b3d584c71cb
+DIST gnome-control-center-3.24.4-patchset.tar.xz 8076 BLAKE2B e70086987957b4c33fff6d3b5038ffc260fc47520de4606fa96a0993cee4eea699bb57e8c0a6406e7d5c99adde702351d6462bf0594398f48f6ba4c9bc217417 SHA512 6228bffb71b61a100248f2f3ffc659532e9a067579d0dcf869e58ba9fb5d0b3e745a3bda2a92caa5bc86f8809885268b543f6863262dc6fef52b61e74eaef927
+DIST gnome-control-center-3.24.4.tar.xz 7320232 BLAKE2B 29a5860b8cc27f161451ae8c053db1d28e8c5f8714cbccac7674c00689569ac4e51f7deb0a341e0868b1467a095f87d685ea0ec733f69274f02ecaf5badfef6e SHA512 34a59d4d89971054b1f54e7a7e3cbc3c306a3fbe3cc94adf1241ad37076a6179c93f04a95e51e57982eda57187e578005060d711a5d955734d5a138e61b3598a
diff --git a/gnome-base/gnome-control-center/gnome-control-center-3.24.4.ebuild b/gnome-base/gnome-control-center/gnome-control-center-3.24.4.ebuild
new file mode 100644
index 000000000000..f2cb4239c171
--- /dev/null
+++ b/gnome-base/gnome-control-center/gnome-control-center-3.24.4.ebuild
@@ -0,0 +1,157 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+GNOME2_EAUTORECONF="yes"
+
+inherit bash-completion-r1 gnome2
+
+DESCRIPTION="GNOME's main interface to configure various aspects of the desktop"
+HOMEPAGE="https://git.gnome.org/browse/gnome-control-center/"
+SRC_URI+=" https://dev.gentoo.org/~leio/distfiles/${P}-patchset.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="2"
+IUSE="+bluetooth +colord +cups debug +gnome-online-accounts +ibus input_devices_wacom kerberos networkmanager v4l wayland"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~x86-solaris"
+
+# gnome-session-2.91.6-r1 is needed so that 10-user-dirs-update is run at login
+# g-s-d[policykit] needed for bug #403527
+# kerberos unfortunately means mit-krb5; build fails with heimdal
+# udev could be made optional, only conditions gsd-device-panel
+# (mouse, keyboards, touchscreen, etc)
+# display panel requires colord and gnome-settings-daemon[colord]
+# printer panel requires cups and smbclient (the latter is not patch yet to be separately optional)
+COMMON_DEPEND="
+	>=dev-libs/glib-2.44.0:2[dbus]
+	>=x11-libs/gdk-pixbuf-2.23.0:2
+	>=x11-libs/gtk+-3.22.0:3[X,wayland?]
+	>=gnome-base/gsettings-desktop-schemas-3.21.4
+	>=gnome-base/gnome-desktop-3.21.2:3=
+	>=gnome-base/gnome-settings-daemon-3.23.90[colord,policykit]
+	>=x11-misc/colord-0.1.34:0=
+
+	>=dev-libs/libpwquality-1.2.2
+	dev-libs/libxml2:2
+	gnome-base/libgtop:2=
+	media-libs/fontconfig
+	>=sys-apps/accountsservice-0.6.39
+
+	>=media-libs/libcanberra-0.13[gtk3]
+	>=media-sound/pulseaudio-2[glib]
+	>=sys-auth/polkit-0.97
+	>=sys-power/upower-0.99:=
+
+	virtual/libgudev
+	x11-apps/xmodmap
+	x11-libs/cairo
+	x11-libs/libX11
+	x11-libs/libXxf86misc
+	>=x11-libs/libXi-1.2
+
+	bluetooth? ( >=net-wireless/gnome-bluetooth-3.18.2:= )
+	colord? (
+		net-libs/libsoup:2.4
+		>=x11-misc/colord-0.1.34:0=
+		>=x11-libs/colord-gtk-0.1.24 )
+	cups? (
+		>=net-print/cups-1.7[dbus]
+		>=net-fs/samba-4.0.0[client]
+	)
+	gnome-online-accounts? (
+		>=media-libs/grilo-0.3.0:0.3=
+		>=net-libs/gnome-online-accounts-3.21.5:= )
+	ibus? ( >=app-i18n/ibus-1.5.2 )
+	kerberos? ( app-crypt/mit-krb5 )
+	networkmanager? (
+		>=gnome-extra/nm-applet-1.2.0
+		>=net-misc/networkmanager-1.2.0:=[modemmanager]
+		>=net-misc/modemmanager-0.7.990 )
+	v4l? (
+		media-libs/clutter-gtk:1.0
+		>=media-video/cheese-3.5.91 )
+	input_devices_wacom? (
+		>=dev-libs/libwacom-0.7
+		>=media-libs/clutter-1.11.3:1.0
+		media-libs/clutter-gtk:1.0
+		>=x11-libs/libXi-1.2 )
+"
+# <gnome-color-manager-3.1.2 has file collisions with g-c-c-3.1.x
+# libgnomekbd needed only for gkbd-keyboard-display tool
+#
+# mouse panel needs a concrete set of X11 drivers at runtime, bug #580474
+# Also we need newer driver versions to allow wacom and libinput drivers to
+# not collide
+#
+# system-config-printer provides org.fedoraproject.Config.Printing service and interface
+# cups-pk-helper provides org.opensuse.cupspkhelper.mechanism.all-edit policykit helper policy
+RDEPEND="${COMMON_DEPEND}
+	|| ( >=sys-apps/systemd-31 ( app-admin/openrc-settingsd sys-auth/consolekit ) )
+	x11-themes/adwaita-icon-theme
+	colord? ( >=gnome-extra/gnome-color-manager-3 )
+	cups? (
+		app-admin/system-config-printer
+		net-print/cups-pk-helper )
+	input_devices_wacom? ( gnome-base/gnome-settings-daemon[input_devices_wacom] )
+	>=gnome-base/libgnomekbd-3
+	wayland? ( dev-libs/libinput )
+	!wayland? (
+		>=x11-drivers/xf86-input-libinput-0.19.0
+		input_devices_wacom? ( >=x11-drivers/xf86-input-wacom-0.33.0 ) )
+
+	!<gnome-base/gdm-2.91.94
+	!<gnome-extra/gnome-color-manager-3.1.2
+	!gnome-extra/gnome-media[pulseaudio]
+	!<gnome-extra/gnome-media-2.32.0-r300
+	!<net-wireless/gnome-bluetooth-3.3.2
+"
+# PDEPEND to avoid circular dependency
+PDEPEND=">=gnome-base/gnome-session-2.91.6-r1"
+
+DEPEND="${COMMON_DEPEND}
+	x11-proto/xproto
+	x11-proto/xf86miscproto
+	x11-proto/kbproto
+
+	dev-libs/libxml2:2
+	dev-libs/libxslt
+	>=dev-util/intltool-0.40.1
+	>=sys-devel/gettext-0.17
+	virtual/pkgconfig
+
+	gnome-base/gnome-common
+	sys-devel/autoconf-archive
+"
+# Needed for autoreconf
+#	gnome-base/gnome-common
+#	sys-devel/autoconf-archive
+
+PATCHES=(
+	# Makes some panels and dependencies optional; requires eautoreconf
+	# https://bugzilla.gnome.org/686840, 697478, 700145
+	# Fix some absolute paths to be appropriate for Gentoo
+	"${WORKDIR}"/patches/
+)
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-update-mimedb \
+		--disable-static \
+		--enable-documentation \
+		$(use_enable bluetooth) \
+		$(use_enable colord color) \
+		$(use_enable cups) \
+		$(usex debug --enable-debug=yes ' ') \
+		$(use_enable gnome-online-accounts goa) \
+		$(use_enable ibus) \
+		$(use_enable kerberos) \
+		$(use_enable networkmanager) \
+		$(use_with v4l cheese) \
+		$(use_enable input_devices_wacom wacom) \
+		$(use_enable wayland)
+}
+
+src_install() {
+	gnome2_src_install completiondir="$(get_bashcompdir)"
+}