dev-python/spyder: drop 5.3.1-r1

Signed-off-by: Andrew Ammerlaan <andrewammerlaan@gentoo.org>

2 files changed, 0 insertions, 204 deletions

diff --git a/dev-python/spyder/Manifest b/dev-python/spyder/Manifest
index af2d5a5acaa3..6758cec7f103 100644
--- a/dev-python/spyder/Manifest
+++ b/dev-python/spyder/Manifest
@@ -1,6 +1,4 @@
-DIST spyder-5.3.1.tar.gz 24415110 BLAKE2B 368179c6ba6d355ca56fe3eb3ed8b24be3e986f1f2d0284f0f5739bdecb21225bce10802883b54dd888da54515bd8477adf6c0d3e38a3c549bb10407534254b0 SHA512 2501ddc45df11671b1a318eb33b50788b334ab10fbafb97a9491775a0efcc6a57814672068ab84314f9cb43961d6fabd9b906fb164cd58c77b6d6ecf0d6621e6
 DIST spyder-5.3.2.gh.tar.gz 24441566 BLAKE2B dae46baf1a2673ee7449d1060302a726963424c946c9a0188ab85401c9a457fe818039ce3217ccd94ee3976b3e1a4dbb4379945862dee039ebd01ca41077846f SHA512 d1e9a83ddad6e637bef9cacc8261e9097684996661f730ff2813c2bdd72b1d58e9ae75f8a54730088761750eee6ae3d622f25fb9d0e6bca70325906cf4fc9348
 DIST spyder-5.3.3.gh.tar.gz 24443628 BLAKE2B 767b3e1d59ce650d2df0d229d94eef53bc4c7b52f5d40fd62748efeb3a756a773110aa17442403a1b37777dd39fc367164ad54cd8f767d4311caa8d3e8bf05da SHA512 7d521f8367953849233538cbfd74f1fd98da87e69dbed8076718e81cd09ae66aca84523c4ecdf0e8aeb60644791754df19f09dd244ce11e3f7decc97bb050e02
 DIST spyder-docs-9156f446a9225446a2a752ecb669cc3db30094a8.gh.tar.gz 90029977 BLAKE2B 7254da77f6d9dd24d9feb8af684d064bb92400acf1561f8a2b9423c63984c22fb3ab384174f87525c3cdb0612590fb97010e9cd1a21ae1e36ffc6d6f9babe973 SHA512 1a9609baea12059fad1e65b84c1db98e15cb3d65e1c60660a1f1ebeab5723b118d6e995a4e4219391d8aafb640da20e2a4984746e9c66893dd0cef2ea3f082f9
 DIST spyder-docs-d43d6cd46b6eb7675ec690b0dff573ca03f2e301.gh.tar.gz 90037375 BLAKE2B 2faf8d2d07b10aec750534c73ebcfc9146533db4223908ecabafb214d7e0a85416aaaf4359f95768572bbd8806f13bd707124f9585299527af5bd5bc735293d4 SHA512 00f12af5298f5b90eaf9a4ea8706b5bb29445ca344b5117801dbac54508eefa29c807e0d4f36524fb5d8b6208204533dc657da63849cadaf13f4aa3652612cb1
