dev-vcs/gitg: bump to 3.26.0 for a couple bugfixes and accepting libgit2-glib-0.26

This shouldn't be considered part of GNOME 3.26; it just fixes a crash on popup menu
triggered by keyboard instead of mouse, another small fix and raising of accepted
libgit2-glib version (without any changes necessary for that besides configure)

Package-Manager: Portage-2.3.6, Repoman-2.3.2

2 files changed, 85 insertions, 0 deletions

diff --git a/dev-vcs/gitg/Manifest b/dev-vcs/gitg/Manifest
index 0145e5aef7fc..d9d8884b8f59 100644
--- a/dev-vcs/gitg/Manifest
+++ b/dev-vcs/gitg/Manifest
@@ -1,2 +1,3 @@
 DIST gitg-3.22.0.tar.xz 1507056 SHA256 ba6895f85c18748294075980a5e03e0936ad4e84534dbb0d8f9e29aa874ddeaf SHA512 2d59af3bb725c111966544ed6977002a901a862f0280c9acf117b2b613b00d889039ea780cad83bd624de5099256e48b99cdf0421362f154a8380e98f5f977da WHIRLPOOL 088819c4580c14268f420a6f745cc68f5ec0e22c88ce318792071773dc8ecf0a1e99d78639ec0dc561ba22366d8f9a1673be4c939cd5074c6c335fc03f86a819
 DIST gitg-3.24.0.tar.xz 1703132 SHA256 3e4ec4a8ae83bc7ced8c7610927ade70e37daa5e8beeb4f357a6ea30b4cc951e SHA512 3200ec39e05e5c7deae62e7c8938cb16ea3e63c034a5520b7e1ca692ce660671e7548650a6d91b29410303d027048b0f1f85206cc484a316cae702898b4c8d73 WHIRLPOOL 21032788792674a0426b312912a4d6cbef253ed866dac6492193fc9f0ab600bec46dcaba7e3532a1f00ae8c0090d82e6be70119c999672816e2a52c2f0634f15
+DIST gitg-3.26.0.tar.xz 1551308 SHA256 26730d437d6a30d6e341b9e8da99d2134dce4b96022c195609f45062f82b54d5 SHA512 782aa02e2f0f4d8c86ad726045502d545877d835f0449d2ec646d93a78bbfa50f84662d3a437c922eb168b2737c00ec088dc2c73487742f332e3910f041b519d WHIRLPOOL f3300bdbe1190f0275f93e9b57eb7318de19f4ae42caf4d2e979245a27e95ec80d54a2b10b7a6b7000ef8214ddb8e09ff981b7191089c3191a6eca9da7048a39
diff --git a/dev-vcs/gitg/gitg-3.26.0.ebuild b/dev-vcs/gitg/gitg-3.26.0.ebuild
new file mode 100644
index 000000000000..d2f5cf8684e8
--- /dev/null
+++ b/dev-vcs/gitg/gitg-3.26.0.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python{3_4,3_5} )
+VALA_MIN_API_VERSION="0.32" # Needed when gtk+-3.20 is found
+
+inherit gnome2 pax-utils python-r1 vala
+
+DESCRIPTION="git repository viewer for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Gitg"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+
+IUSE="glade +python"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+# test if unbundling of libgd is possible
+# Currently it seems not to be (unstable API/ABI)
+RDEPEND="
+	app-crypt/libsecret
+	dev-libs/libgee:0.8[introspection]
+	>=app-text/gtkspell-3.0.3:3
+	>=dev-libs/glib-2.38:2[dbus]
+	>=dev-libs/gobject-introspection-0.10.1:=
+	dev-libs/libgit2:=[threads]
+
+	>=dev-libs/libgit2-glib-0.25.0[ssh]
+	<dev-libs/libgit2-glib-0.27.0
+
+	>=dev-libs/libpeas-1.5.0[gtk]
+	>=dev-libs/libxml2-2.9.0:2
+	net-libs/libsoup:2.4
+	>=gnome-base/gsettings-desktop-schemas-0.1.1
+	>=x11-libs/gtk+-3.20.0:3
+	>=x11-libs/gtksourceview-3.10:3.0
+	x11-themes/adwaita-icon-theme
+	glade? ( >=dev-util/glade-3.2:3.10 )
+	python? (
+		${PYTHON_DEPS}
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}
+	$(vala_depend)
+	>=dev-libs/libgit2-glib-0.24.4[vala]
+	>=dev-util/intltool-0.40
+	gnome-base/gnome-common
+	>=sys-devel/gettext-0.17
+	virtual/pkgconfig
+"
+
+pkg_setup() {
+	use python && [[ ${MERGE_TYPE} != binary ]] && python_setup
+}
+
+src_prepare() {
+	gnome2_src_prepare
+	vala_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-static \
+		--disable-deprecations \
+		$(use_enable glade glade-catalog) \
+		$(use_enable python)
+}
+
+src_install() {
+	# -j1: bug #???
+	gnome2_src_install -j1
+
+	if use python ; then
+		install_gi_override() {
+			python_moduleinto "$(python_get_sitedir)/gi/overrides"
+			python_domodule "${S}"/libgitg-ext/GitgExt.py
+		}
+		python_foreach_impl install_gi_override
+	fi
+}