1 files changed, 120 insertions, 0 deletions
diff --git a/games-fps/urbanterror/urbanterror-4.2.002.ebuild b/games-fps/urbanterror/urbanterror-4.2.002.ebuild
new file mode 100644
index 000000000000..c89f9446091d
--- /dev/null
+++ b/games-fps/urbanterror/urbanterror-4.2.002.ebuild
@@ -0,0 +1,120 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-fps/urbanterror/urbanterror-4.2.002.ebuild,v 1.1 2012/10/12 14:48:20 hasufell Exp $
+
+EAPI=4
+
+inherit check-reqs eutils gnome2-utils games
+
+DESCRIPTION="Hollywood tactical shooter based on the ioquake3 engine"
+HOMEPAGE="http://www.urbanterror.info/home/"
+SRC_URI="http://178.63.102.135/svens_stuff/UrbanTerror42.tar.xz
+	http://dev.gentoo.org/~hasufell/distfiles/ioq3-for-UrbanTerror-${PV}.tar.xz
+	http://upload.wikimedia.org/wikipedia/en/5/56/Urbanterror.svg -> ${PN}.svg"
+
+LICENSE="GPL-2 Q3AEULA"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+curl debug dedicated openal +sdl server smp vorbis"
+
+RDEPEND="
+	!dedicated? (
+		virtual/opengl
+		curl? ( net-misc/curl )
+		openal? ( media-libs/openal )
+		sdl? ( media-libs/libsdl[X,audio,joystick,opengl,video] )
+		!sdl? ( x11-libs/libX11
+			x11-libs/libXext
+			x11-libs/libXxf86dga
+			x11-libs/libXxf86vm )
+		vorbis? ( media-libs/libogg
+			media-libs/libvorbis )
+	)"
+DEPEND="${RDEPEND}
+	dedicated? ( curl? ( net-misc/curl ) )"
+
+S=${WORKDIR}/ioq3-for-UrbanTerror-${PV}
+S_DATA=${WORKDIR}/UrbanTerror42
+
+CHECKREQS_DISK_BUILD="2700M"
+CHECKREQS_DISK_USR="1300M"
+
+pkg_pretend() {
+	check-reqs_pkg_pretend
+
+	if ! use dedicated ; then
+		if ! use sdl && ! use openal ; then
+			ewarn
+			ewarn "Sound support disabled. Enable 'sdl' or 'openal' useflag."
+			ewarn
+		fi
+	fi
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-build.patch
+}
+
+src_compile() {
+	buildit() { use $1 && echo 1 || echo 0 ; }
+	nobuildit() { use $1 && echo 0 || echo 1 ; }
+
+	emake \
+		ARCH=$(usex amd64 "x86_64" "i386") \
+		DEFAULT_BASEDIR="${GAMES_DATADIR}/${PN}" \
+		BUILD_CLIENT=$(nobuildit dedicated) \
+		BUILD_CLIENT_SMP=$(usex smp "$(nobuildit dedicated)" "0") \
+		BUILD_SERVER=$(usex dedicated "1" "$(buildit server)") \
+		USE_SDL=$(buildit sdl) \
+		USE_OPENAL=$(buildit openal) \
+		USE_CURL=$(buildit curl) \
+		USE_CODEC_VORBIS=$(buildit vorbis) \
+		USE_LOCAL_HEADERS=0 \
+		Q="" \
+		$(usex debug "debug" "release")
+}
+
+src_install() {
+	local my_arch=$(usex amd64 "x86_64" "i386")
+
+	doicon -s scalable "${DISTDIR}"/${PN}.svg
+	dodoc ChangeLog README md4-readme.txt "${S_DATA}"/q3ut4/readme42.txt
+	insinto "${GAMES_DATADIR}"/${PN}/q3ut4
+	doins -r "${S_DATA}"/q3ut4/*.pk3
+
+
+	if use !dedicated ; then
+		newgamesbin build/$(usex debug "debug" "release")-linux-${my_arch}/Quake3-UrT$(usex smp "-smp" "").${my_arch} ${PN}
+		make_desktop_entry ${PN} "UrbanTerror"
+	fi
+
+	if use dedicated || use server ; then
+		newgamesbin build/$(usex debug "debug" "release")-linux-${my_arch}/Quake3-UrT-Ded.${my_arch} ${PN}-dedicated
+		docinto examples
+		dodoc "${S_DATA}"/q3ut4/{server.cfg,mapcycle.txt}
+	fi
+
+	prepgamesdirs
+}
+
+pkg_preinst() {
+	games_pkg_preinst
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	games_pkg_postinst
+	gnome2_icon_cache_update
+
+	if use openal && ! use dedicated ; then
+		einfo
+		elog "You might need to set:"
+		elog "  seta s_useopenal \"1\""
+		elog "in your ~/.q3a/q3ut4/q3config.cfg for openal to work."
+		einfo
+	fi
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}