blob: ddadb4bb0a761ad9f19e2ad02b367837a9f3ff3c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
|
# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-base/nautilus/nautilus-2.6.3-r1.ebuild,v 1.4 2004/09/28 21:38:24 swtaylor Exp $
inherit gnome2 eutils
DESCRIPTION="A filemanager for the Gnome2 desktop"
HOMEPAGE="http://www.gnome.org/projects/nautilus/"
SLOT="0"
LICENSE="GPL-2 LGPL-2 FDL-1.1"
KEYWORDS="~x86 ~ppc ~alpha ~sparc ~hppa ~amd64 ~ia64 ~mips"
IUSE="oggvorbis cups gstreamer mad"
#
# eel was not updated the last run, return eel to the following the next bump:
# =gnome-base/eel-${PV}*
RDEPEND=">=dev-libs/glib-2.3
>=x11-libs/pango-1.2
>=x11-libs/gtk+-2.3
>=dev-libs/libxml2-2.4.7
=gnome-base/eel-2.6.2*
>=gnome-base/gnome-vfs-2.5.1
>=media-sound/esound-0.2.27
>=gnome-base/gconf-2
>=gnome-base/libgnome-2.6
>=gnome-base/libgnomeui-2.6
>=gnome-base/gnome-desktop-2.2
>=media-libs/libart_lgpl-2.3.10
>=gnome-base/libbonobo-2.2
>=gnome-base/libbonoboui-2.2
>=gnome-base/librsvg-2.0.1
>=gnome-base/orbit-2.4
>=x11-libs/startup-notification-0.5
dev-libs/popt
app-admin/fam
sys-apps/eject
cups? ( net-print/libgnomecups
net-print/gnome-cups-manager )
!gstreamer? ( oggvorbis? ( media-sound/vorbis-tools ) )
gstreamer? (
>=media-libs/gstreamer-0.8
>=media-libs/gst-plugins-0.8
>=media-plugins/gst-plugins-gnomevfs-0.8
mad? ( >=media-plugins/gst-plugins-mad-0.8 )
oggvorbis? (
>=media-plugins/gst-plugins-ogg-0.8
>=media-plugins/gst-plugins-vorbis-0.8
)
)"
# Add this once its tested by various other arches, bug #56703
# flac? ( >=media-plugins/gst-plugins-flac-0.8 )
# FIXME : what to do with exif/jpeg config stuff ?
DEPEND="${RDEPEND}
sys-devel/gettext
>=dev-util/intltool-0.29
>=app-text/scrollkeeper-0.3.11
>=dev-util/pkgconfig-0.12.0"
PDEPEND=">=x11-themes/gnome-icon-theme-1.1.91
x11-themes/gnome-themes"
DOCS="AUTHORS COPYIN* ChangeLo* HACKING INSTALL MAINTAINERS NEWS README THANKS TODO"
G2CONF="${G2CONF} $(use_enable gstreamer)"
src_unpack() {
unpack ${A}
cd ${S}
# use gstreamer for audio preview (patch by <foser@gentoo.org>)
use gstreamer && epatch ${FILESDIR}/${PN}-2.6-icon_view_gst_audio_preview.patch
# add libgnomeprint support
use cups && epatch ${FILESDIR}/${PN}-2-x-printers.patch
# regenerating only needed with patching
if use cups || use gstreamer; then
WANT_AUTOCONF_2_5=1 autoheader || die
WANT_AUTOCONF_2_5=1 autoconf || die
WANT_AUTOMAKE=1.4 automake || die
fi
# applying patch to optionally remove volumes from the desktop,
# see bug #51343 <obz@gentoo.org>
epatch ${FILESDIR}/${P}-novolumes.patch
has_version '>=media-libs/libexif-0.6' && epatch ${FILESDIR}/${P}-libexif-0.6.patch
}
pkg_postinst() {
gnome2_pkg_postinst
einfo "Nautilus moved to a new spatial browsing model."
einfo "If you are unhappy with this behaviour you can revert to the"
einfo "old browerslike behaviour by issueing the following command :"
einfo "gconftool-2 -s /apps/nautilus/preferences/always_use_browser -t bool TRUE"
}
|
GitWeb