Use _p for defining version of the usb-modeswitch-data.

(Portage version: 2.2.0_alpha110/cvs/Linux x86_64)

2 files changed, 54 insertions, 1 deletions

diff --git a/sys-apps/usb_modeswitch/ChangeLog b/sys-apps/usb_modeswitch/ChangeLog
index e1df6e00daa5..75548e50e80f 100644
--- a/sys-apps/usb_modeswitch/ChangeLog
+++ b/sys-apps/usb_modeswitch/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sys-apps/usb_modeswitch
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/usb_modeswitch/ChangeLog,v 1.30 2012/06/19 19:43:11 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/usb_modeswitch/ChangeLog,v 1.31 2012/06/20 03:17:01 ssuominen Exp $
+
+*usb_modeswitch-1.2.3_p20120531 (20 Jun 2012)
+
+  20 Jun 2012; Samuli Suominen <ssuominen@gentoo.org>
+  +usb_modeswitch-1.2.3_p20120531.ebuild:
+  Use _p for defining version of the usb-modeswitch-data.
 
 *usb_modeswitch-1.2.3-r1 (19 Jun 2012)
 
diff --git a/sys-apps/usb_modeswitch/usb_modeswitch-1.2.3_p20120531.ebuild b/sys-apps/usb_modeswitch/usb_modeswitch-1.2.3_p20120531.ebuild
new file mode 100644
index 000000000000..60344320013d
--- /dev/null
+++ b/sys-apps/usb_modeswitch/usb_modeswitch-1.2.3_p20120531.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/usb_modeswitch/usb_modeswitch-1.2.3_p20120531.ebuild,v 1.1 2012/06/20 03:17:01 ssuominen Exp $
+
+EAPI=4
+inherit linux-info toolchain-funcs
+
+MY_PN=${PN/_/-}
+MY_P=${MY_PN}-${PV/_p*}
+DATA_VER=${PV/*_p}
+
+DESCRIPTION="USB_ModeSwitch is a tool for controlling 'flip flop' (multiple devices) USB gear like UMTS sticks"
+HOMEPAGE="http://www.draisberghof.de/usb_modeswitch/ http://www.draisberghof.de/usb_modeswitch/device_reference.txt"
+SRC_URI="http://www.draisberghof.de/${PN}/${MY_P}.tar.bz2
+	http://www.draisberghof.de/${PN}/${MY_PN}-data-${DATA_VER}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+DEPEND="virtual/libusb:0"
+RDEPEND="${DEPEND}
+	dev-lang/tcl" # usb_modeswitch script is tcl
+
+S=${WORKDIR}/${MY_P}
+
+CONFIG_CHECK="~USB_SERIAL"
+
+src_prepare() {
+	sed -i -e '/install.*BIN/s:-s::' Makefile || die
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc ChangeLog README
+
+	pushd ../${MY_PN}-data-${DATA_VER} >/dev/null
+	emake DESTDIR="${D}" files-install db-install
+	docinto data
+	dodoc ChangeLog README
+	popd >/dev/null
+}