games-action/extreme-tuxracer: bump up to 0.8.0

Reported-by: Agostino Sarubbo
Closes: https://bugs.gentoo.org/739076
Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>

1 files changed, 48 insertions, 0 deletions

diff --git a/games-action/extreme-tuxracer/extreme-tuxracer-0.8.0.ebuild b/games-action/extreme-tuxracer/extreme-tuxracer-0.8.0.ebuild
new file mode 100644
index 000000000000..7bb586bdbb0c
--- /dev/null
+++ b/games-action/extreme-tuxracer/extreme-tuxracer-0.8.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools desktop xdg-utils
+
+DESCRIPTION="High speed arctic racing game based on Tux Racer"
+HOMEPAGE="https://sourceforge.net/p/extremetuxracer/wiki/Home/"
+SRC_URI="https://download.sourceforge.net/extremetuxracer/etr-${PV}.tar.xz -> ${P}.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="
+	>=media-libs/libsfml-2.4:0=
+	virtual/glu
+	virtual/opengl
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}/etr-${PV/_/}"
+
+src_prepare() {
+	default
+	# kind of ugly in there so we'll do it ourselves
+	sed -i -e '/SUBDIRS/s/resources doc//' Makefile.am || die
+	eautoreconf
+}
+
+src_install() {
+	default
+	dodoc doc/{code,courses_events,guide,score_algorithm}
+	doicon -s 48 resources/etr.png
+	doicon -s scalable resources/etr.svg
+	domenu resources/etr.desktop
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}