app-text/qpdfview: remove old version

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Andrey Grozin <grozin@gentoo.org>

2 files changed, 0 insertions, 88 deletions

diff --git a/app-text/qpdfview/Manifest b/app-text/qpdfview/Manifest
index 1facfc1a1d2b..ec7a7d84ac00 100644
--- a/app-text/qpdfview/Manifest
+++ b/app-text/qpdfview/Manifest
@@ -1,3 +1,2 @@
-DIST qpdfview-0.4.18.tar.gz 786577 BLAKE2B 07ef444ba39435578481e549fcbbd2d97362c6bda3092a17f1daa8b8437febf50cd2f145cd5e80cc1be565c5a658e85a428314a1bcd2a5a38efce0830f1cffba SHA512 38741520b20e3ed7100e52982930abac26e994a69df68c54dfa7180be8b2a4f377b91ba03993bab67b0a505ad79d62164f0f168a6715f4306b635ceba6840d66
 DIST qpdfview-0.4.18_p1.tar.bz2 448818 BLAKE2B 690f93c7f0af376e2b60d69a9802cdb159a97eb66b572a913badcd7ce3b9303d69bf8fbb359b5aa09ad1c63b1b6865e3602c8dc9cdad2506a43273d410a64d89 SHA512 41152596e39e6084e4e46c1aca28dfa4c619bf31068ee3272c6119793da5d99c58868ecf682ed0dc81e740f20193372e2780cf7d7fb917545662c93e6a2a1b4a
 DIST qpdfview-0.4.18_p20211227.tar.bz2 485165 BLAKE2B 1efdebf84ffbcedf464615e6ef2ef4092ef3210177e5faf17bb01c39243fdd5b11434459dad897a04acff0cf037129d2a524d37c670ae57556219421c363d1c5 SHA512 ea2206d9f2cbd5bf53ab75c8e78a5b3e30136febcf82630c375d664645d6b5e72c6128fb7b63cb65ec511c2c23014ceddd93495c520e9cddd1c52f01377bea17
diff --git a/app-text/qpdfview/qpdfview-0.4.18.ebuild b/app-text/qpdfview/qpdfview-0.4.18.ebuild
deleted file mode 100644
index d180343f34a8..000000000000
--- a/app-text/qpdfview/qpdfview-0.4.18.ebuild
+++ /dev/null
@@ -1,87 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PLOCALES="ast az be bg bs ca cs da de el en_AU en_GB eo es eu fa fi fr gl he hr hu id it ja kk ko ku ky lt lv ms my nb nds oc pl pt pt_BR ro ru sk sr sv th tr ug uk uz vi zh_CN zh_TW"
-inherit plocale qmake-utils xdg
-
-DESCRIPTION="A tabbed document viewer"
-HOMEPAGE="https://launchpad.net/qpdfview"
-SRC_URI="https://launchpad.net/${PN}/trunk/${PV}/+download/${P}.tar.gz"
-
-LICENSE="GPL-2+"
-SLOT="0"
-KEYWORDS="amd64 ~arm ~ppc64 x86 ~amd64-linux ~x86-linux"
-IUSE="cups +dbus djvu fitz +pdf postscript +sqlite +svg synctex"
-
-REQUIRED_USE="?? ( fitz pdf )"
-
-BDEPEND="
-	dev-qt/linguist-tools:5
-	virtual/pkgconfig
-"
-RDEPEND="
-	cups? ( net-print/cups )
-	djvu? ( app-text/djvu )
-	fitz? ( >=app-text/mupdf-1.7:= )
-	postscript? ( app-text/libspectre )
-	dev-qt/qtconcurrent:5
-	dev-qt/qtcore:5
-	dev-qt/qtgui:5
-	dev-qt/qtprintsupport:5[cups?]
-	dev-qt/qtwidgets:5
-	dbus? ( dev-qt/qtdbus:5 )
-	pdf? ( >=app-text/poppler-0.35[qt5]
-		dev-qt/qtxml:5 )
-	sqlite? ( dev-qt/qtsql:5[sqlite] )
-	svg? ( dev-qt/qtsvg:5 )
-	!svg? ( virtual/freedesktop-icon-theme )
-	synctex? ( app-text/texlive-core )"
-DEPEND="${RDEPEND}"
-
-DOCS=( CHANGES CONTRIBUTORS README TODO )
-
-PATCHES=( "${FILESDIR}/${P}-qt-5.15.patch" ) # bug 726064
-
-src_prepare() {
-	default
-
-	local mylrelease="$(qt5_get_bindir)"/lrelease
-	prepare_locale() {
-		"${mylrelease}" "translations/${PN}_${1}.ts" || die "preparing ${1} locale failed"
-	}
-
-	rm_help() {
-		rm -f "help/help_${1}.html" || die "removing ${1} help file failed"
-	}
-
-	plocale_find_changes translations ${PN}_ .ts
-	plocale_for_each_locale prepare_locale
-	plocale_for_each_disabled_locale rm_help
-
-	# adapt for prefix
-	sed -i -e "s:/usr:${EPREFIX}/usr:g" qpdfview.pri || die
-}
-
-src_configure() {
-	local myconfig=() i=
-	for i in cups dbus djvu pdf svg synctex; do
-		use ${i} || myconfig+=(without_${i})
-	done
-	use fitz && myconfig+=(with_fitz)
-	use postscript || myconfig+=(without_ps)
-	use sqlite || myconfig+=(without_sql)
-
-	local myqmakeargs=(
-		qpdfview.pro
-		CONFIG+="${myconfig[*]}"
-		PLUGIN_INSTALL_PATH="${EPREFIX}/usr/$(get_libdir)/${PN}"
-	)
-	eqmake5 "${myqmakeargs[@]}"
-}
-
-src_install() {
-	emake INSTALL_ROOT="${D}" install
-	einstalldocs
-}