dev-lisp/cl-unicode: Update EAPI from 6 to 7

Signed-off-by: Ulrich Müller <ulm@gentoo.org>

1 files changed, 40 insertions, 0 deletions

diff --git a/dev-lisp/cl-unicode/cl-unicode-0.1.5-r1.ebuild b/dev-lisp/cl-unicode/cl-unicode-0.1.5-r1.ebuild
new file mode 100644
index 000000000000..7e56d351272b
--- /dev/null
+++ b/dev-lisp/cl-unicode/cl-unicode-0.1.5-r1.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit common-lisp-3 xdg-utils
+
+MY_P="v${PV}"
+
+DESCRIPTION="Provides Common Lisp implementations with knowledge about Unicode characters"
+HOMEPAGE="https://edicl.github.io/cl-unicode/"
+SRC_URI="https://github.com/edicl/${PN}/archive/${MY_P}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+
+DEPEND="virtual/commonlisp
+	dev-lisp/flexi-streams"
+RDEPEND="dev-lisp/cl-ppcre"
+
+src_configure() {
+	xdg_environment_reset
+}
+
+src_compile() {
+	# cl-unicode builds parts of its source code automatically the first time it
+	# is compiled, so we compile it here.
+	local initclunicode="(progn (push \"${S}/\" asdf:*central-registry*) (require :${PN}))"
+
+	common-lisp-export-impl-args "$(common-lisp-find-lisp-impl)"
+	${CL_BINARY} ${CL_EVAL} "${initclunicode}"
+}
+
+src_install() {
+	common-lisp-install-sources *.lisp test/
+	common-lisp-install-sources -t all build/
+	common-lisp-install-asdf
+	dodoc CHANGELOG doc/index.html
+}