app-text/qpdfview: bump to the current 0.4.18 snapshot

Closes: https://bugs.gentoo.org/618044
Closes: https://bugs.gentoo.org/618062
Closes: https://bugs.gentoo.org/634978
Package-Manager: Portage-2.3.13, Repoman-2.3.4

2 files changed, 97 insertions, 0 deletions

diff --git a/app-text/qpdfview/Manifest b/app-text/qpdfview/Manifest
index 1987ab5d355e..07464242c6ae 100644
--- a/app-text/qpdfview/Manifest
+++ b/app-text/qpdfview/Manifest
@@ -1,2 +1,3 @@
 DIST qpdfview-0.4.16.tar.gz 636095 SHA256 fad416e8fefc3057fa1b8d12d964c7eccd16dffe0307a0d6e9d55a543294da7f SHA512 d3ac05fc51d48533e44e58cd19e5d222a8bfbc9da4df02ece6a405d2fdd3346eb4614816ae91e89facf28e107b920ff3ce7b2ccc8c9b7832ae2595ef70d65584 WHIRLPOOL 47bc82937562fdcbdf17f567bb0fa6e8eebd2e657320c129e9fd4f592c27eab855e7d2d69a22b45666509ace93b12528811b0671cb9483607448152bb676f11e
 DIST qpdfview-0.4.17beta1.tar.gz 658978 SHA256 60206c5f76410a35098e3c965552cec08cd85941776ea6f6b207d7ea63ce940f SHA512 803bd9a1165fc84302fb3c7734127eaab754bd2bf23083a1bcf340810fa617800f3d0069eae7b1f43fb528ebe17a6a32a652efbb902d525a95efc31efeb1e10a WHIRLPOOL 9ed967656b0e7e1f8828377d667d27a8c468f687b2df76285e1502cbdf0c5183bcec31bd8189ac80455395154e3df447eae1798b9581d05c7a8c24544b7d467b
+DIST qpdfview-0.4.18_pre.tar.gz 667869 SHA256 3e0fb7f16190d948ce5d094af7ff26c3e5e0e10bfdf01b4fe4bfa7b7cdda9602 SHA512 3a7a2cc474078dc742fccba2c87710c1e05cec76f0bd66650fa6cb4d6d8e2103241474689d4798da28ae1aeb2caa6e09dd8d1e9d0433c2eba21b202166aa3051 WHIRLPOOL 10d0b343e10a68f8b90cb777d08f5b7f9126d19bee41e82e7ae412c7903d8541b3484d3cac548322aeb85210fc5d5f07c5c84c9994094ff48384aec4635da2c9
diff --git a/app-text/qpdfview/qpdfview-0.4.18_pre.ebuild b/app-text/qpdfview/qpdfview-0.4.18_pre.ebuild
new file mode 100644
index 000000000000..13bcc7b4241f
--- /dev/null
+++ b/app-text/qpdfview/qpdfview-0.4.18_pre.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PLOCALES="ast az be bg bs ca cs da de el en_GB eo es eu fi fr gl he hr hu id it ja kk ko ky lt ms my pl pt pt_BR ro ru sk sv th tr ug uk vi zh_CN"
+
+inherit l10n qmake-utils xdg-utils gnome2-utils
+
+DESCRIPTION="A tabbed document viewer"
+HOMEPAGE="https://launchpad.net/qpdfview"
+SRC_URI="https://dev.gentoo.org/~grozin/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86 ~amd64-linux ~x86-linux"
+IUSE="cups +dbus djvu fitz +pdf postscript +sqlite +svg synctex"
+
+REQUIRED_USE="?? ( fitz pdf )"
+
+RDEPEND="
+	cups? ( net-print/cups )
+	djvu? ( app-text/djvu )
+	fitz? ( >=app-text/mupdf-1.7:= )
+	postscript? ( app-text/libspectre )
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtwidgets:5
+	dbus? ( dev-qt/qtdbus:5 )
+	pdf? ( >=app-text/poppler-0.35[qt5]
+		dev-qt/qtxml:5 )
+	sqlite? ( dev-qt/qtsql:5[sqlite] )
+	svg? ( dev-qt/qtsvg:5 )
+	!svg? ( virtual/freedesktop-icon-theme )
+	synctex? ( app-text/texlive-core )"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig"
+
+DOCS=( CHANGES CONTRIBUTORS README TODO )
+
+src_prepare() {
+	local mylrelease="$(qt5_get_bindir)"/lrelease
+
+	prepare_locale() {
+		"${mylrelease}" "translations/${PN}_${1}.ts" || die "preparing ${1} locale failed"
+	}
+
+	rm_help() {
+		rm -f "help/help_${1}.html" || die "removing ${1} help file failed"
+	}
+
+	l10n_find_plocales_changes translations ${PN}_ .ts
+	l10n_for_each_locale_do prepare_locale
+	l10n_for_each_disabled_locale_do rm_help
+
+	# adapt for prefix
+	sed -i -e "s:/usr:${EPREFIX}/usr:g" qpdfview.pri || die
+
+	default
+}
+
+src_configure() {
+	local myconfig=() i=
+	for i in cups dbus djvu pdf svg synctex; do
+		use ${i} || myconfig+=(without_${i})
+	done
+	use fitz && myconfig+=(with_fitz)
+	use postscript || myconfig+=(without_ps)
+	use sqlite || myconfig+=(without_sql)
+
+	local myqmakeargs=(
+		qpdfview.pro
+		CONFIG+="${myconfig[@]}"
+		PLUGIN_INSTALL_PATH="${EPREFIX}/usr/$(get_libdir)/${PN}"
+	)
+	eqmake5 "${myqmakeargs[@]}"
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+	einstalldocs
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+	gnome2_icon_cache_update
+}