1 files changed, 43 insertions, 0 deletions
diff --git a/sys-process/latencytop/latencytop-0.1.ebuild b/sys-process/latencytop/latencytop-0.1.ebuild
new file mode 100644
index 000000000000..170180acbc88
--- /dev/null
+++ b/sys-process/latencytop/latencytop-0.1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-process/latencytop/latencytop-0.1.ebuild,v 1.1 2008/01/19 21:24:55 vapier Exp $
+
+inherit toolchain-funcs
+
+DESCRIPTION="tool for identifying where in the system latency is happening"
+HOMEPAGE="http://www.latencytop.org/"
+SRC_URI="http://www.latencytop.org/download/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="unicode"
+
+RDEPEND="=dev-libs/glib-2*
+	sys-libs/ncurses"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	sed -i 's:latencytop.trans:/usr/share/misc/latencytop.trans:' latencytop.c || die
+}
+
+src_compile() {
+	# this sucks, but makefile is worse (for now)
+	use_echo() { use $1 && echo $2 || echo $3 ; }
+	$(tc-getCC) \
+		${CPPFLAGS} ${CFLAGS} ${LDFLAGS} \
+		$(pkg-config glib-2.0 --cflags) \
+		*.c -o latencytop \
+		$(pkg-config glib-2.0 --libs) \
+		$(use_echo unicode -lncursesw -lncurses) \
+		|| die
+}
+
+src_install() {
+	dosbin latencytop || die
+	insinto /usr/share/misc
+	doins latencytop.trans || die
+}