sci-biology/shrimp/shrimp-2.1.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-biology/shrimp/shrimp-2.1.0.ebuild,v 1.3 2013/01/23 10:06:29 patrick Exp $

EAPI=4

inherit flag-o-matic toolchain-funcs

MY_PV=${PV//./_}

DESCRIPTION="SHort Read Mapping Package"
HOMEPAGE="http://compbio.cs.toronto.edu/shrimp/"
SRC_URI="http://compbio.cs.toronto.edu/shrimp/releases/SHRiMP_${MY_PV}.src.tar.gz"

LICENSE="as-is"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="custom-cflags"

# file collision on /usr/bin/utils #453044
DEPEND="!sci-mathematics/cado-nfs"
RDEPEND="${DEPEND}"

S=${WORKDIR}/SHRiMP_${MY_PV}

pkg_setup() {
	if [[ ${CC} == *gcc* ]] &&	! tc-has-openmp; then
		elog "Please set CC to an OPENMP capable compiler (e.g. gcc[openmp] or icc"
		die "C compiler lacks OPENMP support"
	fi
}

src_prepare() {
	sed -e '1 a #include <stdint.h>' -i common/dag_glue.cpp || die
	# respect LDFLAGS wrt 331823
	sed -i -e "s/LDFLAGS/LIBS/" -e "s/\$(LD)/& \$(LDFLAGS)/" \
		-e 's/-static//' Makefile || die
}

src_compile() {
	append-flags -fopenmp
	use custom-cflags || append-flags -O3 # per instructions in BUILDING
	tc-export CXX
	emake CXXFLAGS="${CXXFLAGS}" LDFLAGS="${LDFLAGS}"
}

src_install() {
	dobin bin/*
	insinto /usr/libexec/${PN}
	doins -r utils/*
	dodoc HISTORY README TODO SPLITTING_AND_MERGING
}