xfce-extra/xfce4-sensors-plugin/xfce4-sensors-plugin-1.0.0-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/xfce-extra/xfce4-sensors-plugin/xfce4-sensors-plugin-1.0.0-r1.ebuild,v 1.5 2011/03/22 20:57:53 xarthisius Exp $

EAPI=3
EAUTORECONF=yes
inherit flag-o-matic xfconf

DESCRIPTION="acpi, lm_sensors and hddtemp panel plugin"
HOMEPAGE="http://www.xfce.org/"
SRC_URI="mirror://xfce/src/panel-plugins/${PN}/1.0/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ppc x86"
IUSE="acpi debug hddtemp libnotify lm_sensors"

RDEPEND=">=x11-libs/gtk+-2.10:2
	>=xfce-base/libxfce4util-4.4
	>=xfce-base/libxfcegui4-4.4
	>=xfce-base/xfce4-panel-4.4
	libnotify? ( >=x11-libs/libnotify-0.4 )
	lm_sensors? ( >=sys-apps/lm_sensors-3.1.0 )
	hddtemp? ( app-admin/hddtemp net-analyzer/gnu-netcat )"
DEPEND="${RDEPEND}
	dev-util/intltool
	dev-util/pkgconfig"

pkg_setup() {
	has_version ">=x11-libs/libnotify-0.7" && append-cppflags -DHAVE_LIBNOTIFY_07

	PATCHES=(
		"${FILESDIR}"/${P}-missing_includedir.patch
		"${FILESDIR}"/${P}-without_libnotify.patch
		"${FILESDIR}"/${P}-segfault_workaround.patch
		"${FILESDIR}"/${P}-libnotify-0.7.patch
	)

	XFCONF=(
		--disable-dependency-tracking
		--disable-static
		$(use_enable hddtemp)
		$(use_enable hddtemp netcat)
		$(use_enable lm_sensors libsensors)
		$(use_enable acpi procacpi)
		$(use_enable acpi sysfsacpi)
		$(use_enable libnotify notification)
		$(xfconf_use_debug)
		)

	if ! use hddtemp && ! use lm_sensors && ! use acpi; then
		XFCONF+=(
			--enable-procacpi
			--enable-sysfsacpi
			)
	fi

	DOCS="AUTHORS ChangeLog NEWS NOTES README TODO"
}

src_prepare() {
	sed -i -e '/-no-undefined/d' src/Makefile.am || die
	sed -i -e 's/-Werror//' -e '/^XDT_I18N/s/nl//' configure.in || die
	xfconf_src_prepare
}