blob: 3e400666a2c3b1550e27e00378069639b7fca610 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
ECM_NONGUI="false"
QTMIN=6.6.2
inherit ecm frameworks.kde.org
DESCRIPTION="Framework providing assorted high-level user interface components"
LICENSE="LGPL-2+"
KEYWORDS=""
IUSE="dbus wayland X"
# slot op: includes qpa/qplatformnativeinterface.h
COMMON_DEPEND="
>=dev-qt/qtbase-${QTMIN}:6[dbus?,gui]
wayland? (
dev-libs/wayland
>=dev-qt/qtbase-${QTMIN}:6=[wayland]
>=dev-qt/qtwayland-${QTMIN}:6
)
X? (
>=dev-qt/qtbase-${QTMIN}:6[X]
x11-libs/libX11
)
"
DEPEND="${COMMON_DEPEND}
wayland? ( >=dev-libs/plasma-wayland-protocols-1.11.1 )
X? (
x11-base/xorg-proto
x11-libs/libxcb
)
"
RDEPEND="${COMMON_DEPEND}
!${CATEGORY}/${PN}:5[-kf6compat(-)]
"
BDEPEND="wayland? ( >=dev-qt/qtwayland-${QTMIN}:6 )"
src_configure() {
local mycmakeargs=(
-DBUILD_GEO_SCHEME_HANDLER=ON
-DUSE_DBUS=$(usex dbus)
-DWITH_WAYLAND=$(usex wayland)
-DWITH_X11=$(usex X)
)
ecm_src_configure
}
|
GitWeb
