Version bump. Ebuild adpated to upstream file reorganisation

(Portage version: 2.2_rc33/cvs/Linux x86_64)

3 files changed, 88 insertions, 69 deletions

diff --git a/x11-misc/xaos/ChangeLog b/x11-misc/xaos/ChangeLog
index 338ef630b0de..e68064c2ae55 100644
--- a/x11-misc/xaos/ChangeLog
+++ b/x11-misc/xaos/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for x11-misc/xaos
-# Copyright 2002-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/xaos/ChangeLog,v 1.29 2009/03/28 12:55:30 bicatali Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/xaos/ChangeLog,v 1.30 2009/07/26 01:23:22 bicatali Exp $
+
+*xaos-3.5 (26 Jul 2009)
+
+  26 Jul 2009; Sébastien Fabbro <bicatali@gentoo.org> -xaos-3.4.ebuild,
+  +xaos-3.5.ebuild:
+  Version bump. Ebuild adpated to upstream file reorganisation
 
 *xaos-3.4-r1 (28 Mar 2009)
 
diff --git a/x11-misc/xaos/xaos-3.4.ebuild b/x11-misc/xaos/xaos-3.4.ebuild
deleted file mode 100644
index 4f06dc885270..000000000000
--- a/x11-misc/xaos/xaos-3.4.ebuild
+++ /dev/null
@@ -1,67 +0,0 @@
-# Copyright 1999-2008 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/xaos/xaos-3.4.ebuild,v 1.2 2008/07/31 22:36:54 markusle Exp $
-
-IUSE="aalib nls png svga threads X"
-
-MY_PN=XaoS
-MY_P=${MY_PN}-${PV}
-
-S=${WORKDIR}/${MY_P}
-DESCRIPTION="A very fast real-time fractal zoomer"
-HOMEPAGE="http://xaos.sf.net/"
-SRC_URI="mirror://sourceforge/xaos/${MY_P}.tar.gz"
-
-SLOT="0"
-LICENSE="GPL-2"
-KEYWORDS="~amd64 ~ppc ~sparc ~x86"
-
-RDEPEND="X? (
-				(
-				x11-libs/libX11
-				x11-libs/libXxf86dga
-				x11-libs/libXext
-				x11-libs/libXxf86vm
-				)
-		   )
-	svga? ( >=media-libs/svgalib-1.4.3 )
-	aalib? ( media-libs/aalib )
-	png? ( media-libs/libpng )
-	sys-libs/zlib
-	sci-libs/gsl"
-# xaos has ggi support, but it doesn't build
-#	ggi?   ( media-libs/libggi )
-
-DEPEND="${RDEPEND}
-		X? (
-				(
-				x11-proto/xf86vidmodeproto
-				x11-proto/xextproto
-				x11-proto/xf86dgaproto
-				x11-proto/xproto
-				)
-			)"
-
-src_compile() {
-	local myconf="--with-sffe=yes --with-ggi-driver=no"
-
-	# make sure we use gsl and not nasm (see bug #233318)
-	myconf="${myconf} --with-i386asm=no --with-gsl=yes"
-
-	econf \
-		$(use_with png) \
-		$(use_with aalib aa-driver) \
-		$(use_with svga svga-driver) \
-		$(use_with threads pthread) \
-		$(use_with X x11-driver) \
-		$(use_with X x) \
-		$(use_enable nls) \
-		${myconf} \
-		|| die "econf failed"
-	emake || die "emake failed"
-}
-
-src_install() {
-	emake DESTDIR="${D}" install || die
-	dodoc ChangeLog* TODO RELEASE_NOTES README
-}
diff --git a/x11-misc/xaos/xaos-3.5.ebuild b/x11-misc/xaos/xaos-3.5.ebuild
new file mode 100644
index 000000000000..93652961e257
--- /dev/null
+++ b/x11-misc/xaos/xaos-3.5.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/xaos/xaos-3.5.ebuild,v 1.1 2009/07/26 01:23:22 bicatali Exp $
+
+EAPI=2
+inherit eutils autotools
+
+DESCRIPTION="A very fast real-time fractal zoomer"
+HOMEPAGE="http://xaos.sf.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="aalib doc -gtk nls png svga threads X"
+
+RDEPEND="sys-libs/zlib
+	sci-libs/gsl
+	aalib? ( media-libs/aalib )
+	gtk? ( >=x11-libs/gtk+-2 )
+	png? ( media-libs/libpng )
+	X? ( x11-libs/libX11
+		 x11-libs/libXxf86dga
+		 x11-libs/libXext
+		 x11-libs/libXxf86vm )"
+
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	doc? ( virtual/latex-base )
+	X? ( x11-proto/xf86vidmodeproto
+		 x11-proto/xextproto
+		 x11-proto/xf86dgaproto
+		 x11-proto/xproto )"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-3.4-png.patch
+	epatch "${FILESDIR}"/${PN}-3.4-include.patch
+	sed -i -e 's/-s//' Makefile.in
+	eautoreconf
+}
+
+src_configure() {
+	# use gsl and not nasm (see bug #233318)
+	econf \
+		--with-sffe=yes \
+		--with-gsl=yes \
+		$(use_enable nls) \
+		$(use_with png) \
+		$(use_with aalib aa-driver) \
+		$(use_with gtk gtk-driver) \
+		$(use_with threads pthread) \
+		$(use_with X x11-driver) \
+		$(use_with X x)
+}
+
+src_compile() {
+	emake || die "emake failed"
+	if use doc; then
+		cd "${S}"/doc
+		emake xaos.dvi || die
+		dvipdf xaos.dvi || die
+		cd "${S}"/help
+		emake html || die
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dodoc ChangeLog* NEWS README AUTHORS
+	if use doc; then
+		insinto /usr/share/doc/${PF}
+		doins doc/xaos.pdf || die
+		dohtml help/* || die
+	fi
+	local driver="x11"
+	use gtk && driver="\"GTK+ Driver\""
+	make_desktop_entry "xaos -driver ${driver}" "XaoS Fractal Zoomer" \
+		xaos "Application;Education;Math;Graphics;"
+	doicon "${FILESDIR}"/${PN}.png
+}