dev-embedded/urjtag: bump to 2019.12

* Support newer libftdi (:1)
* Support newer libusb (:1)

Package-Manager: Portage-3.0.9, Repoman-3.0.2
RepoMan-Options: --force
Signed-off-by: Sam James <sam@gentoo.org>

3 files changed, 68 insertions, 17 deletions

diff --git a/dev-embedded/urjtag/Manifest b/dev-embedded/urjtag/Manifest
index 99d2979b368e..571057fe5f91 100644
--- a/dev-embedded/urjtag/Manifest
+++ b/dev-embedded/urjtag/Manifest
@@ -1 +1,2 @@
 DIST urjtag-0.10.tar.bz2 959834 BLAKE2B 9901156fb32372de77b3145cdef3f224b95d79d8f981435a41baf8bf1d7cd4353fcb52c60e3b936b59c3347dc485060ada58e87d7e1d4f6137ae12cd07124226 SHA512 245fc276793dbc7791be0989b75beba7f16e8543f35403d645aadcee8d8d613261509392da7e5dd97e5a2de6e87b18276c394cc6353f01e5d1d4907ffb5811ff
+DIST urjtag-2019.12.tar.xz 1208432 BLAKE2B 69963cbd39dcbec1abd73778fc6e98d743e36f6d4a17ba673b8691598ac0d4cec97e8b9c79068ad8971e6e07de81553bfd3bf5f684515b4a19303dd95ed477a2 SHA512 e149e53410a6591bdadc2c0138c6f81dac0fd6e35601461e19d356decdb820ec8e6bd53d59a1fd9781dfa1fee88d23dcafbd8df9adc0f8e51256c626d2ee0f36
diff --git a/dev-embedded/urjtag/urjtag-2019.12.ebuild b/dev-embedded/urjtag/urjtag-2019.12.ebuild
new file mode 100644
index 000000000000..2156d991a75d
--- /dev/null
+++ b/dev-embedded/urjtag/urjtag-2019.12.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="git://git.code.sf.net/p/urjtag/git"
+	inherit git-r3 autotools
+	S="${WORKDIR}/${P}/${PN}"
+else
+	SRC_URI="mirror://sourceforge/urjtag/${P}.tar.xz"
+	KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+fi
+
+DESCRIPTION="Tool for communicating over JTAG with flash chips, CPUs, and many more"
+HOMEPAGE="http://urjtag.sourceforge.net/"
+
+LICENSE="GPL-2"
+SLOT="0"
+# TODO: Figure out if anyone wants the Python bindings
+IUSE="ftdi ftd2xx readline usb"
+
+DEPEND="ftdi? ( dev-embedded/libftdi:1= )
+	ftd2xx? ( dev-embedded/libftd2xx )
+	readline? ( sys-libs/readline:= )
+	usb? ( virtual/libusb:1 )"
+RDEPEND="${DEPEND}
+	!dev-embedded/jtag"
+
+src_prepare() {
+	default
+
+	if [[ ${PV} == "9999" ]] ; then
+		mkdir -p m4 || die
+		eautopoint
+		eautoreconf
+	fi
+}
+
+src_configure() {
+	econf \
+		--disable-werror \
+		--disable-python \
+		--disable-static \
+		$(use_with readline) \
+		$(use_with ftdi libftdi) \
+		$(use_with ftd2xx) \
+		$(use_with usb libusb 1.0)
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete || die
+}
diff --git a/dev-embedded/urjtag/urjtag-9999.ebuild b/dev-embedded/urjtag/urjtag-9999.ebuild
index 57288a015220..54e0951ff6ce 100644
--- a/dev-embedded/urjtag/urjtag-9999.ebuild
+++ b/dev-embedded/urjtag/urjtag-9999.ebuild
@@ -1,18 +1,15 @@
 # Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-# TODO: figure out htf to make python.eclass work
+EAPI=7
 
-EAPI="5"
-
-inherit eutils ltprune multilib
 if [[ ${PV} == "9999" ]] ; then
 	EGIT_REPO_URI="git://git.code.sf.net/p/urjtag/git"
 	inherit git-r3 autotools
-	S=${WORKDIR}/${P}/${PN}
+	S="${WORKDIR}/${P}/${PN}"
 else
-	SRC_URI="mirror://sourceforge/urjtag/${P}.tar.bz2"
-	KEYWORDS="amd64 ppc sparc x86"
+	SRC_URI="mirror://sourceforge/urjtag/${P}.tar.xz"
+	KEYWORDS="~amd64 ~ppc ~sparc ~x86"
 fi
 
 DESCRIPTION="Tool for communicating over JTAG with flash chips, CPUs, and many more"
@@ -20,37 +17,36 @@ HOMEPAGE="http://urjtag.sourceforge.net/"
 
 LICENSE="GPL-2"
 SLOT="0"
-IUSE="ftd2xx ftdi readline static-libs usb"
+# TODO: Figure out if anyone wants the Python bindings
+IUSE="ftdi readline usb"
 
-DEPEND="ftdi? ( dev-embedded/libftdi:= )
-	ftd2xx? ( dev-embedded/libftd2xx )
+DEPEND="ftdi? ( dev-embedded/libftdi:1 )
 	readline? ( sys-libs/readline:= )
 	usb? ( virtual/libusb:1 )"
 RDEPEND="${DEPEND}
 	!dev-embedded/jtag"
 
 src_prepare() {
+	default
+
 	if [[ ${PV} == "9999" ]] ; then
-		mkdir -p m4
+		mkdir -p m4 || die
 		eautopoint
 		eautoreconf
 	fi
 }
 
 src_configure() {
-	use ftd2xx && LDFLAGS="${LDFLAGS} -L/opt/$(get_libdir)"
+	use readline || export vl_cv_lib_readline=no
 
 	econf \
 		--disable-werror \
 		--disable-python \
-		$(use_with readline) \
 		$(use_with ftdi libftdi) \
-		$(use_with ftd2xx) \
-		$(use_enable static-libs static) \
-		$(use_with usb libusb 1.0)
+		$(use_with usb libusb)
 }
 
 src_install() {
 	default
-	prune_libtool_files
+	find "${ED}" -name '*.la' -delete || die
 }