dev-python/m2crypto: Bump to 0.43.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 71 insertions, 0 deletions

diff --git a/dev-python/m2crypto/Manifest b/dev-python/m2crypto/Manifest
index 97f6e8cf0f6d..478d2089a5a1 100644
--- a/dev-python/m2crypto/Manifest
+++ b/dev-python/m2crypto/Manifest
@@ -1 +1,2 @@
 DIST m2crypto-0.42.0.tar.gz 240072 BLAKE2B 86b9f340eb90a8fc94b09faa20a676a3a63c0c64a0902a6729face72b602a2f55941c156ecb3d522a823457d2514e96b147585264200674e11dfaba3d19790de SHA512 b36fb6d1ca401de9741118ab8d43113511bf27d32f45d2257ed70ea8d3b8a3beaf811731dbbece00a6b990366c43096c6b5f5b12d4649ae923bff98c5fc8e674
+DIST m2crypto-0.43.0.tar.gz 366785 BLAKE2B 611daee57c5605246c0a505604e54ec7e029301194ed75bcb7c02ec04f0246a3dc05e13c8c00f1cc15496495a81c098b203cf69a75ce5a65ea3c7a1c0445e5d3 SHA512 c5232956a88de51bd3a1e02859b7a308eabb4e055cc0c8aac2d8d34a60c60a4a4c7160db4060ec07f559134a04eb41c6ab116a194ec3f7441d342e6d38f9add9
diff --git a/dev-python/m2crypto/m2crypto-0.43.0.ebuild b/dev-python/m2crypto/m2crypto-0.43.0.ebuild
new file mode 100644
index 000000000000..ef855199c635
--- /dev/null
+++ b/dev-python/m2crypto/m2crypto-0.43.0.ebuild
@@ -0,0 +1,70 @@
+# Copyright 2018-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+PYPI_PN="M2Crypto"
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 toolchain-funcs pypi
+
+DESCRIPTION="A Python crypto and SSL toolkit"
+HOMEPAGE="
+	https://gitlab.com/m2crypto/m2crypto/
+	https://pypi.org/project/M2Crypto/
+"
+
+# openssl via src/SWIG/_lib11_compat.i
+LICENSE="MIT openssl"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="abi_mips_n32 abi_mips_n64 abi_mips_o32"
+
+DEPEND="
+	dev-libs/openssl:=
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	>=dev-lang/swig-2.0.9
+"
+
+swig_define() {
+	local x
+	for x; do
+		if tc-cpp-is-true "defined(${x})"; then
+			SWIG_FEATURES+=" -D${x}"
+		fi
+	done
+}
+
+src_prepare() {
+	# relies on very exact clock behavior which apparently fails
+	# with inconvenient CONFIG_HZ*
+	sed -e 's:test_server_simple_timeouts:_&:' \
+		-i tests/test_ssl.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	# setup.py looks at platform.machine() to determine swig options.
+	# For exotic ABIs, we need to give swig a hint.
+	local -x SWIG_FEATURES=
+
+	# https://bugs.gentoo.org/617946
+	swig_define __ILP32__
+
+	# https://bugs.gentoo.org/674112
+	swig_define __ARM_PCS_VFP
+
+	distutils-r1_python_compile
+}
+
+python_test() {
+	"${EPYTHON}" -m unittest -b -v tests.alltests.suite ||
+		die "Tests failed for ${EPYTHON}"
+}