dev-perl/GD: Force-enable gif,jpeg,png

Closes: https://bugs.gentoo.org/623542
Closes: https://bugs.gentoo.org/635830
Closes: https://bugs.gentoo.org/661634
Package-Manager: Portage-3.0.18, Repoman-3.0.2
Signed-off-by: Andreas K. Hüttel <dilfridge@gentoo.org>

1 files changed, 75 insertions, 0 deletions

diff --git a/dev-perl/GD/GD-2.730.0-r1.ebuild b/dev-perl/GD/GD-2.730.0-r1.ebuild
new file mode 100644
index 000000000000..6d099c37daa2
--- /dev/null
+++ b/dev-perl/GD/GD-2.730.0-r1.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DIST_AUTHOR=RURBAN
+DIST_VERSION=2.73
+DIST_EXAMPLES=("demos/*")
+inherit perl-module
+
+DESCRIPTION="Interface to Thomas Boutell's gd library"
+
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~sparc"
+IUSE="animgif fcgi test truetype xpm"
+
+RDEPEND="
+	>=media-libs/gd-2.2.3[png,jpeg]
+	media-libs/giflib
+	media-libs/libpng:0
+	sys-libs/zlib
+	virtual/jpeg:0
+	truetype? (
+		media-libs/gd[truetype]
+		media-libs/freetype:2
+	)
+	xpm? (
+		media-libs/gd[xpm]
+		x11-libs/libXpm
+	)
+	fcgi? (
+		dev-libs/fcgi
+	)
+"
+DEPEND="${RDEPEND}
+"
+BDEPEND="${RDEPEND}
+	>=virtual/perl-ExtUtils-Constant-0.230.0
+	dev-perl/ExtUtils-PkgConfig
+	virtual/perl-ExtUtils-MakeMaker
+	test? (
+		>=dev-perl/Test-Fork-0.20.0
+		>=virtual/perl-Test-Simple-0.880.0
+	)
+"
+
+RESTRICT="!test? ( test )"
+
+src_prepare() {
+	perl-module_src_prepare
+	sed -i "s/use Getopt::Long;/use Getopt::Long qw(:config pass_through);/" \
+		"${S}"/Makefile.PL || die
+}
+
+src_configure() {
+	local myconf
+	myconf="VERSION_33,GD_UNCLOSEDPOLY,GD_FTCIRCLE" # Per line 284 of Makefile.PL
+
+	# The following flags do not work properly. This is why we force-enable
+	# at least some of them. See bug 787404 as tracker.
+	use gif && use animgif && myconf+=",ANIMGIF"
+	myconf+=",JPEG"
+	use truetype && myconf+=",FT"
+	myconf+=",PNG"
+	use xpm && myconf+=",XPM"
+	myconf+=",GIF"
+	myconf="-options '${myconf}'"
+	use fcgi && myconf+=" --fcgi"
+	perl-module_src_configure
+}
+
+src_test() {
+	perl_rm_files t/z_*.t
+	perl-module_src_test
+}