Enable multilib support.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

2 files changed, 77 insertions, 2 deletions

diff --git a/media-sound/fluidsynth/ChangeLog b/media-sound/fluidsynth/ChangeLog
index e1b82d58d8f3..df93e77f3ccb 100644
--- a/media-sound/fluidsynth/ChangeLog
+++ b/media-sound/fluidsynth/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/fluidsynth
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/fluidsynth/ChangeLog,v 1.77 2012/12/27 08:17:26 armin76 Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/fluidsynth/ChangeLog,v 1.78 2014/05/03 09:44:11 mgorny Exp $
+
+*fluidsynth-1.1.6-r1 (03 May 2014)
+
+  03 May 2014; Michał Górny <mgorny@gentoo.org> +fluidsynth-1.1.6-r1.ebuild:
+  Enable multilib support.
 
   27 Dec 2012; Raúl Porcel <armin76@gentoo.org> fluidsynth-1.1.6.ebuild:
   alpha/sparc stable wrt #444388
diff --git a/media-sound/fluidsynth/fluidsynth-1.1.6-r1.ebuild b/media-sound/fluidsynth/fluidsynth-1.1.6-r1.ebuild
new file mode 100644
index 000000000000..9a44bd42f3d1
--- /dev/null
+++ b/media-sound/fluidsynth/fluidsynth-1.1.6-r1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/fluidsynth/fluidsynth-1.1.6-r1.ebuild,v 1.1 2014/05/03 09:44:11 mgorny Exp $
+
+EAPI=5
+inherit cmake-multilib flag-o-matic
+
+DESCRIPTION="Fluidsynth is a software real-time synthesizer based on the Soundfont 2 specifications."
+HOMEPAGE="http://www.fluidsynth.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="alsa dbus debug examples jack ladspa lash portaudio pulseaudio readline sndfile"
+
+RDEPEND=">=dev-libs/glib-2.6.5:2[${MULTILIB_USEDEP}]
+	alsa? ( media-libs/alsa-lib[${MULTILIB_USEDEP}]
+		lash? ( >=media-sound/lash-0.5[${MULTILIB_USEDEP}] ) )
+	dbus? ( >=sys-apps/dbus-1.0.0[${MULTILIB_USEDEP}] )
+	jack? ( media-sound/jack-audio-connection-kit[${MULTILIB_USEDEP}] )
+	ladspa? ( >=media-libs/ladspa-sdk-1.12[${MULTILIB_USEDEP}]
+		>=media-libs/ladspa-cmt-1.15[${MULTILIB_USEDEP}] )
+	pulseaudio? ( >=media-sound/pulseaudio-0.9.8[${MULTILIB_USEDEP}] )
+	portaudio? ( >=media-libs/portaudio-19_pre[${MULTILIB_USEDEP}] )
+	readline? ( sys-libs/readline[${MULTILIB_USEDEP}] )
+	sndfile? ( >=media-libs/libsndfile-1.0.18[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig[${MULTILIB_USEDEP}]"
+
+src_configure() {
+	# autotools based build system has AC_CHECK_LIB(pthread, pthread_create) wrt
+	# bug #436762
+	append-flags -pthread
+
+	mycmakeargs=(
+		$(cmake-utils_use alsa enable-alsa)
+		$(cmake-utils_use dbus enable-dbus)
+		$(cmake-utils_use debug enable-debug)
+		$(cmake-utils_use jack enable-jack)
+		-Denable-ladcca=OFF
+		$(cmake-utils_use ladspa enable-ladspa)
+		$(cmake-utils_use sndfile enable-libsndfile)
+		$(cmake-utils_use portaudio enable-portaudio)
+		$(cmake-utils_use pulseaudio enable-pulseaudio)
+		$(cmake-utils_use readline enable-readline)
+		)
+
+	if use alsa; then
+		mycmakeargs+=( $(cmake-utils_use lash enable-lash) )
+	else
+		mycmakeargs+=( -Denable-lash=OFF )
+	fi
+
+	cmake-multilib_src_configure
+}
+
+src_install() {
+	cmake-multilib_src_install
+
+	dodoc AUTHORS NEWS README THANKS TODO doc/*.txt
+
+	docinto pdf
+	dodoc doc/*.pdf
+
+	if use examples; then
+		docinto examples
+		dodoc doc/*.c
+	fi
+}