Version bumped. Fixed dependency, bug #286194.

(Portage version: 2.1.6.13/cvs/Linux x86_64)

2 files changed, 106 insertions, 1 deletions

diff --git a/x11-wm/awesome/ChangeLog b/x11-wm/awesome/ChangeLog
index 4b1202932e7f..8cd1dfac9dff 100644
--- a/x11-wm/awesome/ChangeLog
+++ b/x11-wm/awesome/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for x11-wm/awesome
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/awesome/ChangeLog,v 1.81 2009/09/14 15:35:23 matsuu Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/awesome/ChangeLog,v 1.82 2009/09/29 14:23:39 matsuu Exp $
+
+*awesome-3.4_rc2 (29 Sep 2009)
+
+  29 Sep 2009; MATSUU Takuto <matsuu@gentoo.org> +awesome-3.4_rc2.ebuild:
+  Version bumped. Fixed dependency, bug #286194.
 
 *awesome-3.4_rc1 (14 Sep 2009)
 
diff --git a/x11-wm/awesome/awesome-3.4_rc2.ebuild b/x11-wm/awesome/awesome-3.4_rc2.ebuild
new file mode 100644
index 000000000000..f4fd6def0981
--- /dev/null
+++ b/x11-wm/awesome/awesome-3.4_rc2.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/awesome/awesome-3.4_rc2.ebuild,v 1.1 2009/09/29 14:23:39 matsuu Exp $
+
+EAPI="2"
+inherit cmake-utils eutils
+
+MY_P="${P/_/-}"
+DESCRIPTION="A dynamic floating and tiling window manager"
+HOMEPAGE="http://awesome.naquadah.org/"
+SRC_URI="http://awesome.naquadah.org/download/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86 ~x86-fbsd"
+#IUSE="dbus doc bash-completion"
+IUSE="dbus doc"
+
+RDEPEND=">=dev-lang/lua-5.1[deprecated]
+	dev-libs/libev
+	>=dev-libs/libxdg-basedir-1
+	dev-util/gperf
+	media-libs/imlib2[png]
+	x11-libs/cairo[xcb]
+	x11-libs/libX11[xcb]
+	>=x11-libs/libxcb-1.4
+	>=x11-libs/pango-1.19.3
+	>=x11-libs/startup-notification-0.10
+	>=x11-libs/xcb-util-0.3.6
+	dbus? ( >=sys-apps/dbus-1 )"
+
+DEPEND="${RDEPEND}
+	app-text/asciidoc
+	app-text/xmlto
+	>=dev-util/cmake-2.6
+	dev-util/pkgconfig
+	media-gfx/imagemagick[png]
+	>=x11-proto/xcb-proto-1.5
+	>=x11-proto/xproto-7.0.15
+	doc? (
+		app-doc/doxygen
+		dev-util/luadoc
+		media-gfx/graphviz
+	)"
+
+RDEPEND="${RDEPEND}
+	app-shells/bash
+	|| (
+		x11-misc/gxmessage
+		x11-apps/xmessage
+	)
+	|| (
+		x11-terms/eterm
+		x11-misc/habak
+		x11-wm/windowmaker
+		media-gfx/feh
+		x11-misc/hsetroot
+		( media-gfx/imagemagick x11-apps/xwininfo )
+		media-gfx/xv
+		x11-misc/xsri
+		x11-apps/xsetroot
+	)"
+#		media-gfx/qiv (media-gfx/pqiv doesn't work)
+#		x11-misc/chbg #68116
+#	bash-completion? ( app-shells/bash-completion )
+
+S="${WORKDIR}/${MY_P}"
+
+DOCS="AUTHORS BUGS PATCHES README STYLE"
+
+mycmakeargs="-DPREFIX=/usr
+	-DSYSCONFDIR=/etc
+	$(cmake-utils_use_with dbus DBUS)
+	$(cmake-utils_use doc GENERATE_LUADOC)"
+
+src_compile() {
+	local myargs="all"
+
+	if use doc ; then
+		myargs="${myargs} doc"
+	fi
+	cmake-utils_src_compile ${myargs}
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	if use doc ; then
+		(
+			cd "${CMAKE_BUILD_DIR}"/doc
+			mv html doxygen
+			dohtml -r doxygen || die
+		)
+		mv "${D}"/usr/share/doc/${PN}/luadoc "${D}"/usr/share/doc/${PF}/html/luadoc || die
+	fi
+	rm -rf "${D}"/usr/share/doc/${PN} || die
+
+	exeinto /etc/X11/Sessions
+	newexe "${FILESDIR}"/${PN}-session ${PN} || die
+}