app-text/djvu: move inkscape and librsvg into BDEPEND.

The "inkscape" and "rsvg-convert" commands are run at build-time to
generate icons; thus they belong in BDEPEND. This commit moves them
there from DEPEND. Done in a new unstable revision because it isn't
very important to anyone who has already installed a stable version.

Closes: https://bugs.gentoo.org/788073
Package-Manager: Portage-3.0.18, Repoman-3.0.2
Signed-off-by: Michael Orlitzky <mjo@gentoo.org>

1 files changed, 67 insertions, 0 deletions

diff --git a/app-text/djvu/djvu-3.5.28-r1.ebuild b/app-text/djvu/djvu-3.5.28-r1.ebuild
new file mode 100644
index 000000000000..af3433f46f91
--- /dev/null
+++ b/app-text/djvu/djvu-3.5.28-r1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools desktop flag-o-matic optfeature xdg
+
+MY_P="${PN}libre-${PV#*_p}"
+DESCRIPTION="DjVu viewers, encoders and utilities"
+HOMEPAGE="http://djvu.sourceforge.net/"
+SRC_URI="http://downloads.sourceforge.net/djvu/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P%%.3}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-solaris"
+IUSE="debug doc jpeg tiff xml"
+
+RDEPEND="jpeg? ( virtual/jpeg:0 )
+	tiff? ( media-libs/tiff:0= )"
+DEPEND="${RDEPEND}"
+
+# inkscape/rsvg-convert are used to generate icons at build-time only
+BDEPEND="app-arch/unzip
+	|| ( gnome-base/librsvg media-gfx/inkscape )"
+
+DOCS=( NEWS README )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	use debug && append-cppflags "-DRUNTIME_DEBUG_ONLY"
+
+	# We install all desktop files by hand.
+	econf \
+		$(use_enable xml xmltools) \
+		$(use_with jpeg) \
+		$(use_with tiff) \
+		--disable-desktopfiles
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name '*.la' -delete || die
+
+	use doc && dodoc -r doc
+
+	# Install desktop files.
+	cd desktopfiles || die
+	for i in {22,32,48,64}; do
+		insinto /usr/share/icons/hicolor/${i}x${i}/mimetypes
+		newins prebuilt-hi${i}-djvu.png image-vnd.djvu.png
+	done
+
+	insinto /usr/share/mime/packages
+	doins djvulibre-mime.xml
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	optfeature "djviewer or browser plugin" app-text/djview
+}