www-apps/wordpress: 4.2.2

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key 0x401A1600)

2 files changed, 66 insertions, 1 deletions

diff --git a/www-apps/wordpress/ChangeLog b/www-apps/wordpress/ChangeLog
index 7f2a31e12346..ad5d2fab4979 100644
--- a/www-apps/wordpress/ChangeLog
+++ b/www-apps/wordpress/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for www-apps/wordpress
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-apps/wordpress/ChangeLog,v 1.173 2015/04/27 19:11:59 sping Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-apps/wordpress/ChangeLog,v 1.174 2015/05/08 17:10:33 sping Exp $
+
+*wordpress-4.2.2 (08 May 2015)
+
+  08 May 2015; Sebastian Pipping <sping@gentoo.org> +wordpress-4.2.2.ebuild:
+  Bump to 4.2.2
 
 *wordpress-4.2.1 (27 Apr 2015)
 
diff --git a/www-apps/wordpress/wordpress-4.2.2.ebuild b/www-apps/wordpress/wordpress-4.2.2.ebuild
new file mode 100644
index 000000000000..33fe3710763f
--- /dev/null
+++ b/www-apps/wordpress/wordpress-4.2.2.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-apps/wordpress/wordpress-4.2.2.ebuild,v 1.1 2015/05/08 17:10:33 sping Exp $
+
+EAPI=5
+
+inherit webapp
+
+DESCRIPTION="Wordpress PHP and MySQL based content management system (CMS)"
+HOMEPAGE="http://wordpress.org/"
+SRC_URI="http://wordpress.org/${P/_rc/-RC}.tar.gz"
+
+LICENSE="GPL-2+"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86"
+
+RDEPEND="virtual/httpd-php
+	|| ( dev-lang/php[mysql] dev-lang/php[mysqli] )"
+
+S=${WORKDIR}/${PN}
+
+need_httpd_cgi
+
+IUSE="+akismet examples +themes vhosts"
+
+# Override default of SLOT="${PVR}"
+WEBAPP_MANUAL_SLOT=yes
+SLOT="${PV}"
+
+src_install() {
+	webapp_src_preinst
+
+	dohtml readme.html
+	rm readme.html license.txt || die
+
+	if ! use akismet ; then
+		rm -R wp-content/plugins/akismet/ || die
+	fi
+	if ! use examples ; then
+		rm wp-content/plugins/hello.php || die
+	fi
+	if ! use themes ; then
+		rm -R wp-content/themes/*/ || die
+	fi
+
+	[[ -f wp-config.php ]] || cp wp-config-sample.php wp-config.php
+
+	insinto "${MY_HTDOCSDIR}"
+	doins -r .
+
+	webapp_serverowned "${MY_HTDOCSDIR}"/index.php
+	webapp_serverowned "${MY_HTDOCSDIR}"/wp-admin/menu.php
+	webapp_serverowned "${MY_HTDOCSDIR}"
+
+	webapp_configfile  "${MY_HTDOCSDIR}"/wp-config.php
+
+	webapp_postinst_txt en "${FILESDIR}"/postinstall-en.txt
+	webapp_postupgrade_txt en "${FILESDIR}"/postupgrade-en.txt
+
+	webapp_src_install
+}