app-misc/fastfetch: add 2.29.0

Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>

2 files changed, 112 insertions, 0 deletions

diff --git a/app-misc/fastfetch/Manifest b/app-misc/fastfetch/Manifest
index 67d4850c7fb0..4c0efb7e59b6 100644
--- a/app-misc/fastfetch/Manifest
+++ b/app-misc/fastfetch/Manifest
@@ -1,3 +1,4 @@
 DIST fastfetch-2.23.0.tar.gz 1105725 BLAKE2B 8b79deb0f35d8238979441014ca049fcfa838c27323fec13127f5a48e6b28feb03965135c1a338b6bd1e59913e660fc91196c27acbe1b693bc5ff7727efaa5cb SHA512 aad3d549c0f4be3b1f99e7bbbf992dccf79f9ef7ea6a26bfc31ba574b1a32496a1cf75b85c32e0643941cad4061d7ba003b42924f9f272a825a1a09b628acc39
 DIST fastfetch-2.27.1.tar.gz 1123299 BLAKE2B 27a5dcba7c2b14baaf62e1372bc38e79c08654a00da4ebbd5f2918e1d2360745b61a5de45e9bdabf1295e03a7003da2db354133da0a19bd97013f59e60ae5637 SHA512 68742a963fd2df830ed8ef89548407bfd1eb5946f665c53fb1e4bc9b3ed3ae36db54ad0660d75395e5f4d239acfa51101cedba360a1a39f78c39f46c1fe559f6
 DIST fastfetch-2.28.0.tar.gz 1131275 BLAKE2B dc119a91b61b6a868140cf7dad8854f998b05b04ed0b8d3c36597fb5f39594f46acda7f26f6aa43392015f36af40a45e2773524440295a944a17198f19d9ea00 SHA512 9a08da7328234caa9bd77ac2393e8c0f8006dc1e9d97f7ceec4d1b737899e0b10ae8b726485bdac70da49f985c5386a341806555c27dfb73fb35a513704352ee
+DIST fastfetch-2.29.0.tar.gz 1136647 BLAKE2B 34e3d6d95bd19bb5d9bbfbc2c6f08af79dbe7175b2149c16684e9a7d8a9131efe27875eb08fad82e7dae320b5d75ebad4554f73f25f6bf8e63352059c71a0144 SHA512 75e483c0ca2ad5455f64074ed922865298a889455af0ff5197fc82d77df71da6a3e1dac061f24fcce010dae00a02ee037777f09a9320b2a93d71b275d5475af8
diff --git a/app-misc/fastfetch/fastfetch-2.29.0.ebuild b/app-misc/fastfetch/fastfetch-2.29.0.ebuild
new file mode 100644
index 000000000000..6186f29ea3dc
--- /dev/null
+++ b/app-misc/fastfetch/fastfetch-2.29.0.ebuild
@@ -0,0 +1,111 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Fast neofetch-like system information tool"
+HOMEPAGE="https://github.com/fastfetch-cli/fastfetch"
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/fastfetch-cli/fastfetch.git"
+	[[ ${PV} == *0.1.9999 ]] && EGIT_BRANCH=master
+	[[ ${PV} == *0.2.9999 ]] && EGIT_BRANCH=dev
+	[[ "${EGIT_BRANCH}" == "" ]] && die "Please set a git branch"
+else
+	SRC_URI="https://github.com/fastfetch-cli/fastfetch/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="X chafa dbus ddcutil drm elf gnome imagemagick opencl opengl osmesa pulseaudio sqlite test vulkan wayland xcb xfce xrandr"
+RESTRICT="!test? ( test )"
+
+# note - qa-vdb will always report errors because fastfetch loads the libs dynamically
+# make sure to crank yyjson minimum version to match bundled version
+RDEPEND="
+	>=dev-libs/yyjson-0.10.0
+	sys-apps/hwdata
+	sys-libs/zlib
+	X? ( x11-libs/libX11 )
+	chafa? ( media-gfx/chafa )
+	dbus? ( sys-apps/dbus )
+	ddcutil? ( app-misc/ddcutil:= )
+	drm? ( x11-libs/libdrm )
+	elf? ( virtual/libelf:= )
+	gnome? (
+		dev-libs/glib
+		gnome-base/dconf
+	)
+	imagemagick? ( media-gfx/imagemagick:= )
+	opencl? ( virtual/opencl )
+	opengl? ( media-libs/libglvnd[X] )
+	osmesa? ( media-libs/mesa[osmesa] )
+	pulseaudio? ( media-libs/libpulse )
+	sqlite? ( dev-db/sqlite:3 )
+	vulkan? (
+		media-libs/vulkan-loader
+		sys-apps/pciutils
+	)
+	wayland? ( dev-libs/wayland )
+	xcb? ( x11-libs/libxcb )
+	xfce? ( xfce-base/xfconf )
+	xrandr? ( x11-libs/libXrandr )
+"
+DEPEND="
+	${RDEPEND}
+	vulkan? ( dev-util/vulkan-headers )
+"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="
+	xrandr? ( X )
+	chafa? ( imagemagick )
+"
+
+src_configure() {
+	local fastfetch_enable_imagemagick7=no
+	local fastfetch_enable_imagemagick6=no
+	if use imagemagick; then
+		fastfetch_enable_imagemagick7=$(has_version '>=media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+		fastfetch_enable_imagemagick6=$(has_version '<media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+	fi
+
+	local mycmakeargs=(
+		-DENABLE_RPM=no
+		-DENABLE_ZLIB=yes
+		-DENABLE_SYSTEM_YYJSON=yes
+		-DIS_MUSL=$(usex elibc_musl)
+		-DINSTALL_LICENSE=no
+
+		-DENABLE_CHAFA=$(usex chafa)
+		-DENABLE_DBUS=$(usex dbus)
+		-DENABLE_DCONF=$(usex gnome)
+		-DENABLE_DDCUTIL=$(usex ddcutil)
+		-DENABLE_DRM=$(usex drm)
+		-DENABLE_ELF=$(usex elf)
+		-DENABLE_EGL=$(usex opengl)
+		-DENABLE_GIO=$(usex gnome)
+		-DENABLE_GLX=$(usex opengl)
+		-DENABLE_IMAGEMAGICK6=${fastfetch_enable_imagemagick6}
+		-DENABLE_IMAGEMAGICK7=${fastfetch_enable_imagemagick7}
+		-DENABLE_OPENCL=$(usex opencl)
+		-DENABLE_OSMESA=$(usex osmesa)
+		-DENABLE_PULSE=$(usex pulseaudio)
+		-DENABLE_SQLITE3=$(usex sqlite)
+		-DENABLE_VULKAN=$(usex vulkan)
+		-DENABLE_WAYLAND=$(usex wayland)
+		-DENABLE_X11=$(usex X)
+		-DENABLE_XCB=$(usex xcb)
+		-DENABLE_XCB_RANDR=$(usex xcb)
+		-DENABLE_XFCONF=$(usex xfce)
+		-DENABLE_XRANDR=$(usex xrandr)
+		-DBUILD_TESTS=$(usex test)
+	)
+
+	append-cppflags -DNDEBUG
+
+	cmake_src_configure
+}