dev-python/django: Bump to 3.2.21

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 111 insertions, 0 deletions

diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest
index 31c1ffa496ee..830029717e79 100644
--- a/dev-python/django/Manifest
+++ b/dev-python/django/Manifest
@@ -1,5 +1,7 @@
 DIST Django-3.2.20.checksum.txt 2559 BLAKE2B db638871c5fd57d05000fd4765a8a0d1b2cc198ec7879fbcd76a11021b0cecd334cea50f27cd0215143fb735429e7aba6638f9783a632009054226b2acd2080c SHA512 dc82a2ead2cd9167a0d0309475d57e0a63b0f35bb2dae4f0a2240c3ab2f3425a748eb7cc66cca678904b1907192457fb3fbc867119329d3daf1fd4230f9a615e
 DIST Django-3.2.20.tar.gz 9831078 BLAKE2B 3591081804dd08188f41ce0b2013b4d7a9adc992b8136ad76ff7a9c49436e6d26e659136e3463c40b380f441448aba8ead4de3e3c7726ec6908830719bef8dcd SHA512 32555552e3929718c998ecb7ca2f39b94bbce378cd3c2b633d497fdf58e435fc7a0a89e22bdfdfcb8e5e6884d909103c0f4b545ee0c01fe58a0ba9dd6eed992b
+DIST Django-3.2.21.checksum.txt 2564 BLAKE2B a075e02b5b4d939a511848894ccea8eeb2c101f0f1369996c3c1f11acf34c26474e3f0596e44dc2da91e1ff3f3ad75e0d27227abbb41c7fd530e18bfdea6a349 SHA512 37ae3b2a804374b56c9fcfe2a18dea8f3fd49d605893c861965be35b21155fa98950fd8970607003be9738bfbcc38e50e2bdd4971dfdaa97e149d3ebb20edcdc
+DIST Django-3.2.21.tar.gz 9836824 BLAKE2B f91f1b26454f4e3f19033fca4b34bb2a59abd8a7ac7716512fb791732d447b79b825d63496d8615827d7e8ae07c1d2e80d76876153fc1a29b775782d63324cb8 SHA512 614d5e79c323f43d893ca235d81f1cb06287ead56aa5b7baf9930b9a99446d77ec111c65675a864cbf7cf2b9dfceaa0ffab389855da9d7a5c6e36067ab42e5dd
 DIST Django-4.1.10.checksum.txt 2559 BLAKE2B 103d1de6ec0da3a2440ea339388e2525ef5770f896be2383cf1828315e2c04ff8f5f8efe4d705dfcb905d453c25b8660410d4ab1b9d61331bc150a16ad857a28 SHA512 f23599dd06889a49c4fbb0c8c7b8f39ebaecbcb02c88ef95cdf33ea0c6563f3cf5c924d8b9a8b81e7b5aa17b6a1469b95e422faa7a53eb759bff516e053f302c
 DIST Django-4.1.10.tar.gz 10513572 BLAKE2B 0f1ef14fcf40cb6952fc459855a4e633e2d21c252a4732b27f8e980af6277ef69869a65a7bd0508fd7cdbd82742cb838170d965219b2919679ac92abfef087b6 SHA512 f31ad6fcce3bea0e0f895ec14b063485edec70872aa9c317243a38fb49b6c863159afc5aa31fb5c7a824c737f520f25cfbef55781c23fa0a204b61cefc66fb01
 DIST Django-4.1.11.checksum.txt 2564 BLAKE2B 55021666213384900c1871d939594bcb38b288870ff3337553d76eb2e0797c6394ec268f0c27768ceddfe9fa83027126de9de5d89ec314b2b6d6e3e7273f6534 SHA512 f36f1fb5fbdc1bee86512316e54dee4d70b535cc87b69d583a7d1b8ca1beeb7cf487484f189436e5116bb7220a18f1b627fe886dd40a11bd1ac29c12222f6321
diff --git a/dev-python/django/django-3.2.21.ebuild b/dev-python/django/django-3.2.21.ebuild
new file mode 100644
index 000000000000..ca46ed4c7d3b
--- /dev/null
+++ b/dev-python/django/django-3.2.21.ebuild
@@ -0,0 +1,109 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+PYTHON_REQ_USE='sqlite?,threads(+)'
+
+inherit bash-completion-r1 distutils-r1 optfeature verify-sig
+
+DESCRIPTION="High-level Python web framework"
+HOMEPAGE="
+	https://www.djangoproject.com/
+	https://github.com/django/django/
+	https://pypi.org/project/Django/
+"
+SRC_URI="
+	https://media.djangoproject.com/releases/$(ver_cut 1-2)/${P^}.tar.gz
+	verify-sig? ( https://media.djangoproject.com/pgp/${P^}.checksum.txt )
+"
+S="${WORKDIR}/${P^}"
+
+LICENSE="BSD"
+# admin fonts: Roboto (media-fonts/roboto)
+LICENSE+=" Apache-2.0"
+# admin icons, jquery, xregexp.js
+LICENSE+=" MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
+IUSE="doc sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/asgiref-3.3.4[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	>=dev-python/sqlparse-0.2.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		$(python_gen_impl_dep sqlite)
+		${RDEPEND}
+		dev-python/docutils[${PYTHON_USEDEP}]
+		dev-python/jinja[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pillow[webp,${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/selenium[${PYTHON_USEDEP}]
+		dev-python/tblib[${PYTHON_USEDEP}]
+		sys-devel/gettext
+	)
+	verify-sig? ( >=sec-keys/openpgp-keys-django-20201201 )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.1-bashcomp.patch
+	"${FILESDIR}"/django-3.2.19-py311.patch
+	# needed for Python 3.11
+	"${FILESDIR}"/django-3.2.20-urlsplit.patch
+)
+
+distutils_enable_sphinx docs --no-autodoc
+
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/django.asc
+
+src_unpack() {
+	if use verify-sig; then
+		cd "${DISTDIR}" || die
+		verify-sig_verify_signed_checksums \
+			"${P^}.checksum.txt" sha256 "${P^}.tar.gz"
+		cd "${WORKDIR}" || die
+	fi
+
+	default
+}
+
+python_prepare_all() {
+	# Fails because of warnings
+	sed -i 's/test_dumpdata_proxy_with_concrete/_&/' tests/fixtures/tests.py || die
+	# TODO: this suddenly started failing
+	sed -i -e 's:test_custom_fields:_&:' tests/inspectdb/tests.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# Tests have non-standard assumptions about PYTHONPATH,
+	# and don't work with ${BUILD_DIR}/lib.
+	PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite -v2 ||
+		die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	newbashcomp extras/django_bash_completion ${PN}-admin
+	bashcomp_alias ${PN}-admin django-admin.py
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature_header "Additional Backend support can be enabled via:"
+	optfeature "MySQL backend support" dev-python/mysqlclient
+	optfeature "PostgreSQL backend support" dev-python/psycopg:2
+	optfeature_header
+	optfeature "GEO Django" "sci-libs/gdal[geos]"
+	optfeature "Memcached support" dev-python/pylibmc dev-python/python-memcached
+	optfeature "ImageField Support" dev-python/pillow
+	optfeature "Password encryption" dev-python/bcrypt
+}