dev-qt/qtconnectivity: add 6.7.2

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

2 files changed, 73 insertions, 0 deletions

diff --git a/dev-qt/qtconnectivity/Manifest b/dev-qt/qtconnectivity/Manifest
index b58172ae6368..4a65b4ebc1a7 100644
--- a/dev-qt/qtconnectivity/Manifest
+++ b/dev-qt/qtconnectivity/Manifest
@@ -1 +1,2 @@
 DIST qtconnectivity-everywhere-src-6.7.1.tar.xz 1061900 BLAKE2B 30cb15ba6a0e08fccfd0f3ce9a9ec36a0902e3fa15bdd0791e166371c6baa31438c141c7bf5c57de0287eeee04bae87aaaf4800eeaa3062ab23d541e577cce3a SHA512 28496a2a7338f71bb51fbd8fa1b23e4e2e14e6fefc6249ce0eeae8d19b7740a70eed1c312c5d5a79344330001592acd4048c134382cdc168cf4d30e9760dbdc2
+DIST qtconnectivity-everywhere-src-6.7.2.tar.xz 1061952 BLAKE2B 2b46b255f5ca5ab7b5363f6e3584dd4318a4e4d120c8595b309fba1354d9e1c763d9fa8e84b22f5c342204b2849b27d08a7f5dbd9d00533e150c2b8fb6561db3 SHA512 381098e406ac18d87d34eb9087d1655c16e604059d69b77c04df9d444cefc77630a212f52b0fc2a1573c524044aa1837379d70460e152cd353731e52c4bd0e67
diff --git a/dev-qt/qtconnectivity/qtconnectivity-6.7.2.ebuild b/dev-qt/qtconnectivity/qtconnectivity-6.7.2.ebuild
new file mode 100644
index 000000000000..718408e17903
--- /dev/null
+++ b/dev-qt/qtconnectivity/qtconnectivity-6.7.2.ebuild
@@ -0,0 +1,72 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Bluetooth and NFC support library for the Qt6 framework"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+fi
+
+IUSE="+bluetooth nfc smartcard"
+REQUIRED_USE="|| ( bluetooth nfc )"
+
+RDEPEND="
+	~dev-qt/qtbase-${PV}:6[network]
+	bluetooth? (
+		~dev-qt/qtbase-${PV}:6[dbus]
+		net-wireless/bluez:=
+	)
+	nfc? (
+		smartcard? ( sys-apps/pcsc-lite )
+	)
+"
+DEPEND="${RDEPEND}"
+
+CMAKE_SKIP_TESTS=(
+	# most hardware tests are auto-skipped, but some still misbehave
+	# if bluez/hardware is available (generally tests here may not be
+	# very relevant without hardware, lists may need to be extended)
+	tst_qbluetoothlocaldevice
+	tst_qbluetoothserver
+	tst_qbluetoothservicediscoveryagent
+	tst_qbluetoothserviceinfo
+	tst_qlowenergycontroller
+)
+
+src_prepare() {
+	qt6-build_src_prepare
+
+	use bluetooth ||
+		sed -i '/add_subdirectory(bluetooth)/d' src/CMakeLists.txt || die
+	use nfc ||
+		sed -i '/add_subdirectory(nfc)/d' src/CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(usev nfc $(qt_feature smartcard pcsclite))
+	)
+
+	qt6-build_src_configure
+}
+
+src_install() {
+	qt6-build_src_install
+
+	# broken (unnecessary) symlink due to add_app() being used over add_tool()
+	use !bluetooth || rm -- "${ED}"/usr/bin/sdpscanner6 || die
+
+	if use test; then
+		local delete=( # sigh
+			"${D}${QT6_BINDIR}"/bluetoothtestdevice
+			"${D}${QT6_BINDIR}"/bttestui
+			"${D}${QT6_BINDIR}"/qlecontroller-server
+		)
+		# using -f given not tracking which tests may be skipped or not
+		rm -f -- "${delete[@]}" || die
+	fi
+}