Version bump

(Portage version: 2.2.0_alpha85/cvs/Linux x86_64)

4 files changed, 101 insertions, 4 deletions

diff --git a/sys-cluster/ceph/ChangeLog b/sys-cluster/ceph/ChangeLog
index deddd53ed82b..873c97a90359 100644
--- a/sys-cluster/ceph/ChangeLog
+++ b/sys-cluster/ceph/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sys-cluster/ceph
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-cluster/ceph/ChangeLog,v 1.16 2012/01/17 17:53:08 xarthisius Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/ceph/ChangeLog,v 1.17 2012/02/07 16:58:08 xarthisius Exp $
+
+*ceph-0.41 (07 Feb 2012)
+
+  07 Feb 2012; Kacper Kowalik <xarthisius@gentoo.org> +ceph-0.41.ebuild,
+  ceph-0.40.ebuild, files/ceph.initd:
+  Version bump
 
 *ceph-0.40 (17 Jan 2012)
 
diff --git a/sys-cluster/ceph/ceph-0.40.ebuild b/sys-cluster/ceph/ceph-0.40.ebuild
index ead4a2c4c691..4da706a55fbe 100644
--- a/sys-cluster/ceph/ceph-0.40.ebuild
+++ b/sys-cluster/ceph/ceph-0.40.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-cluster/ceph/ceph-0.40.ebuild,v 1.1 2012/01/17 17:53:08 xarthisius Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/ceph/ceph-0.40.ebuild,v 1.2 2012/02/07 16:58:08 xarthisius Exp $
 
 EAPI=4
 
@@ -46,6 +46,8 @@ src_prepare() {
 	sed -i "/^docdir =/d" src/Makefile.am || die #fix doc path
 	# disable testsnaps
 	sed -e '/testsnaps/d' -i src/Makefile.am || die
+	sed -e "/bin=/ s:lib:$(get_libdir):" "${FILESDIR}"/${PN}.initd \
+		> "${T}"/${PN}.initd || die
 	eautoreconf
 }
 
@@ -82,6 +84,6 @@ src_install() {
 	keepdir /var/log/${PN}/stat
 	keepdir /var/run/${PN}
 
-	newinitd "${FILESDIR}/${PN}.initd" ${PN}
+	newinitd "${T}/${PN}.initd" ${PN}
 	newconfd "${FILESDIR}/${PN}.confd" ${PN}
 }
diff --git a/sys-cluster/ceph/ceph-0.41.ebuild b/sys-cluster/ceph/ceph-0.41.ebuild
new file mode 100644
index 000000000000..4017997d580f
--- /dev/null
+++ b/sys-cluster/ceph/ceph-0.41.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/ceph/ceph-0.41.ebuild,v 1.1 2012/02/07 16:58:08 xarthisius Exp $
+
+EAPI=4
+
+inherit autotools eutils multilib
+
+DESCRIPTION="Ceph distributed filesystem"
+HOMEPAGE="http://ceph.newdream.net/"
+SRC_URI="http://ceph.newdream.net/download/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug fuse gtk libatomic radosgw static-libs tcmalloc"
+
+CDEPEND="
+	dev-libs/boost
+	dev-libs/libedit
+	dev-libs/crypto++
+	sys-apps/keyutils
+	fuse? ( sys-fs/fuse )
+	libatomic? ( dev-libs/libatomic_ops )
+	gtk? (
+			x11-libs/gtk+:2
+			dev-cpp/gtkmm:2.4
+			gnome-base/librsvg
+		)
+	radosgw? (
+				dev-libs/fcgi
+				dev-libs/expat
+			)
+	tcmalloc? ( dev-util/google-perftools )
+	"
+DEPEND="${CDEPEND}
+	dev-util/pkgconfig"
+RDEPEND="${CDEPEND}
+	sys-fs/btrfs-progs"
+
+STRIP_MASK="/usr/lib*/rados-classes/*"
+
+src_prepare() {
+	sed -e 's:invoke-rc\.d.*:/etc/init.d/ceph reload >/dev/null:' \
+		-i src/logrotate.conf || die
+	sed -i "/^docdir =/d" src/Makefile.am || die #fix doc path
+	# disable testsnaps
+	sed -e '/testsnaps/d' -i src/Makefile.am || die
+	sed -e "/bin=/ s:lib:$(get_libdir):" "${FILESDIR}"/${PN}.initd \
+		> "${T}"/${PN}.initd || die
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--without-hadoop \
+		--docdir=/usr/share/doc/${PF} \
+		--includedir=/usr/include \
+		$(use_with debug) \
+		$(use_with fuse) \
+		$(use_with libatomic libatomic-ops) \
+		$(use_with radosgw) \
+		$(use_with gtk gtk2) \
+		$(use_enable static-libs static) \
+		$(use_with tcmalloc)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	find "${D}" -type f -name "*.la" -exec rm -f {} \;
+
+	rmdir "${D}/usr/sbin"
+
+	exeinto /usr/$(get_libdir)/ceph
+	newexe src/init-ceph ceph_init.sh
+
+	insinto /etc/logrotate.d/
+	newins src/logrotate.conf ${PN}
+
+	chmod 644 "${D}"/usr/share/doc/${PF}/sample.*
+
+	keepdir /var/lib/${PN}
+	keepdir /var/lib/${PN}/tmp
+	keepdir /var/log/${PN}/stat
+	keepdir /var/run/${PN}
+
+	newinitd "${T}/${PN}.initd" ${PN}
+	newconfd "${FILESDIR}/${PN}.confd" ${PN}
+}
diff --git a/sys-cluster/ceph/files/ceph.initd b/sys-cluster/ceph/files/ceph.initd
index f56a67b162c4..2e74f0993599 100644
--- a/sys-cluster/ceph/files/ceph.initd
+++ b/sys-cluster/ceph/files/ceph.initd
@@ -1,6 +1,6 @@
 #!/sbin/runscript
 
-opts="reload"
+extra_started_commands="reload"
 bin=/usr/lib/ceph/ceph_init.sh
 
 depend() {