dev-python/virtualenv: Bump to 20.0.28

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 92 insertions, 0 deletions

diff --git a/dev-python/virtualenv/Manifest b/dev-python/virtualenv/Manifest
index 97862e67947a..754f97797d1f 100644
--- a/dev-python/virtualenv/Manifest
+++ b/dev-python/virtualenv/Manifest
@@ -1,2 +1,3 @@
 DIST virtualenv-16.7.10.tar.gz 5116776 BLAKE2B 42f0a4b4330850b504f8febd991ef6ecdcbb0821efdd94ca324a8cc34a68a760a8a98de97f0cb2384d8e6cbb0ce8f261995c6433886444e29b75ba0ce09ca12c SHA512 f06d7c354ce1910f04dbcbe1a77e60392653bbe4f638bafbe9284454db2c0e5d63cf9159201d0916fc01aaba91d45fb733b63096c38517fcd83fd00ed8b26d28
 DIST virtualenv-20.0.27.tar.gz 8265353 BLAKE2B 31e0a5fa11d988b5340b130615dc5095a61321393fdc4f72fd88e70d88bc7922c2f8f289b995fb623d2fe900a7da8f012433d4a7bb2ecd7ab53810865e05ea2b SHA512 812a17d1461c8e62568f345aba0722204dd22d0d149720d00e37712a34a9d2d614e1b854f07d7e89e1eb6e915ca3f90e8e81fb9c2442ed637efdc6b2120153d7
+DIST virtualenv-20.0.28.tar.gz 8265900 BLAKE2B ee07267a0fff59abe4b51091bbc8ff980ad5419375a1049e943622af174a1b533610f6a80876b75d36c3edbd1851767db08085bfd0db8215fa99495ea9a49bb1 SHA512 4984ce046e0787bd44feb3b30f01d53f1840722693643cec086ac3ee61c471ebf619ea31b41a7e20cfd792d59a7ba19ef64b3a6bf3950891bdf15a49747e4712
diff --git a/dev-python/virtualenv/virtualenv-20.0.28.ebuild b/dev-python/virtualenv/virtualenv-20.0.28.ebuild
new file mode 100644
index 000000000000..a8a3d84852f0
--- /dev/null
+++ b/dev-python/virtualenv/virtualenv-20.0.28.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{2_7,3_{6..9}} pypy3 )
+DISTUTILS_USE_SETUPTOOLS=manual
+
+inherit distutils-r1
+
+DESCRIPTION="Virtual Python Environment builder"
+HOMEPAGE="
+	https://virtualenv.pypa.io/en/stable/
+	https://pypi.org/project/virtualenv/
+	https://github.com/pypa/virtualenv/
+"
+SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/appdirs-1.4.3[${PYTHON_USEDEP}]
+	>=dev-python/distlib-0.3.1[${PYTHON_USEDEP}]
+	>=dev-python/filelock-3[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-41[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/contextlib2-0.6.0[${PYTHON_USEDEP}]
+		>=dev-python/pathlib2-2.3.3[${PYTHON_USEDEP}]
+	' -2)
+	$(python_gen_cond_dep '
+		>=dev-python/importlib_metadata-0.12[${PYTHON_USEDEP}]
+	' -2 python3_{6,7} pypy3)
+	$(python_gen_cond_dep '
+		>=dev-python/importlib_resources-1.0[${PYTHON_USEDEP}]
+	' -2 python3_6 pypy3)"
+# coverage is used somehow magically in virtualenv, maybe it actually
+# tests something useful
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		$(python_gen_cond_dep '
+			dev-python/coverage[${PYTHON_USEDEP}]
+			dev-python/flaky[${PYTHON_USEDEP}]
+			>=dev-python/pip-20.0.2[${PYTHON_USEDEP}]
+			>=dev-python/pytest-5[${PYTHON_USEDEP}]
+			>=dev-python/pytest-freezegun-0.4.1[${PYTHON_USEDEP}]
+			>=dev-python/pytest-mock-2.0.0[${PYTHON_USEDEP}]
+			>=dev-python/pytest-timeout-1.3.4[${PYTHON_USEDEP}]
+			dev-python/wheel[${PYTHON_USEDEP}]
+			>=dev-python/packaging-20.0[${PYTHON_USEDEP}]
+		' 'python3*')
+	)"
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx_rtd_theme \
+	dev-python/towncrier
+
+src_prepare() {
+	# we don't have xonsh
+	rm tests/unit/activation/test_xonsh.py || die
+	# require internet
+	sed -e 's:test_seed_link_via_app_data:_&:' \
+		-i tests/unit/seed/embed/test_boostrap_link_via_app_data.py || die
+	# TODO: investigate
+	sed -e 's:test_cross_major:_&:' \
+		-i tests/unit/create/test_creator.py || die
+
+	distutils-r1_src_prepare
+}
+
+src_configure() {
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+	# TODO: fix/skip with more granularity tests on pypy3
+	if has "${EPYTHON}" pypy3 python2.7; then
+		einfo "Skipping broken tests on pypy3"
+		continue
+	fi
+
+	distutils_install_for_testing
+
+	pytest -vv || die "Tests fail with ${EPYTHON}"
+}