blob: cca3ce3979a45a156d12e0b33c089d8efc71b7a7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
ECM_HANDBOOK="optional"
PVCUT=$(ver_cut 1-3)
KFMIN=5.246.0
QTMIN=6.6.0
inherit ecm gear.kde.org
DESCRIPTION="Application to manage alarms and other timer based alerts for the desktop"
HOMEPAGE="https://apps.kde.org/kalarm/ https://userbase.kde.org/KAlarm"
LICENSE="GPL-2+ handbook? ( FDL-1.2+ )"
SLOT="6"
KEYWORDS=""
IUSE="+pim speech X"
DEPEND="
>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,widgets]
>=kde-apps/kcalutils-${PVCUT}:6
>=kde-apps/kidentitymanagement-${PVCUT}:6
>=kde-apps/kmime-${PVCUT}:6
>=kde-apps/kontactinterface-${PVCUT}:6
>=kde-apps/kpimtextedit-${PVCUT}:6[speech=]
>=kde-apps/pimcommon-${PVCUT}:6
>=kde-frameworks/kauth-${KFMIN}:6
>=kde-frameworks/kcalendarcore-${KFMIN}:6
>=kde-frameworks/kcmutils-${KFMIN}:6
>=kde-frameworks/kcodecs-${KFMIN}:6
>=kde-frameworks/kcompletion-${KFMIN}:6
>=kde-frameworks/kconfig-${KFMIN}:6
>=kde-frameworks/kconfigwidgets-${KFMIN}:6
>=kde-frameworks/kcontacts-${KFMIN}:6
>=kde-frameworks/kcoreaddons-${KFMIN}:6
>=kde-frameworks/kcrash-${KFMIN}:6
>=kde-frameworks/kdbusaddons-${KFMIN}:6
>=kde-frameworks/kglobalaccel-${KFMIN}:6
>=kde-frameworks/kguiaddons-${KFMIN}:6
>=kde-frameworks/kholidays-${KFMIN}:6
>=kde-frameworks/ki18n-${KFMIN}:6
>=kde-frameworks/kiconthemes-${KFMIN}:6
>=kde-frameworks/kidletime-${KFMIN}:6
>=kde-frameworks/kio-${KFMIN}:6
>=kde-frameworks/kitemmodels-${KFMIN}:6
>=kde-frameworks/kjobwidgets-${KFMIN}:6
>=kde-frameworks/knotifications-${KFMIN}:6
>=kde-frameworks/knotifyconfig-${KFMIN}:6
>=kde-frameworks/kservice-${KFMIN}:6
>=kde-frameworks/ktextwidgets-${KFMIN}:6
>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
>=kde-frameworks/kwindowsystem-${KFMIN}:6[X?]
>=kde-frameworks/kxmlgui-${KFMIN}:6
>=media-libs/phonon-4.12.0[qt6]
pim? (
>=kde-apps/akonadi-${PVCUT}:6
>=kde-apps/akonadi-contacts-${PVCUT}:6
>=kde-apps/akonadi-mime-${PVCUT}:6
>=kde-apps/kmailtransport-${PVCUT}:6
)
speech? ( dev-libs/ktextaddons:6[speech] )
X? ( x11-libs/libX11 )
"
RDEPEND="${DEPEND}
pim? ( >=kde-apps/kdepim-runtime-${PVCUT}:6 )
"
src_configure() {
local mycmakeargs=(
-DENABLE_AKONADI_PLUGIN=$(usex pim)
$(cmake_use_find_package speech KF6TextEditTextToSpeech)
-DWITHOUT_X11=$(usex !X)
)
ecm_src_configure
}
src_test() {
# LC_TIME bug 665626, 857012
# TZ bug https://bugs.kde.org/show_bug.cgi?id=445734
LC_TIME="C" TZ=UTC ecm_src_test
}
|
GitWeb