-DIST spyder-docs-d43d6cd46b6eb7675ec690b0dff573ca03f2e301.tar.gz 90037375 BLAKE2B 2faf8d2d07b10aec750534c73ebcfc9146533db4223908ecabafb214d7e0a85416aaaf4359f95768572bbd8806f13bd707124f9585299527af5bd5bc735293d4 SHA512 00f12af5298f5b90eaf9a4ea8706b5bb29445ca344b5117801dbac54508eefa29c807e0d4f36524fb5d8b6208204533dc657da63849cadaf13f4aa3652612cb1
diff --git a/dev-python/spyder/spyder-5.3.1-r1.ebuild b/dev-python/spyder/spyder-5.3.1-r1.ebuild
deleted file mode 100644
index 15fb63a0e467..000000000000
--- a/dev-python/spyder/spyder-5.3.1-r1.ebuild
+++ /dev/null
@@ -1,202 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{8..10} )
-DISTUTILS_USE_PEP517=setuptools
-
-inherit optfeature xdg distutils-r1
-
-# Commit of documentation to fetch
-DOCS_PV="d43d6cd46b6eb7675ec690b0dff573ca03f2e301"
-
-DESCRIPTION="The Scientific Python Development Environment"
-HOMEPAGE="
-	https://www.spyder-ide.org/
-	https://github.com/spyder-ide/spyder/
-	https://pypi.org/project/spyder/
-"
-SRC_URI="
-	https://github.com/spyder-ide/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
-	https://github.com/spyder-ide/${PN}-docs/archive/${DOCS_PV}.tar.gz -> ${PN}-docs-${DOCS_PV}.tar.gz
-"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-
-# The test suite often hangs or does not work. RESTRICTing because IMO it is
-# not worth the several hours I would have to spend every single version bump
-# checking which tests do and do not work.
-RESTRICT="test"
-
-RDEPEND="
-	>=dev-python/atomicwrites-1.2.0[${PYTHON_USEDEP}]
-	>=dev-python/chardet-2.0.0[${PYTHON_USEDEP}]
-	>=dev-util/cookiecutter-1.6.0[${PYTHON_USEDEP}]
-	>=dev-python/diff-match-patch-20181111[${PYTHON_USEDEP}]
-	>=dev-python/intervaltree-3.0.2[${PYTHON_USEDEP}]
-	>=dev-python/jellyfish-0.7[${PYTHON_USEDEP}]
-	>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
-	>=dev-python/keyring-17.0.0[${PYTHON_USEDEP}]
-	>=dev-python/nbconvert-4.0[${PYTHON_USEDEP}]
-	>=dev-python/numpydoc-0.6.0[${PYTHON_USEDEP}]
-	>=dev-python/pexpect-4.4.0[${PYTHON_USEDEP}]
-	>=dev-python/pickleshare-0.4[${PYTHON_USEDEP}]
-	>=dev-python/psutil-5.3[${PYTHON_USEDEP}]
-	>=dev-python/pygments-2.0[${PYTHON_USEDEP}]
-	>=dev-python/python-lsp-black-1.2.0[${PYTHON_USEDEP}]
-	>=dev-python/pyls-spyder-0.4.0[${PYTHON_USEDEP}]
-	>=dev-python/pyxdg-0.26[${PYTHON_USEDEP}]
-	>=dev-python/pyzmq-22.1.0[${PYTHON_USEDEP}]
-	>=dev-python/qdarkstyle-3.0.2[${PYTHON_USEDEP}]
-	<dev-python/qdarkstyle-3.1[${PYTHON_USEDEP}]
-	>=dev-python/qstylizer-0.1.10[${PYTHON_USEDEP}]
-	>=dev-python/qtawesome-1.0.2[${PYTHON_USEDEP}]
-	>=dev-python/qtconsole-5.3.0[${PYTHON_USEDEP}]
-	<dev-python/qtconsole-5.4.0[${PYTHON_USEDEP}]
-	>=dev-python/QtPy-2.1.0[${PYTHON_USEDEP},svg,webengine]
-	>=sci-libs/rtree-0.9.7[${PYTHON_USEDEP}]
-	>=dev-python/sphinx-0.6.6[${PYTHON_USEDEP}]
-	>=dev-python/spyder-kernels-2.3.1[${PYTHON_USEDEP}]
-	<dev-python/spyder-kernels-2.4.0[${PYTHON_USEDEP}]
-	>=dev-python/textdistance-4.2.0[${PYTHON_USEDEP}]
-	>=dev-python/three-merge-0.1.1[${PYTHON_USEDEP}]
-	>=dev-python/watchdog-0.10.3[${PYTHON_USEDEP}]
-"
-
-BDEPEND="
-	test? (
-		dev-python/cython[${PYTHON_USEDEP}]
-		dev-python/flaky[${PYTHON_USEDEP}]
-		dev-python/matplotlib[tk,${PYTHON_USEDEP}]
-		dev-python/pandas[${PYTHON_USEDEP}]
-		dev-python/pillow[${PYTHON_USEDEP}]
-		dev-python/pytest-lazy-fixture[${PYTHON_USEDEP}]
-		dev-python/pytest-mock[${PYTHON_USEDEP}]
-		dev-python/pytest-ordering[${PYTHON_USEDEP}]
-		dev-python/pytest-qt[${PYTHON_USEDEP}]
-		dev-python/pytest-xvfb[${PYTHON_USEDEP}]
-		dev-python/pyyaml[${PYTHON_USEDEP}]
-		dev-python/scipy[${PYTHON_USEDEP}]
-		dev-python/sympy[${PYTHON_USEDEP}]
-	)"
-
-# Based on the courtesy of Arfrever
-# This patch removes a call to update-desktop-database during build
-# This fails because access is denied to this command during build
-PATCHES=(
-	"${FILESDIR}/${PN}-5.0.0-build.patch"
-	"${FILESDIR}/${PN}-5.2.0-doc-theme-renamed.patch"
-)
-
-DOCS=(
-	"AUTHORS.txt"
-	"Announcements.md"
-	"CHANGELOG.md"
-	"CODE_OF_CONDUCT.md"
-	"CONTRIBUTING.md"
-	"NOTICE.txt"
-	"README.md"
-	"RELEASE.md"
-)
-
-distutils_enable_tests pytest
-distutils_enable_sphinx docs/doc \
-	dev-python/sphinx-panels \
-	dev-python/pydata-sphinx-theme \
-	dev-python/sphinx-multiversion
-
-python_prepare_all() {
-	# move docs into workdir
-	mv ../spyder-docs-${DOCS_PV}* docs || die
-
-	# these dependencies are packaged separately:
-	#    dev-python/spyder-kernels,
-	#    dev-python/python-lsp-server,
-	#    dev-python/qdarkstyle
-	rm -r external-deps/* || die
-	# runs against things packaged in external-deps dir
-	rm conftest.py || die
-
-	# Do not depend on pyqt5<5.16, this dependency is carried by QtPy[pyqt5]
-	# Do not depend on pyqtwebengine<5.16, this dependency is carried by QtPy[webengine]
-	# Do not depend on parso and jedi, this is dependency is carried in python-lsp-server
-	# Do not depend on python-lsp-server, this dependency is carried in pyls-spyder
-	# Do not depend on ipython, this dependency is carried in spyder-kernels
-	# The explicit version requirements only make things more complicated, if e.g.
-	# pyls-spyder gains compatibility with a newer version of python-lsp-server
-	# in a new release it will take time for this information to propagate into
-	# the next spyder release. So just remove the dependency and let the other
-	# ebuilds handle the version requirements to speed things up and prevent
-	# issues such as Bug 803269.
-	sed -i \
-		-e '/pyqt5/d' \
-		-e '/pyqtwebengine/d' \
-		-e '/python-lsp-server/d' \
-		-e '/parso/d' \
-		-e '/jedi/d' \
-		-e '/pylint/d' \
-		-e '/ipython/d' \
-			requirements/conda.txt || die
-	sed -i \
-		-e "/'pyqt5[ 0-9<=>.,]*',/d" \
-		-e "/'pyqtwebengine[ 0-9<=>.,]*',/d" \
-		-e "/'python-lsp-server\[all\][ 0-9<=>.,]*',/d" \
-		-e "/'parso[ 0-9<=>.,]*',/d" \
-		-e "/'jedi[ 0-9<=>.,]*',/d" \
-		-e "/'pylint[ 0-9<=>.,]*',/d" \
-		-e "/'ipython[ 0-9<=>.,]*',/d" \
-			setup.py || die
-	sed -i \
-		-e "/^PYLS_REQVER/c\PYLS_REQVER = '>=0.0.1'" \
-		-e "/^PYLSP_REQVER/c\PYLSP_REQVER = '>=0.0.1'" \
-		-e "/^PARSO_REQVER/c\PARSO_REQVER = '>=0.0.1'" \
-		-e "/^JEDI_REQVER/c\JEDI_REQVER = '>=0.0.1'" \
-		-e "/^PYLINT_REQVER/c\PYLINT_REQVER = '>=0.0.1'" \
-		-e "/^IPYTHON_REQVER/c\IPYTHON_REQVER = '>=0.0.1'" \
-			spyder/dependencies.py || die
-
-	# do not check deps, fails because we removed dependencies above
-	sed -i -e 's:test_dependencies_for_spyder_setup_install_requires_in_sync:_&:' \
-		spyder/tests/test_dependencies_in_sync.py || die
-
-	# can't check for update, need network
-	rm spyder/workers/tests/test_update.py || die
-
-	# skip online test
-	rm spyder/widgets/github/tests/test_github_backend.py || die
-
-	distutils-r1_python_prepare_all
-}
-
-# Calling pytest directly makes the tests freeze after completing even if successful
-# Exit code is nonzero even upon success, so can't add || die here test results
-# should be checked for success manually
-python_test() {
-	"${EPYTHON}" runtests.py
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-
-	optfeature "2D/3D plotting in the Python and IPython consoles" dev-python/matplotlib
-	optfeature "View and edit DataFrames and Series in the Variable Explorer" dev-python/pandas
-	optfeature "View and edit two or three dimensional arrays in the Variable Explorer" dev-python/numpy
-	optfeature "Symbolic mathematics in the IPython console" dev-python/sympy
-	optfeature "Import Matlab workspace files in the Variable Explorer" dev-python/scipy
-	optfeature "Run Cython files in the IPython console" dev-python/cython
-	optfeature "The hdf5/h5py plugin" dev-python/h5py
-	# optfeature "The line profiler plugin" dev-python/spyder-line-profiler
-	# optfeature "The memory profiler plugin" dev-python/spyder-memory-profiler
-	# spyder-autopep8 does not have a release (yet)
-	# and are not compatible with >=spyder-4.0.0 at the moment
-	# optfeature "The autopep8 plugin" dev-python/spyder-autopep8
-	# optfeature "Vim key bindings" dev-python/spyder-vim
-	optfeature "Unittest support" dev-python/spyder-unittest
-	# optfeature "Jupyter notebook support" dev-python/spyder-notebook
-	optfeature "System terminal inside spyder" dev-python/spyder-terminal
-	# spyder-reports not yet updated to >=spyder-4.0.0
-	# optfeature "Markdown reports using Pweave" dev-python/spyder-reports
-}