www-servers/gatling: Migrate to acct-user/acct-group packages

Closes: https://bugs.gentoo.org/706812
Signed-off-by: Sebastian Pipping <sping@gentoo.org>
Package-Manager: Portage-3.0.0, Repoman-2.3.23

5 files changed, 99 insertions, 0 deletions

diff --git a/acct-group/gatling/gatling-0.ebuild b/acct-group/gatling/gatling-0.ebuild
new file mode 100644
index 000000000000..b4d3a3313de2
--- /dev/null
+++ b/acct-group/gatling/gatling-0.ebuild
@@ -0,0 +1,8 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit acct-group
+
+ACCT_GROUP_ID=500  # matches acct-user/gatling
diff --git a/acct-group/gatling/metadata.xml b/acct-group/gatling/metadata.xml
new file mode 100644
index 000000000000..ab886b7f0382
--- /dev/null
+++ b/acct-group/gatling/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM 'http://www.gentoo.org/dtd/metadata.dtd'>
+<pkgmetadata>
+	<maintainer type="person">
+		<email>sping@gentoo.org</email>
+		<name>Sebastian Pipping</name>
+	</maintainer>
+</pkgmetadata>
diff --git a/acct-user/gatling/gatling-0.ebuild b/acct-user/gatling/gatling-0.ebuild
new file mode 100644
index 000000000000..d32f48ebb8fa
--- /dev/null
+++ b/acct-user/gatling/gatling-0.ebuild
@@ -0,0 +1,12 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit acct-user
+
+ACCT_USER_GROUPS=( gatling )
+ACCT_USER_HOME=/var/www/localhost
+ACCT_USER_ID=500  # matches acct-group/gatling
+
+acct-user_add_deps
diff --git a/acct-user/gatling/metadata.xml b/acct-user/gatling/metadata.xml
new file mode 100644
index 000000000000..ab886b7f0382
--- /dev/null
+++ b/acct-user/gatling/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM 'http://www.gentoo.org/dtd/metadata.dtd'>
+<pkgmetadata>
+	<maintainer type="person">
+		<email>sping@gentoo.org</email>
+		<name>Sebastian Pipping</name>
+	</maintainer>
+</pkgmetadata>
diff --git a/www-servers/gatling/gatling-0.16-r1.ebuild b/www-servers/gatling/gatling-0.16-r1.ebuild
new file mode 100644
index 000000000000..6616e0b4eca0
--- /dev/null
+++ b/www-servers/gatling/gatling-0.16-r1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+inherit eutils toolchain-funcs
+
+DESCRIPTION="High performance web server"
+HOMEPAGE="https://www.fefe.de/gatling/"
+SRC_URI="https://www.fefe.de/gatling/${P}.tar.xz"
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="libressl ssl diet"
+REQUIRED_USE="ssl? ( !diet )"
+
+DEPEND=">=dev-libs/libowfat-0.32-r2[diet=]
+	diet? ( dev-libs/dietlibc )
+	ssl? (
+		!libressl? ( dev-libs/openssl:0 )
+		libressl? ( dev-libs/libressl )
+	)"
+RDEPEND="${DEPEND}
+	acct-group/gatling
+	acct-user/gatling
+	"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.13-compile.patch"
+	"${FILESDIR}/${PN}-0.15-ar.patch"
+)
+
+src_prepare() {
+	default
+	rm Makefile  # leaves us with GNUmakefile
+}
+
+src_compile() {
+	local DIET=
+	use diet && DIET='/usr/bin/diet'
+
+	local targets='gatling'
+	use ssl && targets+=' tlsgatling'
+
+	emake DIET="${DIET}" CC="$(tc-getCC)" \
+			CFLAGS="${CFLAGS} -I${ROOT}/usr/include/libowfat" \
+			LDFLAGS="${LDFLAGS}" prefix=/usr ${targets}
+}
+
+src_install() {
+	doman gatling.1
+
+	newconfd "${FILESDIR}/gatling.confd" gatling
+	newinitd "${FILESDIR}/gatling.initd-3" gatling
+	dodoc README.{ftp,http}
+
+	dobin gatling
+	use ssl && {
+		dodoc README.tls
+		dobin tlsgatling
+	}
+}