Add live ebuild and make 0.3.0-r1 and 9999 share all code, fix musepack dependency

(Portage version: 2.1.6.13/cvs/Linux i686)

3 files changed, 107 insertions, 6 deletions

diff --git a/media-sound/qmmp/ChangeLog b/media-sound/qmmp/ChangeLog
index e7877d5d901e..7422d2fccb26 100644
--- a/media-sound/qmmp/ChangeLog
+++ b/media-sound/qmmp/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-sound/qmmp
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/qmmp/ChangeLog,v 1.18 2009/10/07 11:42:31 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/qmmp/ChangeLog,v 1.19 2009/10/09 18:12:00 sping Exp $
+
+*qmmp-9999 (09 Oct 2009)
+
+  09 Oct 2009; Sebastian Pipping <sping@gentoo.org> qmmp-0.3.0-r1.ebuild,
+  +qmmp-9999.ebuild:
+  Add live ebuild and make 0.3.0-r1 and 9999 share all code, fix musepack
+  dependency
 
 *qmmp-0.3.0-r1 (07 Oct 2009)
 
diff --git a/media-sound/qmmp/qmmp-0.3.0-r1.ebuild b/media-sound/qmmp/qmmp-0.3.0-r1.ebuild
index 2bfb50113dfa..7360f6ad5efb 100644
--- a/media-sound/qmmp/qmmp-0.3.0-r1.ebuild
+++ b/media-sound/qmmp/qmmp-0.3.0-r1.ebuild
@@ -1,18 +1,26 @@
 # Copyright 1999-2009 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/qmmp/qmmp-0.3.0-r1.ebuild,v 1.1 2009/10/07 11:42:31 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/qmmp/qmmp-0.3.0-r1.ebuild,v 1.2 2009/10/09 18:12:00 sping Exp $
 
 EAPI="2"
 
 inherit cmake-utils
+[ "$PV" == "9999" ] && inherit subversion
 
 DESCRIPTION="Qt4-based audio player with winamp/xmms skins support"
 HOMEPAGE="http://qmmp.ylsoftware.com/index_en.php"
-SRC_URI="http://qmmp.ylsoftware.com/files/${P}.tar.bz2"
+if [ "$PV" != "9999" ]; then
+	SRC_URI="http://qmmp.ylsoftware.com/files/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+else
+	SRC_URI=""
+	ESVN_REPO_URI="http://qmmp.googlecode.com/svn/trunk/qmmp/"
+	KEYWORDS=""
+fi
 
 LICENSE="GPL-2"
 SLOT="0"
-KEYWORDS="~amd64 ~x86"
+# KEYWORDS further up
 IUSE="aac +alsa +dbus bs2b ffmpeg flac jack libsamplerate +mad modplug musepack oss projectm pulseaudio scrobbler sndfile +vorbis wavpack"
 
 RDEPEND="x11-libs/qt-gui:4
@@ -24,7 +32,7 @@ RDEPEND="x11-libs/qt-gui:4
 	flac? ( media-libs/flac )
 	libsamplerate? ( media-libs/libsamplerate )
 	mad? ( media-libs/libmad )
-	musepack? ( >=media-sound/musepack-tools-444 )
+	musepack? ( >=media-libs/libmpcdec-1.2.6 )
 	modplug? ( >=media-libs/libmodplug-0.8.4 )
 	vorbis? ( media-libs/libvorbis
 		media-libs/libogg )
@@ -40,6 +48,8 @@ DEPEND="${RDEPEND}"
 
 DOCS="AUTHORS ChangeLog README"
 
