net-im/kadu/kadu-0.3.9.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/kadu/kadu-0.3.9.ebuild,v 1.2 2004/08/30 15:40:11 dholm Exp $

inherit flag-o-matic eutils

DESCRIPTION="QT version of popular in Poland Gadu-Gadu IM network"
HOMEPAGE="http://kadu.net/"
SRC_URI="http://kadu.net/download/stable/${P/_/-}.tar.bz2"
LICENSE="GPL-2"

SLOT="0"
KEYWORDS="~x86 ~ppc"

IUSE="debug alsa arts esd kadu-voice nas oss spell ssl tcltk xmms"

DEPEND=">=x11-libs/qt-3.0.1
	alsa? ( media-libs/alsa-lib virtual/alsa )
	arts? ( kde-base/arts )
	esd? ( media-sound/esound )
	nas? ( media-libs/nas )
	spell? ( app-text/aspell )
	ssl? ( dev-libs/openssl )
	tcltk? ( >=dev-lang/tcl-8.4.0 >=dev-lang/tk-8.4.0 )
	xmms? ( media-sound/xmms )"

S=${WORKDIR}/${PN}

module_config() {
	sed -i -r "s/(^module_${1}\\s*=\\s*).*/\\1${2}/" .config
}

src_compile() {
	filter-flags -fno-rtti
	local myconf

	use debug && myconf="${myconf} --enable-debug"

	# static modules (disable only, do not compile as .so)
	use ssl || module_config encryption n
	use kadu-voice || module_config voice n

	# dynamic modules
	use alsa || use oss || module_config dsp_sound n
	use arts && module_config arts_sound m
	use esd && module_config esd_sound m
	if use nas; then
		module_config nas_sound m
		epatch "${FILESDIR}/${P}-nas-gentoo.diff"
	fi
	use spell && module_config spellchecker m
	use tcltk && module_config tcl_scripting m
	use xmms && module_config xmms m

	# enable modules, for which there are no USE flags
	module_config filedesc m
	module_config pcspeaker m

	econf ${myconf} || die
	emake || die
}

src_install() {
	make \
		DESTDIR=${D} \
		install || die
}