Make sure that the ebuild creates system.pa, modify the init script to use system.pa rather than default.pa and add a "needs" on consolekit if module-console-kit is requested in system.pa (bug #233789).

(Portage version: 2.2_rc6/cvs/Linux 2.6.26-gentoo x86_64)

3 files changed, 282 insertions, 1 deletions

diff --git a/media-sound/pulseaudio/ChangeLog b/media-sound/pulseaudio/ChangeLog
index 264a3c2d8ca9..2e797845aaaf 100644
--- a/media-sound/pulseaudio/ChangeLog
+++ b/media-sound/pulseaudio/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for media-sound/pulseaudio
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/ChangeLog,v 1.108 2008/08/03 12:37:01 betelgeuse Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/ChangeLog,v 1.109 2008/08/03 18:03:45 chutzpah Exp $
+
+*pulseaudio-0.9.11-r2 (03 Aug 2008)
+
+  03 Aug 2008; Patrick McLean <chutzpah@gentoo.org>
+  +files/pulseaudio.init.d-4, +pulseaudio-0.9.11-r2.ebuild:
+  Make sure that the ebuild creates system.pa, modify the init script to use
+  system.pa rather than default.pa and add a "needs" on consolekit if
+  module-console-kit is requested in system.pa (bug #233789).
 
   03 Aug 2008; Petteri Räty <betelgeuse@gentoo.org>
   pulseaudio-0.9.11-r1.ebuild:
diff --git a/media-sound/pulseaudio/files/pulseaudio.init.d-4 b/media-sound/pulseaudio/files/pulseaudio.init.d-4
new file mode 100644
index 000000000000..b9c883d664c5
--- /dev/null
+++ b/media-sound/pulseaudio/files/pulseaudio.init.d-4
@@ -0,0 +1,72 @@
+#!/sbin/runscript
+# Copyright 1999-2004 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/files/pulseaudio.init.d-4,v 1.1 2008/08/03 18:03:46 chutzpah Exp $
+
+depend() {
+	need localmount
+	use net
+
+	local script="/etc/pulse/system.pa"
+
+	for opt in ${PA_OPTS}; do
+		case "$opt" in
+			--file=*)	script="${opt#*=}" ;;
+			-F*)		script="${opt#-F}" ;;
+		esac
+	done
+
+	config "$script"
+
+	local needs="$(get_options need)"
+	if [ -n "${needs}" ]; then
+		need ${needs}
+		return
+	fi
+
+	if egrep -q '^[[:space:]]*load-module[[:space:]]+module-console-kit' "$script"; then
+	    needs="${needs} consolekit"
+	fi
+
+#ifdef HAL
+	if egrep -q '^[[:space:]]*load-module[[:space:]]+module-hal-detect' "$script"; then
+	    needs="${needs} hald"
+	fi
+#endif
+
+#ifdef AVAHI
+	if egrep -q '[[:space:]]*load-module[[:space:]]+module-zeroconf-publish' "$script"; then
+	    needs="${needs} avahi-daemon"
+	fi
+#endif
+
+#ifdef BLUETOOTH
+	if egrep -q '[[:space:]]*load-module[[:space:]]+module-bt-proximity' "$script"; then
+	    needs="${needs} bluetooth"
+	fi
+#endif
+
+#ifdef ALSA
+	if egrep -q '[[:space:]]*load-module[[:space:]]+module-alsa-(sink|source)' "$script" || 
+	    egrep -q '[[:space:]]*load-module[[:space:]]+module-(hal-)?detect' "$script" ||
+	    egrep -q '[[:space:]]*add-autoload-source[[:space:]]+(input|output)[[:space:]]+module-alsa-(sink|source)' "$script"; then
+	    needs="${needs} alsasound"
+	fi
+#endif
+
+	need "${needs}"
+	save_options need "${needs}"
+}
+
+start() {
+	ebegin "Starting pulseaudio"
+	PA_ALL_OPTS="${PA_OPTS} --fail=1 --daemonize=1 --system"
+	start-stop-daemon --start --exec /usr/bin/pulseaudio -- ${PA_ALL_OPTS}
+	eend $?
+}
+
+stop() {
+	ebegin "Stopping pulseaudio"
+	start-stop-daemon --stop --quiet --exec /usr/bin/pulseaudio --pidfile /var/run/pulse/pid
+	eend $?
+}
diff --git a/media-sound/pulseaudio/pulseaudio-0.9.11-r2.ebuild b/media-sound/pulseaudio/pulseaudio-0.9.11-r2.ebuild
new file mode 100644
index 000000000000..d04009010fe6
--- /dev/null
+++ b/media-sound/pulseaudio/pulseaudio-0.9.11-r2.ebuild
@@ -0,0 +1,201 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/pulseaudio-0.9.11-r2.ebuild,v 1.1 2008/08/03 18:03:45 chutzpah Exp $
+
+EAPI=1
+
+inherit eutils libtool autotools flag-o-matic
+
+DESCRIPTION="A networked sound server with an advanced plugin system"
+HOMEPAGE="http://0pointer.de/lennart/projects/pulseaudio/"
+SRC_URI="http://0pointer.de/lennart/projects/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2 GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc64 ~sparc ~x86"
+IUSE="alsa avahi caps jack lirc oss tcpd X hal dbus libsamplerate gnome bluetooth policykit asyncns +glib"
+
+RDEPEND="X? ( x11-libs/libX11 x11-libs/libSM x11-libs/libXau x11-libs/libXdmcp )
+	caps? ( sys-libs/libcap )
+	libsamplerate? ( >=media-libs/libsamplerate-0.1.1-r1 )
+	alsa? ( >=media-libs/alsa-lib-1.0.17-r1 )
+	glib? ( >=dev-libs/glib-2.4.0 )
+	avahi? ( >=net-dns/avahi-0.6.12 )
+	>=dev-libs/liboil-0.3.0
+	jack? ( >=media-sound/jack-audio-connection-kit-0.100 )
+	tcpd? ( sys-apps/tcp-wrappers )
+	lirc? ( app-misc/lirc )
+	dbus? ( >=sys-apps/dbus-1.0.0 )
+	gnome? ( >=gnome-base/gconf-2.4.0 )
+	hal? (
+		>=sys-apps/hal-0.5.7
+		>=sys-apps/dbus-1.0.0
+	)
+	app-admin/eselect-esd
+	bluetooth? (
+		>=net-wireless/bluez-libs-3
+		>=sys-apps/dbus-1.0.0
+	)
+	policykit? ( sys-auth/policykit )
+	asyncns? ( net-libs/libasyncns )
+	>=media-libs/audiofile-0.2.6-r1
+	>=media-libs/speex-1.2_beta
+	>=media-libs/libsndfile-1.0.10
+	>=dev-libs/liboil-0.3.6
+	sys-libs/gdbm
+	|| ( sys-apps/openrc >=sys-apps/baselayout-2.0_rc5 )
+	>=sys-devel/libtool-1.5.24" # it's a valid RDEPEND, libltdl.so is used
+DEPEND="${RDEPEND}
+	X? ( x11-proto/xproto )
+	dev-libs/libatomic_ops
+	dev-util/pkgconfig
+	dev-util/unifdef"
+
+# alsa-utils dep is for the alsasound init.d script (see bug #155707)
+# bluez-utils dep is for the bluetooth init.d script
+RDEPEND="${RDEPEND}
+	gnome-extra/gnome-audio
+	alsa? ( media-sound/alsa-utils )
+	bluetooth? ( >=net-wireless/bluez-utils-3 )"
+
+pkg_setup() {
+	if use avahi && ! built_with_use net-dns/avahi dbus ; then
+		echo
+		eerror "In order to compile pulseaudio with avahi support, you need to have"
+		eerror "net-dns/avahi emerged with 'dbus' in your USE flag. Please add that"
+		eerror "flag, re-emerge avahi, and then emerge pulseaudio again."
+		die "net-dns/avahi is missing the D-Bus bindings."
+	fi
+
+	enewgroup audio 18 # Just make sure it exists
+	enewgroup realtime
+	enewgroup pulse-access
+	enewgroup pulse
+	enewuser pulse -1 -1 /var/run/pulse pulse,audio
+}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	# Avoid building - and especially linking - test programs
+	# outside of make check
+	sed -i -e 's:noinst_PROGRAMS:check_PROGRAMS:' \
+		"${S}/src/Makefile.am"
+
+	eautoreconf
+	elibtoolize
+}
+
+src_compile() {
+	# To properly fix CVE-2008-0008
+	append-flags -UNDEBUG
+
+	econf \
+		--enable-largefile \
+		$(use_enable glib) \
+		--disable-solaris \
+		$(use_enable asyncns) \
+		$(use_enable oss) \
+		$(use_enable alsa) \
+		$(use_enable lirc) \
+		$(use_enable tcpd tcpwrap) \
+		$(use_enable jack) \
+		$(use_enable lirc) \
+		$(use_enable avahi) \
+		$(use_enable hal) \
+		$(use_enable dbus) \
+		$(use_enable gnome gconf) \
+		$(use_enable libsamplerate samplerate) \
+		$(use_enable bluetooth bluez) \
+		$(use_enable policykit polkit) \
+		$(use_with caps) \
+		$(use_with X x) \
+		--disable-ltdl-install \
+		--localstatedir=/var \
+		--with-realtime-group=realtime \
+		--disable-per-user-esound-socket \
+		|| die "econf failed"
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake -j1 DESTDIR="${D}" install || die "make install failed"
+
+	newconfd "${FILESDIR}/pulseaudio.conf.d" pulseaudio
+
+	use_define() {
+		local define=${2:-$(echo $1 | tr '[:lower:]' '[:upper:]')}
+
+		use "$1" && echo "-D$define" || echo "-U$define"
+	}
+
+	unifdef "${FILESDIR}/pulseaudio.init.d-4" \
+		$(use_define hal) \
+		$(use_define avahi) \
+		$(use_define alsa) \
+		$(use_define bluetooth) \
+		> "${T}/pulseaudio"
+	doinitd "${T}/pulseaudio"
+
+	use avahi && sed -i -e '/module-zeroconf-publish/s:^#::' "${D}/etc/pulse/default.pa"
+
+	dohtml -r doc
+	dodoc README
+
+	# this should fix system daemon startup #233789
+	cp "${D}/etc/pulse/default.pa" "${D}/etc/pulse/system.pa"
+
+	# Create the state directory
+	diropts -o pulse -g pulse -m0755
+	keepdir /var/run/pulse
+
+	find "${D}" -name '*.la' -delete
+}
+
+pkg_postinst() {
+	elog "PulseAudio in Gentoo can use a system-wide pulseaudio daemon."
+	elog "This support is enabled by starting the pulseaudio init.d ."
+	elog "To be able to access that you need to be in the group pulse-access."
+	elog "For more information about system-wide support, please refer to"
+	elog "	 http://pulseaudio.org/wiki/SystemWideInstance"
+	if use gnome; then
+		elog
+		elog "By enabling gnome USE flag, you enabled gconf support. Pleaes note"
+		elog "that you might need to remove the gnome USE flag or disable the"
+		elog "gconf module on /etc/pulse/default.pa to be able to use PulseAudio"
+		elog "with a system-wide instance."
+	fi
+	elog
+	elog "To use the ESounD wrapper while using a system-wide daemon, you also"
+	elog "need to enable auth-anonymous for the esound-unix module, or to copy"
+	elog "/var/run/pulse/.esd_auth into each home directory."
+	elog
+	elog "If you want to make use of realtime capabilities of PulseAudio"
+	elog "you should follow the realtime guide to create and set up a realtime"
+	elog "user group: http://www.gentoo.org/proj/en/desktop/sound/realtime.xml"
+	elog "Make sure you also have baselayout installed with pam USE flag"
+	elog "enabled, if you're using the rlimit method."
+	if use bluetooth; then
+		elog
+		elog "The BlueTooth proximity module is not enabled in the default"
+		elog "configuration file. If you do enable it, you'll have to have"
+		elog "your BlueTooth controller enabled and inserted at bootup or"
+		elog "PulseAudio will refuse to start."
+		elog
+		elog "Please note that the BlueTooth proximity module seems itself"
+		elog "still experimental, so please report to upstream if you have"
+		elog "problems with it."
+	fi
+	if use alsa; then
+		local pkg="media-plugins/alsa-plugins"
+		if has_version ${pkg} && ! built_with_use --missing false ${pkg} pulseaudio; then
+			elog
+			elog "You have alsa support enabled so you probably want to install"
+			elog "${pkg} with pulseaudio support to have"
+			elog "alsa using applications route their sound through pulseaudio"
+		fi
+	fi
+
+	eselect esd update --if-unset
+}