+CMAKE_IN_SOURCE_BUILD="1"
+
 qmmp_use_enable() {
 	# uses completely non standard cmake options...
 	if use ${1}; then
@@ -53,7 +63,7 @@ src_configure() {
 	mycmakeargs="${mycmakeargs}
 		$(qmmp_use_enable alsa ALSA)
 		$(qmmp_use_enable aac AAC)
-		$(qmmp_use_enable bs2b BS2B )
+		$(qmmp_use_enable bs2b BS2B)
 		$(qmmp_use_enable dbus DBUS)
 		$(qmmp_use_enable ffmpeg FFMPEG)
 		$(qmmp_use_enable flac FLAC)
diff --git a/media-sound/qmmp/qmmp-9999.ebuild b/media-sound/qmmp/qmmp-9999.ebuild
new file mode 100644
index 000000000000..86c0cc632cc7
--- /dev/null
+++ b/media-sound/qmmp/qmmp-9999.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/qmmp/qmmp-9999.ebuild,v 1.1 2009/10/09 18:12:00 sping Exp $
+
+EAPI="2"
+
+inherit cmake-utils
+[ "$PV" == "9999" ] && inherit subversion
+
+DESCRIPTION="Qt4-based audio player with winamp/xmms skins support"
+HOMEPAGE="http://qmmp.ylsoftware.com/index_en.php"
+if [ "$PV" != "9999" ]; then
+	SRC_URI="http://qmmp.ylsoftware.com/files/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+else
+	SRC_URI=""
+	ESVN_REPO_URI="http://qmmp.googlecode.com/svn/trunk/qmmp/"
+	KEYWORDS=""
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+# KEYWORDS further up
+IUSE="aac +alsa +dbus bs2b ffmpeg flac jack libsamplerate +mad modplug musepack oss projectm pulseaudio scrobbler sndfile +vorbis wavpack"
+
+RDEPEND="x11-libs/qt-gui:4
+	media-libs/taglib
+	alsa? ( media-libs/alsa-lib )
+	bs2b? ( media-libs/libbs2b )
+	dbus? ( sys-apps/dbus )
+	aac? ( media-libs/faad2 )
+	flac? ( media-libs/flac )
+	libsamplerate? ( media-libs/libsamplerate )
+	mad? ( media-libs/libmad )
+	musepack? ( >=media-libs/libmpcdec-1.2.6 )
+	modplug? ( >=media-libs/libmodplug-0.8.4 )
+	vorbis? ( media-libs/libvorbis
+		media-libs/libogg )
+	jack? ( media-sound/jack-audio-connection-kit
+		media-libs/libsamplerate )
+	ffmpeg? ( media-video/ffmpeg )
+	projectm? ( >=media-libs/libprojectm-1.2.0 )
+	pulseaudio? ( >=media-sound/pulseaudio-0.9.9 )
+	wavpack? ( media-sound/wavpack )
+	scrobbler? ( net-misc/curl )
+	sndfile? ( media-libs/libsndfile )"
+DEPEND="${RDEPEND}"
+
+DOCS="AUTHORS ChangeLog README"
+
+CMAKE_IN_SOURCE_BUILD="1"
+
+qmmp_use_enable() {
+	# uses completely non standard cmake options...
+	if use ${1}; then
+		echo "-DUSE_${2}:BOOL=TRUE"
+	else
+		echo "-DUSE_${2}:BOOL=FALSE"
+	fi
+}
+
+src_configure() {
+	mycmakeargs="${mycmakeargs}
+		$(qmmp_use_enable alsa ALSA)
+		$(qmmp_use_enable aac AAC)
+		$(qmmp_use_enable bs2b BS2B)
+		$(qmmp_use_enable dbus DBUS)
+		$(qmmp_use_enable ffmpeg FFMPEG)
+		$(qmmp_use_enable flac FLAC)
+		$(qmmp_use_enable jack JACK)
+		$(qmmp_use_enable mad MAD)
+		$(qmmp_use_enable modplug MODPLUG)
+		$(qmmp_use_enable musepack MPC)
+		$(qmmp_use_enable oss OSS)
+		$(qmmp_use_enable projectm PROJECTM)
+		$(qmmp_use_enable pulseaudio PULSE)
+		$(qmmp_use_enable scrobbler SCROBBLER)
+		$(qmmp_use_enable sndfile SNDFILE)
+		$(qmmp_use_enable libsamplerate SRC)
+		$(qmmp_use_enable vorbis VORBIS)
+		$(qmmp_use_enable wavpack WAVPACK)"
+
+	cmake-utils_src_configure
+}