dev-ruby/fast_gettext: add 1.8.0

Signed-off-by: Hans de Graaff <graaff@gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

1 files changed, 55 insertions, 0 deletions

diff --git a/dev-ruby/fast_gettext/fast_gettext-1.8.0.ebuild b/dev-ruby/fast_gettext/fast_gettext-1.8.0.ebuild
new file mode 100644
index 000000000000..5b90552bd7b2
--- /dev/null
+++ b/dev-ruby/fast_gettext/fast_gettext-1.8.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+USE_RUBY="ruby23 ruby24 ruby25"
+
+RUBY_FAKEGEM_TASK_DOC=""
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG Readme.md"
+
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+
+inherit ruby-fakegem
+
+DESCRIPTION="GetText but 3.5x faster, 560x less memory, clean namespace and threadsave!"
+HOMEPAGE="https://github.com/grosser/fast_gettext"
+SRC_URI="https://github.com/grosser/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86"
+IUSE=""
+
+ruby_add_bdepend "test? ( dev-ruby/bundler )"
+
+all_ruby_prepare() {
+	rm Gemfile.lock || die
+
+	# Remove jeweler and bump from Gemfile since they are not needed for tests.
+	sed -i -e '/jeweler/d' -e '/bump/d' -e '/appraisal/d' Gemfile || die
+
+	# Avoid unneeded dependency on git and development dependencies.
+	sed -e '/git ls-files/ s:^:#:' \
+		-e '/\(wwtd\|bump\|sqlite3\|activerecord\|i18n\)/ s:^:#:' \
+		-i fast_gettext.gemspec || die
+
+	# Avoid a test dependency on activerecord since this is now in the
+	# dependency tree for app-admin/puppet and many arches don't have
+	# rails keyworded.
+	sed -i -e '/active_record/ s:^:#:' spec/spec_helper.rb || die
+	rm -f spec/fast_gettext/translation_repository/db_spec.rb || die
+	sed -i -e '/works with DB repository/,/^    end/ s:^:#:' spec/fast_gettext/storage_spec.rb || die
+	sed -i -e '/with i18n loaded/,/^  end/ s:^:#:' spec/fast_gettext/vendor/string_spec.rb || die
+
+	# Don't run a test that requires safe mode which we can't provide
+	# due to insecure directory settings for the portage dir. This spec
+	# also calls out to ruby which won't work with different ruby
+	# implementations.
+	sed -i -e '/can work in SAFE mode/,/^  end/ s:^:#:' spec/fast_gettext/translation_repository/mo_spec.rb || die
+}
+
+each_ruby_prepare() {
+	# Make sure the right ruby interpreter is used
+	sed -i -e "s:bundle exec ruby:bundle exec ${RUBY}:" spec/fast_gettext/vendor/*spec.rb || die
+}