dev-python/openstacksdk: add 0.60.0

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

2 files changed, 79 insertions, 0 deletions

diff --git a/dev-python/openstacksdk/Manifest b/dev-python/openstacksdk/Manifest
index 584e0bcfe3d1..66c5143fd3d4 100644
--- a/dev-python/openstacksdk/Manifest
+++ b/dev-python/openstacksdk/Manifest
@@ -1 +1,2 @@
 DIST openstacksdk-0.59.0.tar.gz 1021995 BLAKE2B be57afcdc707547e2cd69774de1b7d0dc4b84ffe58bdaa4f063b85996e8ee08ded60004d3211f827d7b4a5239d1420485ce2fae92b550722c959274a18ed2753 SHA512 02f8f8f174896417f0cf4ce1c65c87ea705664fa7a1c6383ad1791f5d94cb818b5b0bfee331bd0d07d724df59859ccef91c507b0c39522115f9549d6258a3eb7
+DIST openstacksdk-0.60.0.tar.gz 1023829 BLAKE2B 4c3734665126934d0906b3b3356dc195da77191d735c3051664fe48cbb9a0d8b0c5707bd5dd2ad648b9e0d6cf8e6df0cebbe36e411b9a139b52450212fe30837 SHA512 3c7240492e1a93045ea9b8ac55d8ddd3ebe4260a161849e281e3be4e3f1185ab7840a284fc1ab64dee20b99cd06c4ddd445bd8bd28c79d2c36655d554a037ff9
diff --git a/dev-python/openstacksdk/openstacksdk-0.60.0.ebuild b/dev-python/openstacksdk/openstacksdk-0.60.0.ebuild
new file mode 100644
index 000000000000..00e5891929b7
--- /dev/null
+++ b/dev-python/openstacksdk/openstacksdk-0.60.0.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..9} )
+inherit distutils-r1
+
+DESCRIPTION="A collection of libraries for building applications to work with OpenStack."
+HOMEPAGE="https://github.com/openstack/python-openstacksdk"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+CDEPEND=">dev-python/pbr-2.1.0[${PYTHON_USEDEP}]"
+RDEPEND="${CDEPEND}
+	>=dev-python/pyyaml-3.13[${PYTHON_USEDEP}]
+	>=dev-python/appdirs-1.3.0[${PYTHON_USEDEP}]
+	>=dev-python/requestsexceptions-1.2.0[${PYTHON_USEDEP}]
+	>dev-python/jsonpatch-1.20[${PYTHON_USEDEP}]
+	>=dev-python/os-service-types-1.7.0[${PYTHON_USEDEP}]
+	>=dev-python/keystoneauth-3.18.0[${PYTHON_USEDEP}]
+	>=dev-python/munch-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/decorator-4.4.1[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.9.0[${PYTHON_USEDEP}]
+	>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+	>=dev-python/netifaces-0.10.4[${PYTHON_USEDEP}]
+	>=dev-python/dogpile-cache-0.6.5[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-2.7.0[${PYTHON_USEDEP}]
+	dev-python/importlib_metadata[${PYTHON_USEDEP}]
+"
+BDEPEND="${CDEPEND}
+	test? (
+		>=dev-python/ddt-1.0.1[${PYTHON_USEDEP}]
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
+		dev-python/hacking[${PYTHON_USEDEP}]
+		>=dev-python/prometheus_client-0.4.2[${PYTHON_USEDEP}]
+		>=dev-python/oslo-config-6.1.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/requests-mock-1.2.0[${PYTHON_USEDEP}]
+		>=dev-python/statsd-3.3.0[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# Internet?
+	sed -e 's:test_create_dynamic_large_object:_&:' \
+		-i openstack/tests/unit/cloud/test_object.py || die
+
+	# TODO
+	sed -e 's:test_generate_form:_&:' \
+		-e 's:test_create_static_large_object:_&:' \
+		-e 's:test_object_segment_retries:_&:' \
+		-e 's:test_object_segment_retry_failure:_&:' \
+		-e 's:test_slo_manifest_retry:_&:' \
+		-i openstack/tests/unit/cloud/test_object.py || die
+
+	# unhappy about paths due to test runner
+	sed -e 's:test_method_not_supported:_&:' \
+		-i openstack/tests/unit/test_exceptions.py || die
+	sed -e 's:test_repr:_&:' \
+		-i openstack/tests/unit/test_resource.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	distutils_install_for_testing
+
+	# functional tests require cloud instance access
+	eunittest -b openstack/tests/unit
+}