dev-python/tox: Bump to 4.9.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 85 insertions, 0 deletions

diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index 74742b83c3a4..9f1669b2786c 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -8,3 +8,4 @@ DIST tox-4.6.3.tar.gz 172585 BLAKE2B 14d895a516fdb1b767c922633185b31904149e7fea9
 DIST tox-4.6.4.tar.gz 172650 BLAKE2B 84164dbb02002d398e779b0c5e4617213fbfc711ded95faddde93711549eab9e69675f0a459ce60ba8357baf4e7d361f86b4cb85818972e5d018a61db179ba1a SHA512 b6a4673ea58e21b5e8b3d1330244d46ac7a36563a089b2e03cfcd7039386ab6afc437ebf4c516bbe373133a7beb54ebb380d39ab126be69f3601226f2273f3c2
 DIST tox-4.7.0.tar.gz 172893 BLAKE2B 9611cbff7937e859ad923d40978804eede6eb372868c7af85597644a3568e775627361faa64587aa44c9e1e3bcf565fb4c6956d73fe973c258c90f005f5e5b14 SHA512 17c010af1dd402dd1dff86dca9154be16212bdbdafa4d83f6337e5c4ebd6f7256b7cf813ac8bb22d755873c89179caeecbaeed05c7e6dd6903251c3548fa8042
 DIST tox-4.8.0.tar.gz 173370 BLAKE2B 85dafc76b2dd6fb012112020c12e570904bc7d587ebaded729cabf752e14f1f04ed4f7672e52012f5abaff9a68480a2710483b0f5e0a16fbde64f009c30f0df4 SHA512 e7d4b33df31574fb5b35100e79a9a620a967aa8c4a2add474a21fffa52129429cb54485aaddb44957d75b9875afc332f69afdf8c0c598096572e2c8f83756154
+DIST tox-4.9.0.tar.gz 173479 BLAKE2B 00fc440bbcafa6e0d521ce745af0fa7b9a33196fec4f29f2dcad10079d494e3703fa06558ceb26762162687f71f7c77b386f64bdff6b4ac0a78706d2b7fd0743 SHA512 62f0cdb4d425d935315babf90ab331fb772352e68b6c67cf96f1d13007245427e67968a08073cc07a4adf850a991bbbcbff742567808ca22bc231acc1e3692e2
diff --git a/dev-python/tox/tox-4.9.0.ebuild b/dev-python/tox/tox-4.9.0.ebuild
new file mode 100644
index 000000000000..4a3b369c1b46
--- /dev/null
+++ b/dev-python/tox/tox-4.9.0.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{10..11} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="
+	https://tox.readthedocs.io/
+	https://github.com/tox-dev/tox/
+	https://pypi.org/project/tox/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/cachetools-5.3.1[${PYTHON_USEDEP}]
+	>=dev-python/chardet-5.2[${PYTHON_USEDEP}]
+	>=dev-python/colorama-0.4.6[${PYTHON_USEDEP}]
+	>=dev-python/filelock-3.12.2[${PYTHON_USEDEP}]
+	>=dev-python/packaging-23.1[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-3.10[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-1.2[${PYTHON_USEDEP}]
+	>=dev-python/pyproject-api-1.5.3[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	' 3.{9..10})
+	>=dev-python/virtualenv-20.24.3[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/hatch-vcs-0.3[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/build-0.10[${PYTHON_USEDEP}]
+		>=dev-python/distlib-0.3.6[${PYTHON_USEDEP}]
+		>=dev-python/flaky-3.7[${PYTHON_USEDEP}]
+		>=dev-python/psutil-5.9.5[${PYTHON_USEDEP}]
+		>=dev-python/pytest-mock-3.11.1[${PYTHON_USEDEP}]
+		>=dev-python/pytest-xdist-3.3.1[${PYTHON_USEDEP}]
+		>=dev-python/re-assert-1.1[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			>=dev-python/time-machine-2.10[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	# devpi_process is not packaged, and has lots of dependencies
+	cat > "${T}"/devpi_process.py <<-EOF || die
+		def IndexServer(*args, **kwargs): raise NotImplementedError()
+	EOF
+
+	local -x PYTHONPATH=${T}:${PYTHONPATH}
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_build_wheel_external
+	)
+	local EPYTEST_IGNORE=(
+		# requires devpi*
+		tests/test_provision.py
+	)
+
+	[[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[constraints-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit+requirements-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_indirect-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_constraints_indirect-True-True]'
+	)
+
+	epytest
+
+	# tox leaves a *humonogous* tempdir which easily leads to ENOSPC
+	# when running in parallel with other packages
+	rm -r "${T}"/pytest* || die
+}