dev-util/gtk-doc: remove old

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

3 files changed, 0 insertions, 125 deletions

diff --git a/dev-util/gtk-doc/Manifest b/dev-util/gtk-doc/Manifest
index 904ebd0393a1..483ebed1bbc6 100644
--- a/dev-util/gtk-doc/Manifest
+++ b/dev-util/gtk-doc/Manifest
@@ -1,2 +1 @@
-DIST gtk-doc-1.25.tar.xz 673184 BLAKE2B 2468b70403c0334b52ce1bcb77d2015fe83e0af9fac861464db605de9744ec1c7300e9b9a4b4fe0a3641e016083df063d92e1b74e44771d7a88c66815a396765 SHA512 7ac8c73ab9f9ecb6a142bd2232450a6431c3e4fe2372ff40460145b5d0bcffa1953c8cf49436539db86c3a32461cbd4180c714cb19cdd68bfd557816b789339c
 DIST gtk-doc-1.32.tar.xz 762000 BLAKE2B e87b0ed5dffd04acc7569171343839a742a874438248546b1b85ca71102d5a546f41b450c5cedf54ecab5b7b6585a4dac36d7600b21b5cce491470a50f82d3b0 SHA512 6d28395968c2951f1685570e5778b5add76d1b9cff8fcb8632b200b3ba251602a1ea59b1def84fc28560988b87fc0dbbc6947af88d268db6ff23e9c28aea3b28
diff --git a/dev-util/gtk-doc/gtk-doc-1.25-r1.ebuild b/dev-util/gtk-doc/gtk-doc-1.25-r1.ebuild
deleted file mode 100644
index 23d51c05ae3f..000000000000
--- a/dev-util/gtk-doc/gtk-doc-1.25-r1.ebuild
+++ /dev/null
@@ -1,119 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-PYTHON_COMPAT=( python2_7 )
-
-inherit eutils elisp-common gnome2 python-single-r1 readme.gentoo-r1
-
-DESCRIPTION="GTK+ Documentation Generator"
-HOMEPAGE="https://www.gtk.org/gtk-doc/"
-
-LICENSE="GPL-2 FDL-1.1"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc-solaris ~x64-solaris"
-
-IUSE="debug doc emacs highlight test vim"
-RESTRICT="!test? ( test )"
-REQUIRED_USE="${PYTHON_REQUIRED_USE}"
-
-RDEPEND="
-	${PYTHON_DEPS}
-	>=dev-libs/glib-2.6:2
-	>=dev-lang/perl-5.18
-	dev-libs/libxslt
-	>=dev-libs/libxml2-2.3.6:2
-	~app-text/docbook-xml-dtd-4.3
-	app-text/docbook-xsl-stylesheets
-	~app-text/docbook-sgml-dtd-3.0
-	>=app-text/docbook-dsssl-stylesheets-1.40
-	emacs? ( >=app-editors/emacs-23.1:* )
-	highlight? (
-		vim? ( || ( app-editors/vim app-editors/gvim ) )
-		!vim? ( dev-util/source-highlight )
-	)
-	test? ( sys-devel/bc )
-"
-DEPEND="${RDEPEND}
-	~dev-util/gtk-doc-am-${PV}
-	dev-util/itstool
-	virtual/pkgconfig
-"
-
-pkg_setup() {
-	DOC_CONTENTS="gtk-doc does no longer define global key bindings for Emacs.
-		You may set your own key bindings for \"gtk-doc-insert\" and
-		\"gtk-doc-insert-section\" in your ~/.emacs file."
-	SITEFILE=61${PN}-gentoo.el
-	python-single-r1_pkg_setup
-}
-
-src_prepare() {
-	# Remove global Emacs keybindings, bug #184588
-	eapply "${FILESDIR}"/${PN}-1.8-emacs-keybindings.patch
-
-	# Apply upstream commit 1baf9a6, bug #646850
-	sed -e '1,/exit 1/s/exit 1/exit $1/' \
-		-i gtkdoc-mkpdf.in || die
-
-	gnome2_src_prepare
-}
-
-src_configure() {
-	local myconf
-	if use vim; then
-		myconf="${myconf} $(use_with highlight highlight vim)"
-	else
-		myconf="${myconf} $(use_with highlight highlight source-highlight)"
-	fi
-
-	gnome2_src_configure \
-		--with-xml-catalog="${EPREFIX}"/etc/xml/catalog \
-		$(use_enable debug) \
-		${myconf}
-}
-
-src_compile() {
-	gnome2_src_compile
-	use emacs && elisp-compile tools/gtk-doc.el
-}
-
-src_install() {
-	gnome2_src_install
-
-	python_fix_shebang "${ED}"/usr/bin/gtkdoc-depscan
-
-	# Don't install those files, they are in gtk-doc-am now
-	rm "${ED}"/usr/share/aclocal/gtk-doc.m4 || die "failed to remove gtk-doc.m4"
-	rm "${ED}"/usr/bin/gtkdoc-rebase || die "failed to remove gtkdoc-rebase"
-
-	if use doc; then
-		docinto doc
-		dodoc doc/*
-		docinto examples
-		dodoc examples/*
-	fi
-
-	if use emacs; then
-		elisp-install ${PN} tools/gtk-doc.el*
-		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
-		readme.gentoo_create_doc
-	fi
-}
-
-src_test() {
-	emake -j1 check
-}
-
-pkg_postinst() {
-	gnome2_pkg_postinst
-	if use emacs; then
-		elisp-site-regen
-		readme.gentoo_print_elog
-	fi
-}
-
-pkg_postrm() {
-	gnome2_pkg_postrm
-	use emacs && elisp-site-regen
-}
diff --git a/dev-util/gtk-doc/metadata.xml b/dev-util/gtk-doc/metadata.xml
index 1a3871ad27fb..8c9b95e54348 100644
--- a/dev-util/gtk-doc/metadata.xml
+++ b/dev-util/gtk-doc/metadata.xml
@@ -5,11 +5,6 @@
 	<email>gnome@gentoo.org</email>
 	<name>Gentoo GNOME Desktop</name>
 </maintainer>
-<use>
-	<flag name="highlight">Enable source code highlighting</flag>
-	<flag name="vim">Enable source code highlighting through
-	<pkg>app-editors/vim</pkg></flag>
-</use>
 <longdescription lang="en">
 	GTK-Doc is used to document C code.
 	It is typically used to document the public API of libraries,